Debian Codegraph @

texmf-dist/fonts/source/public/drm/drmitcap.mf

raw
1 % +AMDG This document was begun on 4 June 11EX, the feast
2 % of St. Francis Caracciolo, C, and it is humbly dedicated
3 % to him and to the Immaculate Heart of Mary for their
4 % prayers, and to the Sacred Heart of Jesus for His mercy.
5
6 def topcurl(suffix i,j,k) =
7 top z.j = z.i shifted (-curlw,curlh);
8 z.k = z.j shifted (-curlw/2,-curlh);
9 penpos.j(thickstroke/2,90);
10 penpos.k(thinstroke,180);
11 enddef;
12
13 def botcurl(suffix i,j,k) =
14 bot z.j = z.i shifted (curlw,-curlh);
15 z.k = z.j shifted (curlw/2,curlh);
16 penpos.j(thickstroke/2,90);
17 penpos.k(thinstroke,180);
18 enddef;
19
20 beginchar("J",0.75em#+2ss#,cap#,dep#); "The Letter J";
21 italcorr(ex#*slant);
22
23 pickup pencircle yscaled thinstroke;
24 penpos0(thickstroke,0);
25 z0l = (ss,h-curlh);
26 penpos1(thickstroke,-90);
27 z1l = (ss+curlw,h+o);
28 penpos2(0.75thickstroke,-90);
29 z2l = (w/2,y1);
30 penpos3(thinstroke,-90);
31 z3l = (2w/3,y2);
32 penpos4(thickstroke,0);
33 z4r = (w-ss,h+o);
34 penpos5(thickstroke,0);
35 z5 = (5w/6,h/2);
36 penpos6(thickstroke,0);
37 z6 = (3w/4,0);
38 penpos7(thinstroke,-90);
39 z7r = (w/3,-d);
40 penpos8(thickstroke,180);
41 z8r = (ss,-d/2);
42 penpos9(1.5thinstroke,90);
43 z9l = z8l;
44 penpos10(1.5thinstroke,0);
45 z10l = z9l;
46 penpos11(1.5thinstroke,-90);
47 z11l = z10l;
48 z12 = z5;
49 penpos13(1.5thinstroke,45);
50 z13 = (x2,y12);
51 penpos14(1.5thinstroke,45);
52 z14 = 2[z13,z12];
53
54 penstroke z0e..z1e..z2e..z3e..z4e;
55 penstroke z4e..z5e..z6e..{left}z7e..z8e..z9e..z10e..z11e;
56 penstroke z13e--z14e;
57
58 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16);
59 endchar;
60
61 beginchar("Q",em#+2ss#,cap#,dep#+thickstroke#/2); "The Letter Q";
62 italcorr(ex#*slant);
63
64 pickup pencircle yscaled thinstroke;
65 penpos0(thinstroke,0);
66 z0 = (w/2,0.60h);
67 penpos1(thinstroke,90);
68 z1l = z0l;
69 penpos2(thinstroke,180);
70 z2l = z1l;
71 penpos3(thinstroke,-90);
72 z3l = z2l;
73 penpos4(thinstroke,0);
74 z4 = (x0 + 0.1w,y0);
75 penpos5(thinstroke,-90);
76 z5 = (x1,y1 - 0.2w);
77 penpos6(thinstroke,180);
78 z6 = (x0 - 0.2w,y2);
79 penpos7(1.25thinstroke,90);
80 z7 = (x1,y1 + 0.15w);
81 penpos8(1.5thinstroke,0);
82 z8 = (x4r + 0.1w,y0);
83 penpos9(1.75thinstroke,-90);
84 z9 = (x5,y5-0.15w);
85 penpos10(2thinstroke,180);
86 z10r = (ss,y6);
87 penpos11(thickstroke,90);
88 z11r = (x7,h+o);
89 penpos12(thickstroke,0);
90 z12r = (w-ss,y8);
91 penpos13(0.8thickstroke,-90);
92 z13 = (2w/3,0-o);
93 penpos14(thinstroke,-90);
94 z14l = (ss+1.5curlw,0-curlh);
95 penpos15(thickstroke,180);
96 z15r = (ss,0-curlh/2);
97 penpos16(thinstroke,90);
98 z16 = (x14,0+o);
99 penpos17(thickstroke,60);
100 z17 = (2w/3,-d/2);
101 penpos18(thickstroke,90);
102 z18l = (w-ss,-d);
103 penpos19(0.7thickstroke,120);
104 z19 = (x18 + 2qtailunit + thickstroke,-2d/3);
105 penpos20(thinstroke,120);
106 z20 = z19 shifted (thickstroke,curlh/3);
107 penpos21(0.5thinstroke,120);
108 z21 = z20 shifted (thickstroke,curlh/3);
109 penpos22(0.1thinstroke,120);
110 z22 = z21 shifted (thickstroke,curlh/3);
111 penpos23(thickstroke,90);
112 z23l = (x18 + qtailunit+2thickstroke,-d);
113 penpos24(0.5thickstroke,-90);
114 z24l = (z16r--z17l) intersectionpoint (z14--z13);
115
116 penstroke
117 z2e..z1e..z0e..z3e..z2e{up}..z4e..z5e..z6e..z7e..z8e..z9e..z10e..z11e..z12e..z13e..z24e..z14e..z15e..{right}z16e..z17e..z18e..z23e..z19e..z20e..z21e..z22e;
118
119 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24);
120 endchar;
121
122 beginchar("T",5em#/6+2ss#,cap#,0);"The Letter T";
123 italcorr(ex#*slant);
124
125 z0 = (w/2-thickstroke/2,lserh);
126 z1 = z0 shifted (thickstroke,0);
127 llserif(0,2,3,4,5)(1);
128 lrserif(1,6,7,8,9)(1);
129 z10 = (x0,h-thickstroke);
130 z11 = z10 shifted (thickstroke,0);
131 fill z0..z2..z3--z4--z8--z7..z6..z1--z11--z10--cycle;
132 penpos12(thickstroke,90);
133 z12l = z10;
134 penpos13(thickstroke,90);
135 z13l = z11;
136 penpos14(thickstroke,90);
137 z14r = (ss+curlw,h);
138 penpos15(thickstroke,90);
139 z15r = (w-ss-curlw,h);
140 penpos16(0.8thickstroke,180);
141 z16r = (ss,y14l-hair);
142 penpos17(0.5thickstroke,-90);
143 z17l = z16l shifted (0,-thinstroke);
144 penpos18(0.8thinstroke,-90);
145 z18 = ((x12+x14)/2,y17);
146 penpos19(0.8thickstroke,180);
147 z19l = (w-ss,y15r+hair);
148 penpos20(0.5thickstroke,-90);
149 z20r = z19r shifted (0,thinstroke);
150 penpos21(0.8thinstroke,-90);
151 z21 = ((x15+x13)/2,y20);
152
153 penstroke z18e..z17e..z16e..z14e--z15e..z19e..z20e..z21e;
154
155 capt := currentpicture;
156
157 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24);
158 endchar;
159
160 beginchar("Y",5em#/6+2ss#,cap#,0); "The Letter Y";
161 italcorr(ex#*slant);
162
163 pickup pencircle yscaled thinstroke;
164 z0 = (w/2-thickstroke/2,lserh);
165 z1 = z0 shifted (thickstroke,0);
166 llserif(0,2,3,4,5)(1);
167 lrserif(1,6,7,8,9)(1);
168 z10 = (x0,h/2);
169 z11 = z10 shifted (thickstroke,0);
170 fill z0..z2..z3--z4--z8--z7..z6..z1--z11--z10--cycle;
171 penpos12(thickstroke,0);
172 z12l = z10;
173 penpos13(thickstroke,0);
174 z13 = (w-2curlw,h-curlh);
175 penpos14(thickstroke,0);
176 z14 = (2curlw,h-curlh);
177 topcurl(14,15,16);
178 penpos17(thickstroke/2,-90);
179 z17 = (x13 + curlw,y15);
180 penpos18(thinstroke,180);
181 z18 = (x17 + curlw/2,y16);
182 penpos19(thinstroke,0);
183 z19r = z12r;
184
185 penstroke z12e---z14e..z15e..z16e;
186 penstroke z12e---z13e..z17e..z18e;
187
188 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24);
189 endchar;
190
191 beginchar("Z",5em#/6+2ss#,cap#,dep#); "The Letter Z";
192 italcorr(ex#*slant);
193
194 pickup pencircle yscaled thinstroke;
195 penpos0(thickstroke,90);
196 z0r = (ss,h-o);
197 penpos1(thickstroke,180);
198 z1l = (w-ss,h);
199 penpos2(0.7thickstroke,90);
200 z2 = 0.666[z0,z1] shifted (-thinstroke,-thinstroke);
201 penpos3(thickstroke,180);
202 z3r = (ss,0-o);
203 penpos4(thinstroke,70);
204 z4r = (x0l+thinstroke/2,y0l);
205 penpos5(0.8thickstroke,90);
206 z5r = ((x0+x2)/2,h+o);
207 penpos6(thickstroke,-90);
208 z6r = (w-ss,-2d/3);
209 penpos7(0.7thickstroke,-90);
210 z7 = (w/2,0);
211 penpos8(0.8thickstroke,-90);
212 z8 = 0.5[(x7,0),(x6,0)] shifted (0,-d/3);
213 penpos9(1.5thinstroke,230);
214 z9l = z3l;
215
216 penstroke z4e--z0e;
217 penstroke z0e..z5e..z2e..z1e;
218 penstroke z1e--z3e;
219 penstroke z3e..z9e{right}..z7e..z8e..z6e;
220
221 capz := currentpicture;
222
223 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24);
224 endchar;
225
226 beginchar("G",em#+2ss#,cap#,dep#); "The Letter G";
227 italcorr(ex#*slant);
228
229 z1=(w-ss-userw-thickstroke/2,h-userh);
230 z2=z1-(0,thickstroke);
231 z3=(w-ss-userw,2userh);
232 z5=(w/2,h+o);
233 z6=z5-(0,thinstroke);
234 z7=(w/2,0);
235 z8=z7+(0,thinstroke);
236 z9=(ss,h/2);
237 z10=z9+(curvwid,0);
238 z4=z3-(thickstroke,0);
239 z11=(x3,h/2-userh);
240 z12=z11-(thickstroke,0);
241 z30 = (x3,-dep/2);
242 z31 = ((x4+x8)/2,-dep);
243 z32 = (x8,-2dep/3);
244 z33 = z32 shifted (dotwidth/2,dotwidth/2);
245 z34 = z33 shifted (dotwidth/2,-dotwidth/2);
246 z35 = z34 shifted (-dotwidth/2,-dotwidth/4);
247 z36 = z30 shifted (-thickstroke,0);
248 z37 = z31 shifted (0,thinstroke);
249
250 ulserif(12,15,16,17,18)(1);
251 urserif(11,19,20,21,22)(1);
252 ctsideserif(1,23,24,25,26,2)(1);
253
254 path gbody; gbody =
255 z17--z21--z20..z19..z11--z3..{left}z7{left}..{up}z9{up}..{right}z5{right}..z1;
256 path ginbody; ginbody = z2..{left}z6{left}..{down}z10{down}..{right}z8{right}..z4--z12..z15..z16--z17;
257
258 fill gbody & topserif & ginbody & cycle;
259
260 fill z11---z3---z30..z31..z32..z33..z34..z35..z37..
261 z36--z4--z12--cycle;
262
263 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51);
264 endchar;