Debian Codegraph @

texmf-dist/fonts/source/public/cmpica/pcpunct.mf

raw
1 % This file is public domain.
2 % Originally written 1986, Don Hosek.
3 % This declaration added by Clea F. Rees 2008/11/14 with the permission of Dan Hosek.
4 %
5 % This is PCPUNCT.MF in text format, as of June 22, 1986.
6 % based on PUNCT.MF
7 % This file contains punctuation marks common to roman and italic styles.
8 % {\tt'} and {\tt`} have been replaced with {\pc'}
9
10 % Codes \0041, \0043, \0045, \0047--\0054,\ %
11 %% \0056, \0057, \0072, \0073, \0075, \0100,\par
12 % \0133, \0135, and \0140 are generated, as well as code |spanish_shriek|
13 % (for a Spanish exclamation point) if that code value is known.
14
15 cmchar "Exclamation point";
16 beginchar("!",5u#+width_adj#,asc_height#,0);
17 italcorr asc_height#*slant-2u#-.5width_adj#+.5dot_size#;
18 adjust_fit(0,0);
19 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
20 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
21 numeric bot_width;
22 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
23 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
24 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
25 if square_dots: top y1=h;
26 filldraw stroke z1e--z2e; % stem
27 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
28 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
29 penlabels(0,1,2,3,4); endchar;
30
31 cmchar "Spanish open exclamation point";
32 beginchar(spanish_shriek,5u#+width_adj#,asc_height#-desc_depth#,desc_depth#);
33 italcorr h#*slant-2u#-.5width_adj#+.5dot_size#;
34 adjust_fit(0,0);
35 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
36 lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
37 numeric top_width;
38 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
39 pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
40 x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
41 if square_dots: bot y1=-d;
42 filldraw stroke z1e--z2e; % stem
43 else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
44 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
45 penlabels(0,1,2,3,4); endchar;
46
47 cmchar "Hash mark (number sign)";
48 compute_spread(.6x_height#,.7x_height#);
49 beginchar("#",15u#,asc_height#,asc_depth#);
50 italcorr (math_axis#+.5(spread#+rule_thickness#))*slant-.5u#;
51 adjust_fit(0,0);
52 pickup rule.nib; lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
53 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
54 draw z1--z2; % upper bar
55 draw z3--z4; % lower bar
56 lft x6=hround 3u; rt x7=hround(w-3u); x5-x6=x7-x8;
57 x8=good.x if monospace: .6 else: .5 fi\\w;
58 top y5=top y7=h+eps; bot y6=bot y8=-d-eps;
59 y15=y1; z15=whatever[z5,z6]; y36=y3; z36=whatever[z5,z6];
60 y27=y2; z27=whatever[z7,z8]; y48=y4; z48=whatever[z7,z8];
61 draw z5--if x5>x6+1:(good.x(x15+.5),y1)--(good.x(x15-.5),y1)
62 --(good.x(x36+.5),y3)--(good.x(x36-.5),y3)--fi\\z6; % left diagonal
63 draw z7--if x7>x8+1:(good.x(x27+.5),y2)--(good.x(x27-.5),y2)
64 --(good.x(x48+.5),y4)--(good.x(x48-.5),y4)--fi\\z8; % right diagonal
65 labels(1,2,3,4,5,6,7,8,15,27,36,48); endchar;
66
67 cmchar "Per cent sign";
68 beginchar("%",9u#+max(6u#,2fudge*(hair#+stem#)),
69 body_height#,body_height#-asc_height#);
70 italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
71 adjust_fit(0,0); pickup fine.nib;
72 numeric left_curve,right_curve;
73 left_curve=hround 5/6[fudged.hair,fudged.stem];
74 right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
75 pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
76 top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
77 bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
78 x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
79 filldraw stroke pulled_super_arc.e(1,2)(superpull)
80 & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
81 filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
82 pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
83 bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
84 top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
85 x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
86 filldraw stroke pulled_super_arc.e(5,6)(superpull)
87 & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
88 filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
89 pickup rule.nib; top y9=h; bot y10=-d;
90 if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
91 draw z9--z10; % diagonal
92 else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
93 pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
94 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
95 path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
96 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
97 penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
98
99 cmchar "Straight single quote";
100 beginchar("'",5u#,asc_height#,0);
101 italcorr asc_height#*slant+.5 if serifs: flare# else: stem# fi -2u#;
102 adjust_fit(0,0);
103 x1=x2=.5w; y2=max(.5[bar_height,x_height]+.5vair,h-x_height);
104 if serifs: pickup crisp.nib; pos1(flare,0); pos2(vair,0);
105 y1+.5stem=h; filldraw circ_stroke z1e--z2e; % stem and bulb
106 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
107 top y1=h; filldraw stroke z1e--z2e; fi % stem
108 penlabels(1,2); endchar;
109
110 cmchar "Left parenthesis";
111 beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
112 italcorr body_height#*slant-.5u#;
113 adjust_fit(0,0); pickup fine.nib;
114 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
115 rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
116 top y1=h; y2=.5[y1,y3]=math_axis;
117 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
118 ...{3(x3e-x2e),y3-y2}z3e; % arc
119 penlabels(1,2,3); endchar;
120
121 cmchar "Right parenthesis";
122 beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
123 italcorr math_axis#*slant-.5u#;
124 adjust_fit(0,0); pickup fine.nib;
125 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
126 lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
127 top y1=h; y2=.5[y1,y3]=math_axis;
128 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
129 ...{3(x3e-x2e),y3-y2}z3e; % arc
130 penlabels(1,2,3); endchar;
131
132 cmchar "Asterisk";
133 beginchar("*",9u#,
134 if low_asterisk:math_axis#+.5x_height# else: body_height# fi,0);
135 italcorr h#*slant-.75u#;
136 adjust_fit(0,0);
137 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
138 x0=.5w; y0=h-.5x_height;
139 for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
140 numeric theta; theta=angle(z[d]-z0);
141 fill z0+.5(0,-thin_join)rotated theta
142 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
143 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
144 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
145 labels(0,[-150],[-90],[-30],30,90,150); endchar;
146
147 cmchar "Plus sign";
148 beginarithchar("+"); pickup rule.nib;
149 x1=x2=good.x .5w; top y1=h+eps; .5[y1,y2]=math_axis;
150 lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
151 draw z1--z2; % stem
152 draw z3--z4; % crossbar
153 labels(1,2,3,4); endchar;
154
155 cmchar "Comma";
156 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
157 define_whole_blacker_pixels(dot_diam);
158 beginchar(",",5u#,dot_diam#,comma_depth#);
159 adjust_fit(0,0);
160 x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
161 comma(1,a,dot_diam,.2u,comma_depth); % dot and tail
162 penlabels(1); endchar;
163
164 cmchar "Period";
165 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
166 define_whole_blacker_pixels(dot_diam);
167 beginchar(".",5u#,dot_diam#,0);
168 adjust_fit(0,0); pickup fine.nib;
169 pos1(dot_diam,0); pos2(dot_diam,90);
170 lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
171 penlabels(1,2); endchar;
172
173 cmchar "Virgule (slash)";
174 beginchar("/",9u#,body_height#,paren_depth#);
175 italcorr body_height#*slant-.5u#;
176 adjust_fit(0,0); pickup rule.nib;
177 rt x1=hround(w-u)+eps; top y1=h+eps;
178 lft x2=hround u-eps; bot y2=-d-eps;
179 draw z1--z2; % diagonal
180 penlabels(1,2); endchar;
181
182 cmchar "Colon";
183 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
184 define_whole_blacker_pixels(dot_diam);
185 beginchar(":",5u#,x_height#,0);
186 italcorr x_height#*slant+.5dot_diam#-2u#;
187 adjust_fit(0,0); pickup fine.nib;
188 pos1(dot_diam,0); pos2(dot_diam,90);
189 lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
190 pos3(dot_diam,0); pos4(dot_diam,90);
191 x3=x1; bot y4l=0; z3=z4; dot(3,4); % lower dot
192 penlabels(1,2,3,4); endchar;
193
194 cmchar "Semicolon";
195 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
196 define_whole_blacker_pixels(dot_diam);
197 beginchar(";",5u#,x_height#,comma_depth#);
198 italcorr x_height#*slant+.5dot_diam#-2u#;
199 adjust_fit(0,0); pickup fine.nib;
200 pos1(dot_diam,0); pos2(dot_diam,90);
201 lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
202 x3-.5dot_diam=hround(.5w-.5dot_diam); y3-.5dot_diam=0;
203 comma(3,a,dot_diam,.05u,comma_depth); % lower dot and tail
204 penlabels(1,2,3); endchar;
205
206 cmchar "Equals sign";
207 compute_spread(.45x_height#,.55x_height#);
208 beginchar("=",14u#,v_center(spread#+rule_thickness#));
209 italcorr h#*slant-.5u#;
210 adjust_fit(0,0); pickup rule.nib;
211 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
212 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
213 draw z1--z2; % upper bar
214 draw z3--z4; % lower bar
215 labels(1,2,3,4); endchar;
216
217 cmchar "At sign";
218 beginchar("@",14u#,asc_height#,0);
219 italcorr .7asc_height#*slant-.5u#;
220 adjust_fit(0,if hefty or monospace:-2u# else: 0 fi);
221 pickup fine.nib; pos0(fudged.hair,0); pos1(vair,90);
222 pos2(fudged.stem,180); pos3(vair,270);
223 pos4(fudged.stem,-180); pos5(fudged.stem,-180);
224 pos6(vair,-90); pos7(fudged.hair,0);
225 pos8(vair,90); pos9(fudged.hair,180);
226 pos10(vair,270); pos11(.5[vair,flare],360);
227 x1=x3=.5[x0,x2]; y0=y2=.5[y1,y3];
228 x8=x10=.5w; y7=y9=.5[y8,y10];
229 lft x9r=hround u; x7=w-x9; top y8r=h+oo; bot y10r=-oo;
230 top y1r=vround(.8[y10,y8]+.5vair); bot y3r=vround(.2[y10,y8]-.5vair);
231 x6l=1/3[x5l,x7l]; y6=y3; y11=good.y(.1[y10,y8]-.5);
232 x0=x4=x5; y4=.8[y3,y1]; y5=2/3[y7,y6];
233 if hefty or monospace: lft x2r=hround(5u-.5fudged.stem);
234 rt x0r=hround(w-3u); x11r=x0r;
235 else: lft x2r=hround 3.4u; x0=w-x2; x11r=x7r; fi
236 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % left inner bowl
237 filldraw stroke super_arc.e(3,0) & super_arc.e(0,1); % right inner bowl
238 filldraw stroke super_arc.e(8,9) & super_arc.e(9,10)
239 & term.e(10,11,right,1,4); % left outer bowl and terminal
240 if hefty or monospace: {{interim superness:=hein_super;
241 filldraw stroke super_arc.e(0,8)}}; % link
242 else: (x,y6r)=whatever[z6l,z7l]; x6r:=x;
243 filldraw stroke z4e---z5e...z6e{right}...{up}z7e
244 & super_arc.e(7,8); fi % stem and link
245 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
246
247 cmchar "Left bracket";
248 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
249 beginchar("[",wd#,body_height#,paren_depth#);
250 italcorr body_height#*slant;
251 adjust_fit(0,0);
252 numeric top_thickness,side_thickness;
253 if hefty: top_thickness=vair;
254 side_thickness=max(crisp.breadth,stem-2stem_corr);
255 else: top_thickness=side_thickness=rule_thickness; fi;
256 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
257 top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
258 filldraw stroke z1e--z2e; % stem
259 pos3(top_thickness,90); pos4(top_thickness,90);
260 pos5(top_thickness,90); pos6(top_thickness,90);
261 x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
262 filldraw stroke z3e--z4e; % upper bar
263 filldraw stroke z5e--z6e; % lower bar
264 penlabels(1,2,3,4,5,6); endchar;
265
266 cmchar "Right bracket";
267 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
268 beginchar("]",wd#,body_height#,paren_depth#);
269 italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
270 adjust_fit(0,0);
271 numeric top_thickness,side_thickness;
272 if hefty: top_thickness=vair;
273 side_thickness=max(crisp.breadth,stem-2stem_corr);
274 else: top_thickness=side_thickness=rule_thickness; fi;
275 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
276 top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
277 filldraw stroke z1e--z2e; % stem
278 pos3(top_thickness,90); pos4(top_thickness,90);
279 pos5(top_thickness,90); pos6(top_thickness,90);
280 x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
281 filldraw stroke z3e--z4e; % upper bar
282 filldraw stroke z5e--z6e; % lower bar
283 penlabels(1,2,3,4,5,6); endchar;
284
285 cmchar "Straight single quote";
286 beginchar("`",5u#,asc_height#,0);
287 italcorr asc_height#*slant+.5 if serifs: flare# else: stem# fi -2u#;
288 adjust_fit(0,0);
289 x1=x2=.5w; y2=max(.5[bar_height,x_height]+.5vair,h-x_height);
290 if serifs: pickup crisp.nib; pos1(flare,0); pos2(vair,0);
291 y1+.5stem=h; filldraw circ_stroke z1e--z2e; % stem and bulb
292 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
293 top y1=h; filldraw stroke z1e--z2e; fi % stem
294 penlabels(1,2); endchar;
295