Debian Codegraph @

texmf-dist/fonts/source/public/chess/chessbase.mf

raw
1 % This is `chessbase.mf' version 1.0 as of 8/90
2 % METAfounded by Piet Tutelaers (internet: [email protected])
3
4 % In this file all pieces are defined.
5 % The points defining a piece are all in the unitsquare
6 % (0,0)--(0,1)--(1,1)--cycle.
7
8 def dark_square(expr D) =
9 clearit; L:=min(D/4, 9); delta:=1/L;
10 pickup fine_pen;
11 for i=1 upto min(D/4,9):
12 draw (0,delta*i*D)--(D-delta*i*D,D);
13 draw (delta*i*D,0)--(D,D-delta*i*D);
14 endfor;
15 draw (0,0)--(D,D);
16 enddef;
17
18 def erase_square(expr D, col, row) =
19 currentpicture:=board;
20 erase fill (0,0)--(0,1)--(1,1)--(1,0)--cycle scaled D shifted(col*D, row*D);
21 board:=currentpicture;
22 enddef;
23
24 def empty_board(expr D) =
25 picture board; path border;
26 border = ((0,0)--(1,0)--(1,1)--(0,1)--cycle);
27 dark_square(D); board:=nullpicture;
28 for i=0 upto M-1:
29 for j=0 upto M-1:
30 if not odd(i+j): addto board also currentpicture shifted (D*i,D*j) fi;
31 endfor
32 endfor;
33 clearit;
34 pickup border_pen;
35 draw border scaled (M*D);
36 addto board also currentpicture;
37 currentpicture:=board;
38 enddef;
39
40 def reflect(text t) =
41 forsuffixes $=t: z$'=z$ reflectedabout (z1,z2); endfor;
42 enddef;
43
44 def opr(suffix $) = (x$+thick#/d#, y$) enddef; % one point right
45 def opl(suffix $) = (x$-thick#/d#, y$) enddef; % one point left
46 def opu(suffix $) = (x$, y$+thick#/d#) enddef; % one point up
47 def opd(suffix $) = (x$, y$-thick#/d#) enddef; % one point down
48
49 vardef K(expr D, col, row) =
50 clearxy;
51 path cross_bar, crown, crown_top, crown_left, crown_right, crown_lower,
52 crown_top_inner, crown_left_inner, crown_right_inner;
53 def moved = scaled D shifted (col*D, row*D) enddef;
54
55 pickup thick_pen;
56 % draw cross
57 z1=(.5,.96); z2=(.5,.8); z11=(.42,.9); reflect(11);
58 cutdraw (z1--z2) moved; cutdraw (z11--z11') moved;
59 % top part of crown
60 z3=(.5,.38); z21=(.475,.5); z22=(.45,.575); z23=(.45,.775);
61 reflect(21,22,23);
62 crown_top= ((z3..z21..z22..z23..z2..z23'..z22'..z21'..z3) & cycle);
63 % left and right part
64 z31=z21; z32=z22; z33=(.32,.67); z34=(.13,.69); z35=(.07,.55);
65 z36=(.13,.45); z37=(.2,.34);
66 reflect(31, 32, 33, 34, 35, 36, 37);
67 crown_left=(z3..z31..z33..z34..z35..z36..z37);
68 crown_right=(z37'..z36'..z35'..z34'..z33'..z31'..z3);
69 % lower part of the crown
70 z6=(.5,.095); z61=(.27,.12); z62=(.2,.15); z63=(.21,.23);
71 reflect(61, 62, 63);
72 crown_lower= ((z37--z63) & (z63--z62) & (z62..z61..z6..z61'..z62') &
73 (z62'--z63') & (z63'--z37') & (z37'..z3..z37) & cycle);
74 % draw contour of crown
75 pickup thin_pen;
76 crown= crown_left & z37..z3..z37' & crown_right & cycle;
77 if background=dark: erase fill crown moved;
78 erase fill crown_top moved;
79 erase fill crown_lower moved;fi;
80 draw crown moved; draw crown_top moved;
81 if color=black:
82 z121=(.5,.5); z123=(.45,.675); z102=(.5,.77);
83 reflect(123);
84 crown_top_inner = (z121{curl 0}..z123..z102..z123'..{curl 0}z121 & cycle);
85 z131=(.45,.5); z133=(.32,.64); z134=(.13,.66); z135=(.10,.55);
86 z136=(.16,.45); z137=(.22,.36); z103=(.475,.4);
87 crown_left_inner= ((z103..z131..z133..z134..z135..z136..z137)
88 & (z137..{right}z103) & cycle);
89 crown_right_inner=crown_left_inner reflectedabout (z1,z2);
90 fill crown_top_inner moved;
91 fill crown_left_inner moved;
92 fill crown_right_inner moved;
93 fill crown_lower moved;
94 else: draw crown_lower moved;
95 fi;
96 % draw inner parts
97 z4=(.5,.28); z5=(.5,.21);
98 if color=white:
99 draw (z37..z3..z37') moved;
100 draw (z63..z4..z63') moved;
101 draw (z62..z5..z62') moved;
102 else: pickup thick_pen;
103 erase draw (opr(37)..z3..opl(37')) moved;
104 erase draw (opr(63)..z4..opl(63')) moved;
105 erase draw (opr(62)..z5..opl(62')) moved;
106 fi;
107 enddef;
108
109 vardef Q(expr D, col, row) =
110 clearxy;
111 path crown_top, crown, crown_lower;
112 def moved = scaled D shifted (col*D, row*D) enddef;
113
114 pickup thin_pen;
115 % top part of crown
116 z1=(.5,.92); z2=(.5,.5); z11=(.42,.46); z12=(.275,.88);
117 z13=(.25,.44); z14=(.075,.8); z15=(.125,.4);
118 reflect(11,12,13,14,15);
119 crown_top = (z15'--z14'--z13'--z12'--z11'--z1--z11--z12--z13--z14--z15);
120 % lower part of the crown
121 z6=(.5,.0775); z61=(.25,.1); z62=(.2,.125); z63=(.24,y62+1/3(y15-y62));
122 z64=(.2,y62+2/3(y15-y62));
123 reflect(61,62,63,64);
124 crown_lower= ((z15--z64) & (z64--z63) & (z63--z62) &
125 (z62..z61..z6..z61'..z62') & (z62'--z63') & (z63'--z64') &
126 (z64'--z15'));
127 % draw contour of crown
128 crown= (crown_top & crown_lower & cycle);
129 if background=dark:
130 if color=white: erase fill crown moved; fi; fi;
131 if color=white: draw crown moved;
132 forsuffixes $:=1,12,12',14,14':
133 erase fill (fullcircle scaled .1 shifted z$) moved;
134 draw (fullcircle scaled .1 shifted z$) moved; endfor;
135 else: fill crown moved;
136 forsuffixes $:=1,12,12',14,14':
137 fill (fullcircle scaled .1 shifted z$) moved; endfor; fi;
138 % draw inner parts
139 z3=(.5,y5+(y64-y62)); z4=(.5,y5+(y63-y62)); z5=(.5,.18);
140 if color=white: draw (z64..z3..z64') moved; draw (z63..z4..z63') moved;
141 draw (z62..z5..z62') moved;
142 z21=z11; z22=(.325,.475); z23=z13; z24=(.175,.44); z25=z15;
143 reflect(21,22,23,24,25);
144 draw ((z2..z21..z22) & (z22..z23..z24) & (z24--z25)) moved;
145 draw ((z2..z21'..z22') & (z22'..z23'..z24') & (z24'--z25')) moved;
146 else: pickup thick_pen;
147 erase draw (opr(64)..z3..opl(64')) moved;
148 erase draw (opr(63)..z4..opl(63')) moved;
149 erase draw (opr(62)..z5..opl(62')) moved;
150 fi;
151 enddef;
152
153 vardef R(expr D, col, row) =
154 clearxy;
155 path rook;
156 def moved = scaled D shifted (col*D, row*D) enddef;
157
158 pickup thin_pen;
159 % top part of rook
160 z1=(.5,.86); y15=y14=y11=y1; x15=x16=.21; x19=x20=.225; y13=y12=.8;
161 y16=.725; y17=.65; y18=.35; y19=.26; y20=y21=.175; y22=.1;
162 x22=x21=.175; x17=x18=.31; x13=x14=.325; x11=x12=.43; z2=(.5,.1);
163 reflect(11,12,13,14,15,16,17,18,19,20,21,22);
164 rook = (z11--z12--z13--z14--z15--z16--z17--z18--z19--z20--z21--z22--z22'
165 --z21'--z20'--z19'--z18'--z17'--z16'--z15'--z14'--z13'--z12'--z11'--cycle);
166 % draw contour of rook
167 if background=dark:
168 if color=white: erase fill rook moved; fi; fi;
169 if color=white: draw rook moved; else: fill rook moved; fi;
170 % draw inner parts
171 if color=white: draw (z16--z16') moved; draw (z17--z17') moved;
172 draw (z18--z18') moved; draw (z19--z19') moved;
173 draw (z20--z20') moved;
174 else: pickup thick_pen;
175 erase draw (opr(16)--opl(16')) moved;
176 erase draw (opr(17)--opl(17')) moved;
177 erase draw (opr(18)--opl(18')) moved;
178 erase draw (opr(19)--opl(19')) moved;
179 erase draw (opr(20)--opl(20')) moved; fi;
180 enddef;
181
182 vardef N(expr D, col, row) =
183 clearxy;
184 path knight, ear, eye, nose, mouth, neck;
185 def moved = scaled D shifted (col*D, row*D) enddef;
186
187 pickup thin_pen;
188 % the knight's contour
189 z1=(.5,.82); z2=(.5,.075); z11=(.45,.93); z12=(.375,.85); z13=(.25,.925);
190 z14=(.26,.8); z15=(.22,.75); z16=(.18,.7); z17=(.18,.66); z18=(.07,.42);
191 z19=(.07,.36); z20=(.14,.3); z21=(.17,.3); z22=(.175,.275); z23=(.225,.28);
192 z24=(.29,.38); z25=(.41,.46); z26=(.49,.51); z27=(.435,.295); z28=(.32,.165);
193 z29=(.31,y2); z30=(.93,y2); z31=(.87,.5); z32=(.7,.78);
194 knight = ((z1--z11--z12--z13--z14) &
195 (z14..z15..z16..z17..z18..z19..z20..z21) &
196 (z21..z22..z23..z24..z25..z26) &
197 (z26..z27..z28..z29) & (z29--z30) &
198 (z30..z31..z32..z1) &cycle);
199 % draw contour of knight
200 if color=white: erase fill knight moved;
201 draw knight moved;
202 else: fill knight moved; fi;
203 % draw inner parts
204 z4=(.22,.62); z41=(.25,.67); z42=(.29,.705); z43=(.31,.7); z44=(.3,.68);
205 eye = (z4..z41..z42..z43 & z43..z44..z4 & cycle);
206 z5=(.1,.36); z51=(.1,.39); z52=(.135,.43); z53=(.15,.4); z54=(.13,.38);
207 nose = (z5..z51..z52..z53..z54..z5 &cycle);
208 if color=white: z21'=(.2,.34); draw (z21'--z21) moved; %mouth
209 z26'=(.54,.63); draw (z26'..z26{z24-z26}) moved; %neck
210 draw (z12--z14) moved; % ear
211 fill eye moved; fill nose moved;
212 else: erase fill eye moved; erase fill nose moved; fi;
213 z30'=z30 + (-thick#/d#,thick#/d#); pickup thick_pen
214 erase draw (opd(1)..opd(32)..opl(31)..z30') moved; % mane
215 enddef;
216
217 vardef B(expr D, col, row) =
218 clearxy;
219 path top, hat, brim, mitre, stole;
220 def moved = scaled D shifted (col*D, row*D) enddef;
221
222 pickup thin_pen;
223 % the top circle
224 z1=(.5,.85); z2=(.5,.8);
225 top = (fullcircle scaled .1 shifted z1);
226 if color=white: erase fill top moved; draw top moved;
227 else: fill top moved; fi;
228 % the hat
229 z3=(.5,.43); z21=(.27,.57); z31=(.35,.4); reflect(21,31);
230 hat = (z31'..z21'..z2{(-1,1)}) & (z2{(-1,-1)}..z21..z31);
231 % the brim
232 z4=(.5,.33); z5=(.5,.23);
233 z41=(.32,.28); reflect(41);
234 brim = ((z31--z41) & (z41..z5..z41') & (z41'--z31'));
235 % the stole
236 z6=(.5,.15); z7=(.5,.3); z61=(.44,.12); z62=(.25,.1); z63=(.15,.05);
237 z64=(.09,.11); z65=(.25,.18); z66=(.44,.2);
238 reflect(61,62,63,64,65,66);
239 stole = ((z7..z66..z65..z64) & (z64--z63) & (z63..z62..z61..z6) &
240 (z6..z61'..z62'..z63') & (z63'--z64') & (z64'..z65'..z66'..z7) &cycle);
241 % the mitre
242 mitre = (hat & brim & cycle);
243 if background=dark:
244 if color=white: erase fill mitre moved;
245 erase fill stole moved; fi; fi;
246 if color=black: fill mitre moved; fill stole moved;
247 else: draw mitre moved; draw stole moved;
248 erase fill mitre moved; draw mitre moved; fi;
249
250 % inner parts of mitre
251 center:=.59; width:=.065;
252 if color=white: draw (z31..z3..z31') moved; draw (z41..z4..z41') moved;
253 draw ((.5,center-width)--(.5,center+width)) moved;
254 draw ((.5-width,center)--(.5+width,center)) moved;
255 else: pickup thick_pen;
256 erase cutdraw (opr(31)..z3..opl(31')) moved;
257 erase cutdraw (opr(41)..z4..opl(41')) moved;
258 erase cutdraw ((.5,center-width)--(.5,center+width)) moved;
259 erase cutdraw ((.5-width,center)--(.5+width,center)) moved;
260 fi;
261 enddef;
262
263 vardef p(expr D, col, row) =
264 clearxy;
265 path pawn;
266 def moved = scaled D shifted (col*D, row*D) enddef;
267
268 pickup thin_pen;
269 % the pawn's contour
270 z1=(.5,.9); z2=(.5,.1); z11=(.41,.85); z12=(.46,.73); z13=(.32,.6);
271 z14=(.41,.46); z15=(.3,.4); z16=(.2,.1);
272 reflect(11,12,13,14,15,16);
273 pawn = ((z12'..z11'..z1..z11..z12) &
274 (z12..z13..z14) &
275 (z14..z15..z16) &
276 (z16--z16') &
277 (z16'..z15'..z14') &
278 (z14'..z13'..z12') & cycle);
279
280 % draw contour of pawn
281 if background=dark:
282 if color=white: erase fill pawn moved; fi; fi;
283 if color=black: fill pawn moved;
284 else: draw pawn moved; fi;
285 enddef;