Debian Codegraph @

texmf-dist/fonts/source/public/beuron/beuronbuchst.mf

raw
1 % beuronbuchst.mf
2 % Die Buchstaben der Beuroner Kunst
3 % The letters of Beuronese art
4 % Autor: K. Wehr
5 % 1. November 2017
6 % U.I.O.G.D.
7
8 mode_setup;
9
10 Schriftgr# := 1cc#; % nominelle Schriftgröße
11 hoe# := 2/3Schriftgr#; % Höhe der Buchstaben
12
13 font_size Schriftgr#;
14 font_x_height 0.6hoe#;
15 font_quad 1.5hoe#;
16 font_normal_space f*2/3hoe#;
17 font_normal_stretch f*1/3hoe#;
18 font_normal_shrink f*1/6hoe#;
19
20
21 S# := 0.11hoe#; % Stiftbreite
22 define_pixels(S);
23
24 klAb# := f*1.0S#; % kleinstmöglicher Buchstabenabstand
25 grAb# := f*2.6S#; % größtmöglicher Buchstabenabstand
26 Ue:=0.2*S; % Überstand der Rundungen nach oben und unten
27
28 % Korrektur des solve-Makros, die Verschachtelungen erlaubt:
29 vardef save_solve@#(expr true_x,false_x) =
30 save tx_, fx_, x_;
31 tx_ := true_x;
32 fx_ := false_x;
33 forever:
34 x_ := 0.5[tx_,fx_];
35 exitif abs(tx_-fx_) <= tolerance;
36 if @#(x_): tx_ else: fx_ fi := x_;
37 endfor
38 x_
39 enddef;
40
41 % Bestimme z.i so, dass die Gerade durch z.i und z.j zur Parallelen durch z.k
42 % den Abstand S hat:
43 def bestimme_Parallelenpunkt_A(suffix i, j, k) =
44 % Überprüfe, ob der Abstand der Geraden durch z.i und z.j zur Parallelen
45 % durch z.k größer ist als S, wobei die unbekannte Koordinate von z.i durch
46 % das Argument ersetzt wird:
47 vardef Abstand_groesser_S(expr Wert) =
48 pair Lotfuss;
49 if (unknown x.i):
50 Lotfuss = whatever[z.j,(Wert,y.i)];
51 Lotfuss-z.k = whatever*((Wert,y.i)-z.j) rotated 90;
52 else:
53 Lotfuss = whatever[z.j,(x.i,Wert)];
54 Lotfuss-z.k = whatever*((x.i,Wert)-z.j) rotated 90;
55 fi
56 length(Lotfuss-z.k) > S
57 enddef;
58
59 if (unknown x.i):
60 x.i = save_solve Abstand_groesser_S(x.j,x.k);
61 else:
62 y.i = save_solve Abstand_groesser_S(y.j,y.k);
63 fi
64 enddef;
65
66 % Bestimme den Punkt z.i links von der Geraden durch z.j und z.k so,
67 % dass er von dieser Geraden den Abstand Ab hat:
68 def bestimme_Parallelenpunkt_B(suffix i, j, k)(expr Ab) =
69 pair Lotfuss;
70 Lotfuss = z.j+Ab*unitvector(z.k-z.j) rotated 90;
71 z.i-Lotfuss = whatever*(z.k-z.j);
72 enddef;
73
74
75 Avn# := klAb#; % Vor- und Nachbreite des A
76 Ab# := f*1.15hoe#+2Avn#; % Dickte des A
77 define_pixels(Avn);
78
79 beginchar("A",Ab#,hoe#,0); "Buchstabe A";
80 x1 = w-x4 = Avn;
81 x2 = w-x3;
82 y1 = y2 = y3 = y4 = 0;
83 z5 = (w/2,h-S);
84 x6 = w-x7;
85 y6 = y7 = h;
86 bestimme_Parallelenpunkt_A(6,1,5);
87 z5-z2 = whatever*(z6-z1);
88 fill z1--z2--z5--z3--z4--z7--z6--cycle;
89 picture ABild_teilweise, ABild;
90 ABild_teilweise := currentpicture;
91 z8 = 0.45[z2,z5];
92 x9 = w/2;
93 z10 = (w-x8,y8);
94 % Winkel, in dem der Mittelbalken zur Horizontalen verläuft:
95 Aalpha := 30;
96 z9 = z8+whatever*(dir(-Aalpha));
97 Abeta := angle(z5-z2);
98 penpos8(whatever,-180+Abeta);
99 penpos9(whatever,-90);
100 penpos10(whatever,-Abeta);
101 bestimme_Parallelenpunkt_B(8l,8,9)(S/2);
102 z9l-z8l = whatever*(z9-z8);
103 z10l-z9l = whatever*(z10-z9);
104 penstroke z8e--z9e--z10e;
105 penlabels(range 1 thru 10);
106 ABild := currentpicture;
107 endchar;
108
109
110 Pvor# := grAb#; % Vorbreite des P
111 Pnach# := 0.4[klAb#,grAb#]; % Nachbreite des P
112 Pb# := f*0.7hoe#+Pvor#+Pnach#; % Dickte des P
113 define_pixels(Pvor,Pnach);
114
115 beginchar("P",Pb#,hoe#,0); "Buchstabe P";
116 PBreite := w-Pvor-Pnach; % wird für das B und das R benötigt
117 pickup pensquare scaled S;
118 lft bot z1 = (Pvor,0);
119 lft top z2 = (Pvor,h);
120 draw z1--z2;
121 x3 = x1;
122 y3 = 0.5[y1,y2];
123 rt x4 = w-Pnach;
124 y4 = 0.5[y2,y3];
125 x5 = x6 = 0.5[x3,x4];
126 y5 = y3;
127 y6 = y2;
128 pickup pencircle scaled S;
129 draw z3---z5..z4..z6---z2;
130 labels(range 1 thru 6);
131 picture PBild;
132 PBild := currentpicture;
133 endchar;
134
135
136 Bvor# := grAb#; % Vorbreite des B
137 Bnach# := 0.5[klAb#,grAb#]; % Nachbreite des B
138 Bb# := f*0.85hoe#+Bvor#+Bnach#; % Dickte des B
139 define_pixels(Bvor,Bnach);
140
141 beginchar("B",Bb#,hoe#,0); "Buchstabe B";
142 pickup pensquare scaled S;
143 lft bot z1 = (Bvor,0);
144 lft top z2 = (Bvor,h);
145 draw z1--z2;
146 x3 = x1+2S;
147 y3 = y5 = y9 = 0.55[y1,y2];
148 x4-x2 = PBreite-S;
149 y4 = 0.5[y2,y3];
150 x5 = x6 = 0.5[x2,x4];
151 y6 = y2;
152 rt x7 = w-Bnach;
153 y7 = 0.5[y1,y3];
154 x8 = x9 = 0.5[x1,x7];
155 y8 = y1;
156 draw z3--z9;
157 draw z3--z5; % falls bei großer Stauchung z5 links von z3 liegt
158 pickup pencircle scaled S;
159 draw z1---z8..z7..{left}z9;
160 draw z2---z6..z4..{left}z5;
161 labels(range 1 thru 9);
162 picture BBild;
163 BBild := currentpicture;
164 endchar;
165
166
167 Ovn# := 0.3[klAb#,grAb#]; % Vor- und Nachbreite des O
168 Ob# := f*1.1hoe#+2Ovn#; % Dickte des O
169 define_pixels(Ovn);
170
171 beginchar("O",Ob#,hoe#,0); "Buchstabe O";
172 pickup pencircle scaled S;
173 lft x3 = Ovn;
174 rt x1 = w-Ovn;
175 x2 = x4 = w/2;
176 y1 = y3 = h/2;
177 top y2 = h+Ue;
178 bot y4 = -Ue;
179 OBreite := w-2Ovn; % wird für das Q benötigt
180 pair OUnten; % wird für das G benötigt
181 OUnten := z4;
182 def OSpannung = ..tension 0.93.. enddef;
183 path OPfad; % wird für das C und das G benötigt
184 OPfad := z1 OSpannung z2 OSpannung z3 OSpannung z4 OSpannung cycle;
185 draw OPfad;
186 labels(1,2,3,4);
187 picture OBild; % wird auch für das Q benötigt
188 OBild := currentpicture;
189 endchar;
190
191
192 Cvor# := Ovn#; % Vorbreite des C
193 Cnach# := 0.55[klAb#,grAb#]; % Nachbreite des C
194 Cb# := f*0.95hoe#+Cvor#+Cnach#; % Dickte des C
195
196 beginchar("C",Cb#,hoe#,0); "Buchstabe C";
197 pickup pencircle scaled S;
198 cutdraw subpath(0.5,3.5) of OPfad;
199 picture CBild;
200 CBild := currentpicture;
201 endchar;
202
203
204 Dvor# := grAb#;
205 Dnach# := 0.4[klAb#,grAb#];
206 Db# := f*0.95hoe#+Dvor#+Dnach#;
207 define_pixels(Dvor,Dnach);
208
209 beginchar("D",Db#,hoe#,0); "Buchstabe D";
210 pickup pensquare scaled S;
211 lft x1 = lft x2 = Dvor;
212 bot y1 = 0;
213 top y2 = h;
214 draw z1--z2;
215 rt x3 = w-Dnach;
216 y3 = 0.5[y1,y2];
217 x4 = x5 = 0.4[x1,x3];
218 y4 = y1;
219 y5 = y2;
220 pickup pencircle scaled S;
221 draw z1---z4..z3..z5---z2;
222 labels(range 1 thru 5);
223 picture DBild;
224 DBild := currentpicture;
225 endchar;
226
227
228 Evor# := 0.6[klAb#,grAb#];
229 Enach# := 0.4[klAb#,grAb#];
230 Eb# := f*0.8hoe#+Evor#+Enach#;
231 define_pixels(Evor,Enach);
232
233 beginchar("E",Eb#,hoe#,0); "Buchstabe E";
234 interim autorounding := 0;
235 EBreite := w-Evor-Enach; % Breite der Glyphe
236 pickup pencircle scaled S;
237 lft x5 = Evor;
238 lft x3 = Evor+1/8EBreite;
239 top y2 = h+0.5Ue;
240 bot y6 = -0.5Ue;
241 x2 = x4 = x6 = Evor+0.53EBreite;
242 x1-x2 = x2-x3;
243 x7-x6 = x6-x5;
244 y4 = 0.55[y6,y2];
245 y5 = y7 = 0.5[y6,y4];
246 y1 = y3 = 0.5[y4,y2];
247 path Eoben, Eunten;
248 Eoben = z1{up}..z2{left}..z3{down}..{right}z4;
249 Eunten = z4{left}..z5{down}..z6{right}..{up}z7;
250 cutdraw subpath(0.4,3.0) of Eoben;
251 cutdraw subpath(0,2.7) of Eunten;
252 labels(range 1 thru 7);
253 picture EBild;
254 EBild := currentpicture;
255 endchar;
256
257
258 Fvor# := grAb#;
259 Fnach# := 0.1[klAb#,grAb#];
260 Fb# := f*0.8hoe#+Fvor#+Fnach#;
261 define_pixels(Fvor,Fnach);
262
263 beginchar("F",Fb#,hoe#,0); "Buchstabe F";
264 pickup pensquare scaled S;
265 lft x1 = lft x2 = Fvor;
266 rt x3 = w-Fnach;
267 bot y1 = 0;
268 top y2 = top y3 = h;
269 z4 = 0.5[z1,z2];
270 x5 = 0.5[x2,x3];
271 y5 = y4;
272 draw z1--z2--z3;
273 draw z4--z5;
274 labels(range 1 thru 5);
275 picture FBild;
276 FBild := currentpicture;
277 endchar;
278
279
280 Gvor# := Ovn#;
281 Gnach# := 0.4[klAb#,grAb#];
282 Gb# := f*1.05*hoe#+Gvor#+Gnach#;
283 define_pixels(Gvor, Gnach);
284
285 beginchar("G",Gb#,hoe#,0); "Buchstabe G";
286 Galpha:=65; % Anfangswinkel in Punkt 1
287 pickup pencircle scaled S;
288 z4 = OUnten;
289 rt x3 = w-Gnach;
290 y3 = 0.35h;
291 x2 = Gvor+0.6(w-Gvor-Gnach);
292 y2 = 0.6h;
293 x1 = 0.5[Gvor+S/2,x2];
294 y1 = 0.25[y2,y4];
295 cutdraw subpath(0.5,3) of OPfad & z4{right}..z3{up}..z2{left}..{-dir(Galpha)}z1;
296 labels(range 1 thru 4);
297 picture GBild;
298 GBild := currentpicture;
299 endchar;
300
301
302 Hvn# := grAb#;
303 Hb# := f*0.95hoe#+2Hvn#;
304 define_pixels(Hvn);
305
306 beginchar("H",Hb#,hoe#,0); "Buchstabe H";
307 pickup pensquare scaled S;
308 lft x1 = lft x2 = Hvn;
309 rt x3 = rt x4 = w-Hvn;
310 bot y1 = bot y3 = 0;
311 top y2 = top y4 = h;
312 z5 = 0.5[z1,z2];
313 z6 = 0.5[z3,z4];
314 draw z1--z2;
315 draw z3--z4;
316 draw z5--z6;
317 labels(range 1 thru 6);
318 picture HBild;
319 HBild := currentpicture;
320 endchar;
321
322
323 Ib# := S#+2grAb#;
324
325 beginchar("I",Ib#,hoe#,0); "Buchstabe I";
326 pickup pensquare scaled S;
327 bot z1 = (0.5w,0);
328 top z2 = (0.5w,h);
329 draw z1--z2;
330 labels(1,2);
331 picture IBild;
332 IBild := currentpicture;
333 endchar;
334
335
336 Jvor# := 0.2[klAb#,grAb#];
337 Jnach# := 0.95[klAb#,grAb#];
338 Jb# := f*0.75hoe#+Jvor#+Jnach#;
339 define_pixels(Jvor,Jnach);
340
341 beginchar("J",Jb#,hoe#,0); "Buchstabe J";
342 interim autorounding := 0;
343 pickup pencircle scaled S;
344 lft x1 = Jvor;
345 y1 = y3 = 0.35h;
346 x2 = 0.5[x1,x3];
347 bot y2 = -Ue;
348 rt x3 = rt x4 = w-Jnach;
349 y4 = h;
350 cutdraw z1{down}..z2{right}..z3---z4;
351 labels(1,2,3,4);
352 picture JBild;
353 JBild := currentpicture;
354 endchar;
355
356
357 Kvor# := grAb#;
358 Knach# := 0.4[klAb#,grAb#];
359 Kb# := f*0.85hoe#+Kvor#+Knach#;
360 define_pixels(Kvor,Knach);
361
362 beginchar("K",Kb#,hoe#,0); "Buchstabe K";
363 pickup pensquare scaled S;
364 lft bot z1 = (Kvor,0);
365 lft top z2 = (Kvor,h);
366 x3 = x4 = rt x1;
367 y3 = h-y4;
368 x5 = x3+S;
369 y5 = 0.5[y1,y2];
370 x6 = x8;
371 x7 = x9 = w-Knach;
372 y6 = y7 = 0;
373 y8 = y9 = h;
374 bestimme_Parallelenpunkt_B(3,7,5)(S);
375 z8-z4 = whatever*(z9-z5);
376 draw z1--z2;
377 fill z4--z8--z9--z5--z7--z6--z3--cycle;
378 labels(range 1 thru 9);
379 picture KBild;
380 KBild := currentpicture;
381 endchar;
382
383
384 beginchar("L",Fb#,hoe#,0); "Buchstabe L";
385 pickup pensquare scaled S;
386 lft bot z1 = (Fvor,0);
387 lft top z2 = (Fvor,h);
388 rt bot z3 = (w-Fnach,0);
389 draw z1--z2;
390 draw z1--z3;
391 labels(1,2,3);
392 picture LBild;
393 LBild := currentpicture;
394 endchar;
395
396
397 Mvn# := grAb#;
398 Mb# := f*1.1hoe#+2Mvn#;
399 define_pixels(Mvn);
400
401 beginchar("M",Mb#,hoe#,0); "Buchstabe M";
402 pickup pensquare scaled S;
403 lft x1 = lft x2 = Mvn;
404 rt x3 = rt x4 = w-Mvn;
405 bot y1 = bot y3 = 0;
406 top y2 = top y4 = h;
407 x5 = x6 = 0.5w;
408 y5 = 0.45h;
409 x7 = x8 = rt x2;
410 x9 = x10 = lft x4;
411 y7 = y9;
412 y8 = y10 = h;
413 bestimme_Parallelenpunkt_A(7,5,8);
414 z8-z6 = whatever*(z7-z5);
415 draw z1--z2;
416 draw z3--z4;
417 fill z7--z5--z9--z10--z6--z8--cycle;
418 labels(range 1 thru 10);
419 picture MBild;
420 MBild := currentpicture;
421 endchar;
422
423
424 Nvn# := grAb#;
425 Nb# := f*1.05hoe#+2Nvn#;
426 define_pixels(Nvn);
427
428 beginchar("N",Nb#,hoe#,0); "Buchstabe N";
429 pickup pensquare scaled S;
430 lft x1 = lft x2 = Nvn;
431 rt x3 = rt x4 = w-Nvn;
432 bot y1 = bot y3 = 0;
433 top y2 = top y4 = h;
434 x5 = x6 = rt x2;
435 x7 = x8 = lft x3;
436 y6 = h;
437 y8 = 0;
438 y6-y5 = y7-y8;
439 bestimme_Parallelenpunkt_A(5,8,6);
440 draw z1--z2;
441 draw z3--z4;
442 fill z5--z6--z7--z8..cycle;
443 labels(range 1 thru 8);
444 picture NBild;
445 NBild := currentpicture;
446 endchar;
447
448
449 Qvor# := Ovn#;
450 Qnach# := 0.9klAb#;
451 Qb# := f*1.2hoe#+Qvor#+Qnach#;
452 define_pixels(Qvor,Qnach);
453
454 beginchar("Q",Qb#,hoe#,0); "Buchstabe Q";
455 currentpicture := OBild;
456 x4 = w-Qnach;
457 y3 = y4 = 0;
458 y1 = y2 = 0.35h;
459 (x3-x1)/OBreite = (y1-y3)/h;
460 x4-x2 = x3-x1;
461 bestimme_Parallelenpunkt_B(2,1,3)(S);
462 fill z1--z2--z4--z3--cycle;
463 labels(1,2,3,4);
464 picture QBild;
465 QBild := currentpicture;
466 endchar;
467
468
469 Rvor# := grAb#;
470 Rnach# := 0.2[klAb#,grAb#];
471 Rb# := f*0.9hoe#+Rvor#+Rnach#;
472 define_pixels(Rvor,Rnach);
473
474 beginchar("R",Rb#,hoe#,0); "Buchstabe R";
475 pickup pensquare scaled S;
476 lft x1 = lft x2 = Rvor;
477 bot y1 = 0;
478 top y2 = h;
479 x3 = x1+2S;
480 y3 = y5 = 0.5[y1,y2];
481 x4-x2 = PBreite-S;
482 y4 = 0.5[y2,y3];
483 x5 = x6 = 0.5[x2,x4];
484 y6 = y2;
485 bot y7 = 0;
486 x8 = w-Rnach;
487 z8 = z7+S/2*right;
488 draw z1--z2;
489 draw z3--z5;
490 pickup pencircle scaled S;
491 draw z2---z6..z4{down}..{left}z5;
492 interim autorounding := 0;
493 cutdraw z3{right}..z7---z8;
494 labels(range 1 thru 8);
495 picture RBild;
496 RBild := currentpicture;
497 endchar;
498
499
500 Svor# := 0.35[klAb#,grAb#];
501 Snach# := 0.5[klAb#,grAb#];
502 Sb# := f*0.8hoe#+Svor#+Snach#;
503 define_pixels(Svor,Snach);
504
505 beginchar("S",Sb#,hoe#,0); "Buchstabe S";
506 pickup pencircle scaled S;
507 x2 = x4 = x6 = Svor+0.5(w-Svor-Snach);
508 top y2 = h+1/4Ue;
509 bot y6 = -1/2Ue;
510 y4 = 0.55[y6,y2];
511 rt x5 = w-Snach;
512 x6-x7 = 1.2(x5-x6);
513 y5 = y7 = 0.5[y6,y4];
514 x4-x3 = 0.65(x5-x4);
515 x1-x2 = 1.2(x2-x3);
516 y1 = y3;
517 (y3-y4)/(y2-y4) = (y4-y5)/(y4-y6);
518 path SPfad;
519 SPfad = z1{up}..z2{left}..z3{down}..z4..z5{down}..z6{left}..{up}z7;
520 cutdraw subpath (0.3,5.75) of SPfad;
521 labels(range 1 thru 7);
522 picture SBild;
523 SBild := currentpicture;
524 endchar;
525
526
527 Tvn# := 0.1[klAb#,grAb#];
528 Tb# := f*0.95hoe#+2Tvn#;
529 define_pixels(Tvn);
530
531 beginchar("T",Tb#,hoe#,0); "Buchstabe T";
532 pickup pensquare scaled S;
533 bot z1 = (w/2,0);
534 top z2 = (w/2,h);
535 draw z1--z2;
536 Talpha = 30; % Neigungswinkel der Querstrichenden
537 penpos3(whatever,-90-Talpha);
538 penpos4(whatever,-90+Talpha);
539 x3r = w-x4r = Tvn;
540 y3l = y4l = h;
541 y3l-y3r = y4l-y4r = S;
542 penstroke z3e--z4e;
543 penlabels(1,2,3,4);
544 picture TBild;
545 TBild := currentpicture;
546 endchar;
547
548
549 beginchar("U",Ab#,hoe#,0); "Buchstabe U";
550 currentpicture := ABild_teilweise reflectedabout ((0,h/2),(w,h/2));
551 picture VBild;
552 VBild := currentpicture;
553 endchar;
554
555
556 beginchar("V",Ab#,hoe#,0); "Buchstabe V";
557 currentpicture := VBild;
558 endchar;
559
560
561 Wvn# := klAb#;
562 Wb# := f*1.8hoe#+2Wvn#;
563 define_pixels(Wvn);
564
565 beginchar("W",Wb#,hoe#,0); "Buchstabe W";
566 x1 = w-x4 = Wvn;
567 x2 = w-x3;
568 y1 = y2 = y3 = y4 = h;
569 x5 = w-x6;
570 y5 = y6 = 0.8h;
571 z7 = (1/2w,y5-S);
572 x8 = w-x9;
573 y8 = y9 = S;
574 x10 = w-x13;
575 x11 = w-x12;
576 y10 = y11 = y12 = y13 = 0;
577 vardef linker_Winkel_groesser(expr xWert) =
578 x8' := xWert;
579 y8' := y8;
580 x5' := whatever;
581 y5' := y5;
582 x10' := whatever;
583 y10' := y10;
584 bestimme_Parallelenpunkt_A(10',1,8');
585 bestimme_Parallelenpunkt_A(5',8',7);
586 180-angle(z1-z10') > angle(z5'-z8')
587 enddef;
588 x8 = save_solve linker_Winkel_groesser(x1+S,x7-S);
589 bestimme_Parallelenpunkt_A(10,1,8);
590 bestimme_Parallelenpunkt_A(5,8,7);
591 z2-z8 = whatever*(z1-z10);
592 z11-z7 = whatever*(z5-z8);
593 fill z1--z2--z8--z5--z6--z9--z3--z4--z13--z12--z7--z11--z10--cycle;
594 labels(range 1 thru 13);
595 picture WBild;
596 WBild := currentpicture;
597 endchar;
598
599
600 Xvn# := Knach#;
601 XBreite# := f*1.05hoe#;
602 Xb# := XBreite#+2Xvn#;
603 define_pixels(Xvn);
604
605 beginchar("X",Xb#,hoe#,0); "Buchstabe X";
606 y1 = y2 = y3 = y4 = 0;
607 y5 = y6 = y7 = y8 = h;
608 x1 = x5 = w-x4 = w-x8 = Xvn;
609 x2 = x6 = w-x3 = w-x7;
610 bestimme_Parallelenpunkt_A(7,1,8);
611 fill z1--z2--z8--z7--cycle;
612 fill z3--z4--z6--z5--cycle;
613 z9 = whatever[z4,z6] = whatever[z1,z7]; % Hilfspunkt für das Y
614 Xmh = y9;
615 labels(range 1 thru 9);
616 picture XBild;
617 XBild := currentpicture;
618 endchar;
619
620
621 Yvn# := klAb#;
622 Yb# := XBreite#+2Yvn#;
623 define_pixels(Yvn);
624
625 beginchar("Y",Yb#,hoe#,0); "Buchstabe Y";
626 pickup pensquare scaled S;
627 x1 = w-x4 = Yvn;
628 x2 = w-x3;
629 y1 = y2 = y3 = y4 = h;
630 x5 = x6 = x7 = x8 = 0.5w;
631 y5 = Xmh;
632 bestimme_Parallelenpunkt_A(3,5,4);
633 z6-z1 = whatever*(z5-z2);
634 bot y7 = 0;
635 top y8 = y5;
636 fill z1--z6--z4--z3--z5--z2--cycle;
637 draw z7--z8;
638 labels(range 1 thru 8);
639 picture YBild;
640 YBild := currentpicture;
641 endchar;
642
643
644 Zvn# := 0.6[klAb#,grAb#];
645 Zb# := f*1.0hoe#+2Zvn#;
646 define_pixels(Zvn);
647
648 beginchar("Z",Zb#,hoe#,0); "Buchstabe Z";
649 pickup pensquare scaled S;
650 lft x1 = lft x3 = Zvn;
651 rt x2 = rt x4 = w-Zvn;
652 bot y1 = bot y2 = 0;
653 top y3 = top y4 = h;
654 draw z1--z2;
655 draw z3--z4;
656 x5 = lft x1;
657 x8 = rt x4;
658 y5 = y6 = top y1;
659 y7 = y8 = bot y3;
660 x8-x7 = x6-x5;
661 bestimme_Parallelenpunkt_A(7,5,8);
662 fill z5--z6--z8--z7--cycle;
663 labels(range 1 thru 8);
664 picture ZBild;
665 ZBild := currentpicture;
666 endchar;
667
668
669 Tzb# := f*1.0hoe#; % Dickte des Trennzeichens (Mittenpunkt)
670
671 beginchar("/",Tzb#,hoe#,0); "Worttrennung";
672 pickup pencircle scaled 1.5S;
673 z1 = (w/2,h/2);
674 drawdot z1;
675 endchar;
676
677
678 beginchar(":",1.4Tzb#,hoe#,0); "Doppelpunkt";
679 pickup pencircle scaled 1.5S;
680 x1 = x2 = w/2;
681 y1 = h-y2 = 0.3h;
682 drawdot z1;
683 drawdot z2;
684 endchar;
685
686
687 Krvn# := 1.5grAb#; % Vor- und Nachbreite des Kreuzzeichens (+)
688 Krhoe# := 0.65hoe#; % Höhe und Breite des Kreuzzeichens
689 Krb# := Krhoe#+2Krvn#; % Dickte des Kreuzzeichens
690 define_pixels(Krhoe);
691
692 beginchar("+",Krb#,hoe#,0); "Kreuz";
693 pickup pensquare scaled S;
694 x1 = x2 = w/2;
695 y2 = h-y1;
696 x4 = w-x3;
697 y3 = y4 = h/2;
698 rt x4-lft x3 = top y2-bot y1 = Krhoe;
699 draw z1--z2;
700 draw z3--z4;
701 labels(1,2,3,4);
702 endchar;
703
704
705 Bsvn# := 0.4[klAb#,grAb#]; % Vor- und Nachbreite des Bindestrichs
706 Bsb# := f*0.5hoe#+2Bsvn#; % Dickte des Bindestrichs
707 define_pixels(Bsvn);
708
709 beginchar("-",Bsb#,hoe#,0); "Bindestrich";
710 %x1r = Bsvn;
711 %x2l = w-Bsvn;
712 %y1 = y2 = h/2;
713 %penpos1(whatever,-90-Talpha);
714 %penpos2(whatever,-90-Talpha);
715 %y1l-y1r = y2l-y2r = S;
716 %penstroke z1e--z2e;
717 %penlabels(1,2);
718 pickup pensquare scaled S;
719 lft x1 = w-rt x2 = Bsvn;
720 y1 = y2 = h/2;
721 draw z1--z2;
722 endchar;
723
724
725 % Griechisches Omega
726 Omegavn# := Ovn#; % Vor- und Nachbreite des Omega
727 Omegab# := f*1.1hoe#+2Omegavn#; % Dickte des Omega
728 define_pixels(Omegavn);
729
730 beginchar(141,Omegab#,hoe#,0); "Griechischer Buchstabe Omega";
731 pickup pensquare scaled S;
732 lft x1 = w-rt x9 = Omegavn+S/3;
733 bot y1 = 0;
734 y1 = y2 = y8 = y9;
735 x2-x1 = x9-x8 = 0.25(w-2Omegavn);
736 x3 = x2;
737 x7 = x8;
738 y3 = y7 = 1/5h;
739 x5 = 0.5w;
740 top y5 = h+Ue;
741 lft x4 = w-rt x6 = Omegavn;
742 y4 = y6 = 0.52[y3,y5];
743 z3h = z3+S/2*right;
744 z7h = z7+S/2*left;
745 draw z1--z2--z3;
746 draw z7--z8--z9;
747 % Winkel, in dem die Rundung beginnt:
748 Omegawinkel := 15;
749 pickup pencircle scaled S;
750 draw z3h{dir(180-Omegawinkel)}..z4{up}..z5..z6{down}..{dir(180+Omegawinkel)}z7h;
751 pickup pencircle scaled 1.1S;
752 cutoff(z3h,0);
753 cutoff(z7h,180);
754 labels(range 1 thru 9,3h,7h);
755 endchar;
756
757 beginchar("a",Ab#,hoe#,0); "Buchstabe a";
758 currentpicture := ABild;
759 endchar;
760
761 beginchar("b",Bb#,hoe#,0); "Buchstabe b";
762 currentpicture := BBild;
763 endchar;
764
765 beginchar("c",Cb#,hoe#,0); "Buchstabe c";
766 currentpicture := CBild;
767 endchar;
768
769 beginchar("d",Db#,hoe#,0); "Buchstabe d";
770 currentpicture := DBild;
771 endchar;
772
773 beginchar("e",Eb#,hoe#,0); "Buchstabe e";
774 currentpicture := EBild;
775 endchar;
776
777 beginchar("f",Fb#,hoe#,0); "Buchstabe f";
778 currentpicture := FBild;
779 endchar;
780
781 beginchar("g",Gb#,hoe#,0); "Buchstabe g";
782 currentpicture := GBild;
783 endchar;
784
785 beginchar("h",Hb#,hoe#,0); "Buchstabe h";
786 currentpicture := HBild;
787 endchar;
788
789 beginchar("i",Ib#,hoe#,0); "Buchstabe i";
790 currentpicture := IBild;
791 endchar;
792
793 beginchar("j",Jb#,hoe#,0); "Buchstabe j";
794 currentpicture := JBild;
795 endchar;
796
797 beginchar("k",Kb#,hoe#,0); "Buchstabe k";
798 currentpicture := KBild;
799 endchar;
800
801 beginchar("l",Fb#,hoe#,0); "Buchstabe l";
802 currentpicture := LBild;
803 endchar;
804
805 beginchar("m",Mb#,hoe#,0); "Buchstabe m";
806 currentpicture := MBild;
807 endchar;
808
809 beginchar("n",Nb#,hoe#,0); "Buchstabe n";
810 currentpicture := NBild;
811 endchar;
812
813 beginchar("o",Ob#,hoe#,0); "Buchstabe o";
814 currentpicture := OBild;
815 endchar;
816
817 beginchar("p",Pb#,hoe#,0); "Buchstabe p";
818 currentpicture := PBild;
819 endchar;
820
821 beginchar("q",Qb#,hoe#,0); "Buchstabe q";
822 currentpicture := QBild;
823 endchar;
824
825 beginchar("r",Rb#,hoe#,0); "Buchstabe r";
826 currentpicture := RBild;
827 endchar;
828
829 beginchar("s",Sb#,hoe#,0); "Buchstabe s";
830 currentpicture := SBild;
831 endchar;
832
833 beginchar("t",Tb#,hoe#,0); "Buchstabe t";
834 currentpicture := TBild;
835 endchar;
836
837 beginchar("u",Ab#,hoe#,0); "Buchstabe u";
838 currentpicture := VBild;
839 endchar;
840
841 beginchar("v",Ab#,hoe#,0); "Buchstabe v";
842 currentpicture := VBild;
843 endchar;
844
845 beginchar("w",Wb#,hoe#,0); "Buchstabe w";
846 currentpicture := WBild;
847 endchar;
848
849 beginchar("x",Xb#,hoe#,0); "Buchstabe x";
850 currentpicture := XBild;
851 endchar;
852
853 beginchar("y",Yb#,hoe#,0); "Buchstabe y";
854 currentpicture := YBild;
855 endchar;
856
857 beginchar("z",Zb#,hoe#,0); "Buchstabe z";
858 currentpicture := ZBild;
859 endchar;
860
861 input beuronkern;
862
863 end