Debian Codegraph @

texmf-dist/fonts/source/public/bguq/bguq.mf

raw
1 % This file contains a single character, the Begriffsschrift
2 % universal quantifier (the code being the same as for the cm
3 % "blank space" symbol).
4 %
5 % $Id: bguq.mf,v 1.6 2012/07/22 23:12:01 jjg Exp $
6
7 % from mflogo/logo.mf, modified to have a variable superness
8
9 def super_half(suffix i,j,k)(expr s) =
10 draw z.i{0, y.j-y.i}
11 ... (s[x.j, x.i], s[y.i, y.j]){z.j-z.i}
12 ... z.j{x.k-x.i,0}
13 ... (s[x.j, x.k], s[y.k, y.j]){z.k-z.j}
14 ... z.k{0, y.k-y.j}
15 enddef;
16
17 mode_setup;
18
19 proofing := 2;
20 define_pixels(u);
21 define_pixels(bglt);
22
23 % The width 14.4u# is chosen so that at 10pt (where u=20/36)
24 % the width is 8pt, as in the original begriff quantifier.
25 % The depth is the same as for the descender for the base
26 % font (fraktur in this case)
27
28 beginchar(oct"040", 14.4u# - 2bglt#, 0, desc_depth#);
29
30 % the super value determines the shape of the bowl
31 % which is a superellipse:
32 % - at 1.000 is a rectangle,
33 % - at 0.707 (i.e., sqrt(2)/2) is an ellipse
34 % - at 0.500 is a diamond
35 % we use a value a little larger than 0.707 giving a
36 % stroke which is noticably squarer than an ellipse
37
38 numeric super;
39 super := 0.77;
40
41 y1 = y3 = bglt/2;
42 y2 + d = bglt/2;
43 x1 = w - x3 = -bglt/2;
44 x2 = w/2;
45
46 pickup pencircle scaled bglt;
47 super_half(1,2,3,super);
48
49 % clean off the ends of the (round pen) stroke
50
51 unfill
52 (x1-bglt/2,y1) --
53 (x3+bglt/2,y3) --
54 (x3+bglt/2,y3+bglt/2) --
55 (x1-bglt/2,y1+bglt/2) --
56 cycle;
57
58 penlabels(1,2,3);
59
60 endchar;
61
62 end
63
64 % fin
65