Debian Codegraph @

texmf-dist/fonts/source/public/bbm/blbordl.mf

raw
1 % Copyright 1993 Gilles F. Robert.
2 % You may freely use, modify and/or distribute this file.
3 % This statement added 2008/11/14 by Clea F. Rees on the basis of the email exchange archived at http://lists.debian.org/debian-tex-maint/2008/05/msg00040.html.
4 %
5 % Computer Modern Blackboard lower case:
6 % Was romanl.mf; modified for blackboard letter
7 % Gilles F. ROBERT (29-03-93) v1.0
8
9 % These letters were originally coded by D. E. Knuth in November, 1979,
10 % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
11 % Sans serif designs by Richard Southall were added in April, 1982.
12 % The programs were revised for the new \MF\ conventions in 1985.
13 % modified March 93 by Gilles F. ROBERT for blackboard letters
14
15 % Character codes \0141 through \0172 are generated.
16
17 cmchar "The letter a";
18 beginchar("a",9u#,x_height#,0);
19 bh#:=min(bar_height#,1.14x_height#-bar_height#); define_pixels(bh);
20 italcorr 1/3[bh#,x_height#]*slant+.5stem#-serif_fit#-2u#;
21 adjust_fit(0,serif_fit# if serifs: if hair#+.5stem#>1.5u#:-.25u# fi\\fi);
22 pickup fine.nib; top y3r=h+vround 1.5oo;
23 if serifs: pos1(flare,180); pos2(hair,180);
24 pos3(vair,90); lft x1r=hround max(u,2.1u-.5flare); x3=.5w-.5u;
25 y1=min(bh+.5flare+2vair+2,.9[bh,h]-.5flare);
26 bulb(3,2,1); % bulb
27 else: pos1(5/7[vair,flare],95); x1l=good.x 1.5u; x1r:=good.x x1r;
28 pos3(1/8[vair,thin_join],90);
29 x3=.5w-.2u; top y1r=vround .82[bh,top y3r];
30 filldraw stroke term.e(3,1,left,.9,4); fi % terminal
31 pos4(stem,0); rt x4r=hround(w-2.5u+.5stem); y4=1/3[bh,h];
32 pos5(stem,0); x5=x4; y5=max(.55bh,2vair);
33 filldraw stroke super_arc.e(3,4)&z4e..z5e; % arc and stem
34 pen_duplicate(7);
35 pos6(.3[thin_join,vair],90); x6=x4; bot y6=bh;
36 pos7(hround(.5curve-stem_corr),180);
37 lft x.G7r=hround max(.5u,1.5u-.5curve); y7=1/3[top y8l,top y6r];
38 pos8(vair,270); x8l=.5w-.75u; bot y8r=-oo;
39 pos9(thin_join,360); z9l=z5l;
40 (x,y8r)=whatever[z8l,z9l]; x8r:=max(x,x8-u);
41 {{interim superness:=more_super;
42 filldraw stroke z9e{down}...z8e{left}...{up}z.G7e&super_arc.e(G7,6)}}; % bowl
43 Delta_x = min(hround(curve_interspace+.5curve-stem_corr),.5(x9r-x.G7l));
44 define_upper_and_lower(D6,D8,D7,{{interim superness:=more_super;
45 z9r{down}...z8r{left}...{up}z.G7r&super_arc.r(G7,6)}});
46 filldraw stroke z.D6e--z.D8e; % inner stroke
47 if serifs: numeric shaved_stem; shaved_stem=hround(stem-3stem_corr);
48 if hair#+.5stem#>1.5u#: pickup tiny.nib;
49 pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
50 pos10(shaved_stem,0); x10=x5'; y10=.2[.5tiny,bh];
51 pos11(shaved_stem,0); rt x11r=hround(w-.25u); bot y11=0;
52 pos12(shaved_stem,0); x11=x12; top y12=slab+eps;
53 filldraw z5'l---z10l...z11l{right}--z11r
54 --z12r{left}...z10r+.75(z12-z11)---z5'r--cycle; % foot
55 else: pickup crisp.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
56 pos10(shaved_stem,0); x10=x5'; y10=1/3bh;
57 pos11(.2[vair,stem],90); x11r=.5[x10r,x12r]; bot y11l=-vround .5oo;
58 pos12(hair,180); rt x12l=hround(w-.1u); y12=max(y10,y11+vair);
59 pos13(hair,180); x13=x12; top y13=max(vround .6bh,top y12);
60 (x',y11l)=whatever[z11r,z12r]; x11l:=max(x',x10);
61 filldraw stroke z5'e---z10e...z11e{right}...z12e---z13e; fi % hook
62 else: numeric shaved_stem; shaved_stem=hround(stem-stem_corr);
63 pickup tiny.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
64 pos10(shaved_stem,0); x10=x5'; bot y10=0;
65 filldraw stroke z5'e--z10e; fi % base of stem
66 penlabels(1,2,3,4,5,6,G7,8,D6,D7,D8,9,10,11,12,13); endchar;
67
68 cmchar "The letter b";
69 beginchar("b",10u#+serif_fit#,asc_height#,0);
70 italcorr .5x_height#*slant+min(.5curve#-u#,-.25u#);
71 adjust_fit(serif_fit#,0);
72 pen_duplicate(0,0',1,2);
73 pickup tiny.nib; pos1(.5stem',0); pos2(.5stem,0);
74 pos0'(.5stem',0); pos0(.5stem,0); z0l=z0'l; x0'=x1; x0=x2;
75 lft x.G1l=hround(2.5u-.5stem'); top y1=h;
76 Delta_x = hround(interspace+.5stem);
77 numeric edge; edge=rt x.D2r;
78 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
79 pos4(vair,90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
80 rt x3l=max(rt x3l-(lft x3r-tiny.lft x.D2l),1/3[rt x.D2,edge]);
81 y3=1/8[bar_height,x_height];
82 x4l=w-.5(w-serif_fit-interspace)+.5u; top y4r=x_height+oo;
83 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
84 x6l=x4l-.2u; bot y6r=-oo;
85 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
86 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x4,x5r]);
87 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x6,x5r]);
88 filldraw stroke z3e{up}...pulled_arc.e(4,5)&pulled_arc.e(5,6)...{up}z7e; % bowl
89 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
90 y2=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{left}...{up}z7l));
91 pickup tiny.nib; double filldraw stroke z1e--z0'e--z0e--z2e; % double stem
92 pickup crisp.nib; pos8(hair,0); pos7'(stem+interspace,0);
93 z7'=z2; x8l=x7'l; bot y8=0;
94 filldraw stroke z7'e--z8e; % point
95 if serifs: sloped_biserif.l(1,0',a,1/3,jut,serif_drop,a',1/3); % upper serif
96 mid_biserif(2,0',b,1/3); % lower serif
97 else: mid_biserif(1,0',a,1/3); fi % upper terminal
98 penlabels(G0,D0,G1,D1,G2,D2,3,4,5,6,7,8); endchar;
99
100 cmchar "The letter c";
101 beginchar("c",8u#,x_height#,0);
102 italcorr x_height#*slant-.2u#;
103 adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
104 pen_duplicate(3);
105 pickup fine.nib; pos2(vair',90); pos4(vair',270);
106 x2=x4=.5(w+u); top y2r=vround(h+1.5oo); bot y4r=-oo;
107 pos3(.5curve,180); lft x.G3r=hround max(.6u,1.35u-.5curve); y3=.5h;
108 Delta_x = min(hround(curve_interspace+.5curve),x2r-x.G3l);
109 if serifs: pos1(hair,0); pos0(flare,0);
110 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,h]-.5flare);
111 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
112 pos5(hair,0); rt x5r=hround(w-.5u);
113 y5=max(good.y(.5bar_height-.9),y4l+vair');
114 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
115 filldraw stroke pulled_super_arc.e(2,G3)(.7superpull)
116 & pulled_super_arc.e(G3,4)(.5superpull)
117 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
118 else: pos1(4/7[vair',flare],80);
119 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
120 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
121 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
122 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
123 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
124 if angle direction 1 of p.e>75:
125 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
126 filldraw stroke pulled_super_arc.e(2,G3)(.7superpull)
127 & pulled_super_arc.e(G3,4)(.5superpull) & p.e; fi % arc and lower terminal
128 define_upper_and_lower(D2,D4,D3,
129 pulled_super_arc.r(2,G3)(.7superpull) & pulled_super_arc.r(G3,4)(.5superpull));
130 filldraw stroke z.D2e--z.D4e; % inner stroke
131 penlabels(0,1,2,G3,4,D2,D3,D4,5); endchar;
132
133 cmchar "The letter d";
134 beginchar("d",10u#+serif_fit#,asc_height#,0);
135 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
136 adjust_fit(0,serif_fit#);
137 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
138 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
139 rt x1r=hround(w-2.5u+.5stem'); top y1=h;
140 numeric edge; edge=lft x2l;
141 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
142 pen_duplicate(5);
143 pos4(vair,90); pos5(.5curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
144 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),1/3[lft x2,edge]);
145 y3=1/8[bar_height,x_height];
146 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
147 lft x.G5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
148 x6l=x4l-.2u; bot y6r=-oo;
149 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
150 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x.G5r,x4]);
151 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x.G5r,x6]);
152 filldraw stroke z3e{up}...pulled_arc.e(4,G5)
153 & pulled_arc.e(G5,6)...{up}z7e; % bowl
154 Delta_x = min(hround(curve_interspace+.5curve),x6r-x.G5l);
155 define_upper_and_lower(D4,D6,D5,
156 z3r{up}...pulled_arc.r(4,G5) & pulled_arc.r(G5,6)...{up}z7r);
157 filldraw stroke z.D4e--z.D6e; % inner stroke
158 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
159 pickup tiny.nib; bot y2=if serifs:-min(oo,serif_drop) else: 0 fi;
160 filldraw stroke z1e--z0'e--z0e--z2e; % stem
161 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
162 sloped_serif.r(2,0,b,1/3,jut,min(oo,serif_drop)); fi % lower serif
163 penlabels(0,1,2,3,4,G5,6,D4,D5,D6,7); endchar;
164
165 cmchar "The letter e";
166 beginchar("e",7.25u#+max(.75u#,.5curve#),x_height#,0);
167 italcorr .5[bar_height#,x_height#]*slant+.5min(curve#-1.5u#,0);
168 adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
169 numeric left_curve,right_curve;
170 left_curve=right_curve+6stem_corr=curve if not serifs: -3stem_corr fi;
171 if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
172 if .5left_curve<tiny.breadth: left_curve:=2tiny.breadth; fi
173 pen_duplicate(3);
174 pickup tiny.nib; pos1(right_curve,0);
175 pos2(vair,90); pos3(.5left_curve,180);
176 y1=good.y bar_height; top y2r=h+vround 1.5oo; y0l=bot y1;
177 rt x1r=hround min(w-.5u,w-u+.5right_curve);
178 lft x.G3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
179 {{interim superness:=more_super;
180 filldraw stroke super_arc.e(1,2)}}; % right bowl
181 y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
182 Delta_x = min(hround(curve_interspace+.5curve),x2r-x.G3l);
183 if serifs: pos4(vair',270); pos5(hair,360);
184 y5=max(good.y(.5bar_height-.9),y4l+vair); x5r=x1r;
185 (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
186 filldraw stroke pulled_arc.e(2,G3) & pulled_arc.e(G3,4)
187 ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
188 define_upper_and_lower(D2,D4,D3,pulled_arc.r(2,G3) & pulled_arc.r(G3,4));
189 filldraw stroke z.D2e--z.D4e; % inner stroke
190 else: pos4(vair,270);
191 filldraw stroke super_arc.e(2,G3) & super_arc.e(G3,4); % left bowl and arc
192 define_upper_and_lower(D2,D4,D3,super_arc.r(2,G3) & super_arc.r(G3,4));
193 filldraw stroke z.D2e--z.D4e; % inner stroke
194 pickup fine.nib; pos4'(vair,270); z4=z4';
195 pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
196 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
197 filldraw stroke term.e(4',5,right,1,4); fi % terminal
198 y1'r=y0r=y0l+.6[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
199 forsuffixes $=l,r:
200 x0$=x.D3r; endfor
201 fill stroke z0e--z1'e; % crossbar
202 penlabels(0,1,2,G3,4,D2,D3,D4,5); endchar;
203
204 cmchar "The letter f";
205 beginchar("f",5.5u#,asc_height#,0);
206 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
207 adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
208 pen_duplicate(1);
209 pickup tiny.nib; pos1(.5stem',0); lft x.G1l=hround(2.5u-.5stem');
210 pickup fine.nib; numeric bulb_diam;
211 if serifs: bulb_diam=hround .8[stem,flare];
212 pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
213 if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
214 else: pos2(5/7[vair,flare],90); top y2r=h;
215 rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
216 f_double_stroke(1,2,a,b,bc,c,jut,if not monospace:1.25fi\\ jut); % double stem, terminal, serif
217 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
218 pos3(bar,90); pos4(bar,90);
219 rt x4=hround(w-if monospace:.75u+1 else:1/3u fi);
220 filldraw stroke z3e--z4e; % bar
221 penlabels(G1,D1,2,3,4); endchar;
222
223 iff not variant_g: cmchar "The letter g";
224 beginchar("g",9u#,x_height#,desc_depth#);
225 italcorr x_height#*slant+.25u#;
226 adjust_fit(0,0);
227 numeric light_vair,light_curve,loop_top,loop_side;
228 light_vair=Vround(.5[thin_join,vair]+vair_corr);
229 light_curve=max(fine.breadth,hround(curve-3stem_corr));
230 light_curve'=max(4fine.breadth/3,hround(curve-3stem_corr));
231 loop_top=Vround .77[vair,fudged.stem];
232 loop_side=hround .64[vair,fudged.stem];
233 pickup fine.nib; pos1(light_vair,90);
234 pen_duplicate(2);
235 pos2(.5light_curve',180); pos3(light_vair,270);
236 pos4(light_curve,360); pos11(loop_top,90);
237 y11r=good.y(y11r+.15bar_height-y11); x1=x3=.5[x.G2,x4]; y2=y4=.5[y1,y3];
238 lft x.G2r=hround(1.75u-.375light_curve'); rt x4r=hround(w-2.75u+.5light_curve);
239 top y1r=h+oo; y3r=good.y(y3r+.27[top y11r,bot y1l]-y3);
240 filldraw stroke pulled_arc.e(1,G2) & pulled_arc.e(G2,3); % left half of bowl
241 filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,1); % right half of bowl
242 Delta_x = min(hround(curve_interspace+.5light_curve'),x1r-x.G2l);
243 define_upper_and_lower(D1,D3,D2,pulled_arc.r(1,G2) & pulled_arc.r(G2,3));
244 filldraw stroke z.D1e--z.D3e; % inner stroke
245 x0=superness[x1r,x4r]; y0=superness[y4r,y1r]; % NE point on the super bowl
246 x8'=superness[x3r,x.G2r]; y8'=superness[y.G2r,y3r]; % SW point on the super bowl
247 x8''=superness[x3,x.G2]; y8''=superness[y.G2,y3];
248 pos0(thin_join,angle(z0-z8')+90);
249 pos8(thin_join,angle(z0-z8')-90); z8=.618[z8',z8''];
250 if serifs: pos5(vair,90);
251 pos6(hair,0); pos7(.5[hair,flare],0); x5=.75[x0,x6]; top y5r=h+o;
252 rt x6r=hround(w-.25u); y6+(.5[hair,flare])/2=.95[bar_height,h]+oo;
253 filldraw stroke z0e..{right}z5e; bulb(5,6,7); % ear
254 else: pos5(vair',100); top y5r=h+oo;
255 rt x5l=hround(w-.25u); y5l:=good.y y5l;
256 filldraw z0l{z5-z0}..z5l--z5r{left}..{curl 1}z0r--cycle; fi % ear
257 pos10(loop_top,90); x10=x8+.75u; y10=y11;
258 pos12(loop_side,0); pos13(light_vair,-90);
259 pos14(loop_side,-180); pos10'(.5[thin_join,vair],-270);
260 rt x12r=hround max(w-1.25u+.5loop_side,w-.5u); y12=y14=.5[y11,y13];
261 x11=x13=max(.5w,x10+eps); bot y13r=-d-oo-1; x14=w-x12; z10'l=z10l;
262 filldraw stroke z8e{z8-z0}..z10e---z11e; % link
263 filldraw stroke {{interim superness:=hein_super; super_arc.e(11,12)}}
264 & super_arc.e(12,13) & super_arc.e(13,14) & super_arc.e(14,10'); % loop
265 penlabels(0,1,G2,3,D1,D2,D3,4,5,6,7,8,10,11,12,13,14); labels(8',8''); endchar;
266
267 iff variant_g: cmchar "Variant letter g";
268 beginchar("g",10u#+serif_fit#,x_height#,desc_depth#);
269 italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
270 adjust_fit(0,serif_fit# if serifs: -.5u# fi);
271 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
272 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
273 rt x1r=hround(w-2.5u+.5stem');
274 numeric edge; edge=lft x2l;
275 path edge_path; edge_path=(edge,h)--(edge,0);
276 pen_duplicate(5);
277 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
278 pos4(vair,90); pos5(.5curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
279 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
280 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
281 lft x.G5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
282 x6l=x4l-.2u; bot y6r=vround 1/3vair;
283 lft x7l=edge; y7=min(y3,y6+y4-y3+.6vair);
284 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x.G5r,x4]);
285 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x.G5r,x6]);
286 filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,G5)
287 &super_arc.e(G5,6)&z6e{right}...{up}z7e; % bowl
288 Delta_x = min(hround(curve_interspace+.5curve),x6r-x.G5l);
289 define_upper_and_lower(D4,D6,D5,super_arc.r(4,G5) & super_arc.r(G5,6));
290 filldraw stroke z.D4e--z.D6e; % inner stroke
291 y1=ypart(edge_path intersectionpoint(z3l{up}...{left}z4l));
292 y0=ypart(edge_path intersectionpoint(z7l{down}...{left}z6l));
293 pickup tiny.nib; bot y2=if serifs: -.25d else: 0 fi;
294 filldraw stroke z1e--z0'e--z0e--z2e; % stem
295 pickup crisp.nib;
296 pos8(hround(hair-stem_corr),0); pos7'(stem',0);
297 z7'=z1; x8r=x7'r; top y8=h+oo;
298 filldraw stroke z7'e--z8e; % point
299 if serifs: pickup tiny.nib;
300 pos9(vair,-90); x9=.5[x2,x10]; bot y9r=-d-o-1;
301 pos10(hair,-180); lft x10r=hround u; y10=-.75d+.5flare;
302 pos11(flare,-180); z11r=z10r;
303 bulb(9,10,11); filldraw stroke super_arc.e(2,9); % tail
304 else: pickup fine.nib; pos2'(stem,0); z2'=z2;
305 z2''r=z2'r; z2''=z2'; z2''l=(x2'l,0);
306 pos9(vair,-90); x9=4.5u; bot y9r=-d-o-1;
307 pos10(.5[vair,flare],-90); lft x10=hround 1.25u;
308 y10r=good.y -5/6d; y10l:=good.y y10l;
309 filldraw stroke z2'e..z2''e&super_arc.e(2'',9)
310 & term.e(9,10,left,.9,4); fi % tail
311 penlabels(0,1,2,3,4,G5,6,D4,D5,D6,7,8,9,10,11); endchar;
312
313 cmchar "The letter h";
314 beginchar("h",10u#,asc_height#,0);
315 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
316 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
317 pen_duplicate(1,1',2,2');
318 pickup tiny.nib; pos1(.5stem,0); pos2(.5stem,0);
319 pos1'(.5stem',0); pos2'(.5stem',0); pos3(stem,0);
320 Delta_x = hround(interspace+.5stem);
321 lft x.G1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3r=w-x.G1l;
322 top y1=h; bot y2=0; y1=y1'; y2=y2';
323 double filldraw stroke z1'e--z2'e; % left (double) stem
324 h_stroke(D2,a,3,4); % arch and right stem
325 if serifs: sloped_biserif.l(1',2',b,1/3,jut,serif_drop,b',1/3); % upper left serif
326 numeric inner_jut; pickup tiny.nib;
327 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
328 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
329 dish_biserif(2,1,c,1/3,jut,cd,1/3,d,1/3,jut); % lower left serif
330 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); % lower right serif
331 else: mid_biserif(1,2,b,1/3); % upper left terminal
332 mid_biserif(2,1,cd,1/3); fi % lower left terminal
333 penlabels(G1,D1,G2,D2,3,4); endchar;
334
335 cmchar "The letter i";
336 numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
337 beginchar("i",5u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
338 define_whole_blacker_pixels(dot_diam);
339 italcorr h#*slant-serif_fit# + .5dot_diam# -2u#;
340 adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
341 pen_duplicate(1,2);
342 pickup tiny.nib; pos1(.5stem',0); pos2(.5stem',0);
343 Delta_x = hround(interspace+.5stem');
344 if odd(w-stem'-interspace): change_width; fi
345 lft x.G1l=hround(.5w-.5stem'-.5interspace); x1=x2;
346 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
347 double filldraw stroke z1e--z2e; % double stem
348 pos3(dot_diam,0); pos4(dot_diam,90);
349 if serifs: x3r=max(x1r,hround(x1+.5dot_diam-.2jut)-.5tiny)
350 else: x3=x1-.5 fi;
351 top y4r=h+1;
352 if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
353 x3=x4; y3=.5[y4l,y4r]; dot(3,4); % dot
354 if serifs: sloped_biserif.l(1,2,a,1/3,.95jut,serif_drop,a',1/3); % upper serif
355 dish_biserif(2,1,b,1/3,jut,bc,1/3,c,1/3,.9jut); % lower serif
356 else: mid_biserif(1,2,a,1/3); % upper terminal
357 mid_biserif(2,1,bc,1/3); fi % lower terminal
358 penlabels(G1,D1,G2,D2,3,4); endchar;
359
360 cmchar "The letter j";
361 numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
362 beginchar("j",5.5u#,min(asc_height#,10/7x_height#+.5dot_diam#),desc_depth#);
363 define_whole_blacker_pixels(dot_diam);
364 italcorr h#*slant-serif_fit#+.5stem#-2u#;
365 adjust_fit(serif_fit#+2stem_shift# if monospace:+\\.5u# fi,
366 serif_fit#-2stem_shift# if monospace:-.5u# fi);
367 pen_duplicate(1,2);
368 pickup tiny.nib; pos1(.5stem',0); pos2(.5stem',0);
369 rt x.D1r=hround(.5w+.25u+.5stem'+.5interspace); x1=x2;
370 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
371 filldraw stroke z.D1e--z.D2e; % right stem
372 pos3(dot_diam,0); pos4(dot_diam,90);
373 x3r=x.D1r; top y4r=h+1;
374 if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
375 x3=x4; y3=.5[y4l,y4r]; dot(3,4); % dot
376 if serifs:
377 pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
378 x5=.5[x.D2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
379 if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
380 (x,y5r)=whatever[z5l,z.D2l]; x5r:=max(x,.5[x6r,x5]);
381 filldraw stroke z.D2e{down}...z5e{left}; bulb(5,6,7); % arc and bulb
382 Delta_x = min(hround(interspace+.5stem'),x.D2l-x5r);
383 define_lower(G5,G2,z.D2r{down}...z5r{left});
384 filldraw stroke z.G1e--z.G5e; % left (inner) stem
385 sloped_biserif.l(1,2,a,1/3,1.1jut,serif_drop,a',1/3); % upper serif
386 else: pen_duplicate(2');
387 pickup fine.nib; pos2'(.5stem',0); z2'=z2;
388 pos6(.2[vair,.5stem'],-90); pos7(vair,-90);
389 lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
390 (x,y7l)=whatever[z7r,z3]; x7l:=x;
391 z5r=z.D2'r; (x.D2'l,y5l)=whatever[z7l,z5r]; x5l=x.D2'l; y5=y5r;
392 x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
393 filldraw stroke z.D2'e..{down}z5e & super_arc.e(5,6)
394 & z6e{left}..z7e; % arc and terminal
395 Delta_x = min(hround(interspace+.5stem'),x.D2l-x7l);
396 define_lower(G5,G2',z.D2'r..{down}z5r & super_arc.r(5,6)
397 & z6r{left}..z7r);
398 filldraw stroke z.G2'e--z.G5e; % inner stroke
399 pickup tiny.nib; filldraw stroke z.G1e--z.G2e; % right stem
400 mid_biserif(1,2,a,1/3); fi % upper terminal
401 penlabels(G1,D1,G2,D2,G2',D2',3,4,5,G5,6,7); endchar;
402
403 cmchar "The letter k";
404 beginchar("k",9.5u#,asc_height#,0);
405 italcorr x_height#*slant-.2u#;
406 adjust_fit(serif_fit#,serif_fit#); pickup tiny.nib;
407 numeric right_jut,stem[],alpha[];
408 stem1=stem2=max(tiny.breadth,hround(.5fudged.stem-stem_corr));
409 stem3=max(tiny.breadth,hround(fudged.hair if hefty:-\\4stem_corr fi));
410 stem4=max(tiny.breadth,hround(fudged.stem-3stem_corr));
411 pen_duplicate(1,2);
412 if serifs: right_jut=.6jut; else: right_jut=.4tiny; fi
413 pos1(stem1,0); pos2(stem2,0); top y1=h; bot y2=0;
414 Delta_x = hround(interspace+stem1);
415 lft x.G1l=lft x.G2l=hround(2.5u-.5stem1);
416 top y3=x_height; rt x3r=hround(r-letter_fit-.7u-right_jut)+eps;
417 bot y6=0; rt x6r=hround(r-letter_fit-.3u-right_jut)+eps;
418 x4=x11=x.D1; y4=.7bar_height; y11=y3;
419 alpha1=diag_ratio(1,.5(stem3-tiny),y3-y4,x3r-x4);
420 alpha2=diag_ratio(1,.5(stem4-tiny),y11-y6,x6r-x.D1);
421 penpos3(alpha1*(stem3-tiny),0); penpos4(whatever,-90);
422 z5=.5[z5l,z5r]; penpos6(alpha2*(stem4-tiny),0);
423 forsuffixes $=l,r: y3'$=x_height; y6'$=0; z4$=z3'$+whatever*(z3-z4);
424 z5$=z6'$+whatever*(z11-z6)=whatever[z3,z4]; endfor
425 z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
426 % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
427 z6'r=z6r+penoffset z11-z6 of currentpen+whatever*(z11-z6);
428 z6'l=z6l+penoffset z6-z11 of currentpen+whatever*(z11-z6);
429 fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle; % upper diagonal
430 fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle; % lower diagonal
431 pen_duplicate(0,0');
432 pos0(stem1,0); pos0'(stem2,0); y0=y0'; x0=x1; x0'=x2;
433 rt z.D0r=whatever[z3,z4]; double filldraw stroke z1e..z0e--z0'e..z2e; % double stem
434 if serifs: numeric inner_jut;
435 if rt x2r+jut+.5u+1<=lft x6l-jut: inner_jut=jut;
436 else: rt x2r+inner_jut+.5u+1=lft x6l-inner_jut; fi
437 sloped_biserif.l(1,0,a,1/3,jut,serif_drop,a',1/3); % upper stem serif
438 dish_biserif(2,0',b,1/3,jut,bc,1/3,c,1/3,inner_jut); % lower stem serif
439 dish_serif(3,4,d,2/3,1.4jut,e,1/2,right_jut)(dark); % upper diagonal serif
440 dish_serif(6,5,f,1/2,inner_jut,g,1/3,right_jut)(dark); % lower diagonal serif
441 else: mid_biserif(1,0,a,1/3); % upper stem terminal
442 mid_biserif(2,0',bc,1/3); fi % lower stem terminal
443 penlabels(G0,D0,G1,D1,G2,D2,3,4,5,6,11); endchar;
444
445 cmchar "The letter l";
446 beginchar("l",5u#,asc_height#,0); l_width#:=5u#+2serif_fit#;
447 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
448 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
449 pen_duplicate(1,2);
450 pickup tiny.nib; pos1(.5stem',0); pos2(.5stem',0);
451 Delta_x = hround(interspace+.5stem');
452 if odd(w-stem'-interspace): change_width; fi
453 lft x.G1l=hround(.5w-.5stem'-.5interspace); x1=x2; top y1=h; bot y2=0;
454 double filldraw stroke z1e--z2e; % double stem
455 if serifs: sloped_biserif.l(1,2,a,1/3,jut,serif_drop,a',1/3); % upper serif
456 dish_biserif(2,1,b,1/3,jut,bc,1/3,c,1/3,jut); % lower serif
457 else: mid_biserif(1,2,a,1/3); % upper terminal
458 mid_biserif(2,1,bc,1/3); fi % lower terminal
459 penlabels(G1,D1,G2,D2); endchar;
460
461 cmchar "The letter m";
462 beginchar("m",15u#,x_height#,0);
463 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
464 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
465 numeric shaved_stem; shaved_stem=hround(.5mfudged.stem-stem_corr);
466 pen_duplicate(1,1',2,2');
467 pickup tiny.nib; %pos1(.5mfudged.stem,0); pos2(.5mfudged.stem,0);
468 pos1(shaved_stem,0); pos2(shaved_stem,0);
469 pos1'(shaved_stem,0); pos2'(shaved_stem,0);
470 pos3(mfudged.stem,0); pos5(mfudged.stem,0);
471 Delta_x = hround(interspace+.5mfudged.stem);
472 lft x.G1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; % stem, sic
473 lft x3l=hround(.5w-.5mfudged.stem+.5interspace); x5l-x3r=x3l-x.D1r;
474 if not monospace: r:=hround(x5+x.D1)+r-w-interspace; fi % change width for better fit
475 top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
476 double filldraw stroke z1'e--z2'e; % left (double) stem
477 h_stroke(D2,a,3,4); % left arch and middle stem
478 h_stroke(4,b,5,6); % right arch and right stem
479 if serifs: sloped_biserif.l(1',2',c,1/3,jut,serif_drop,c',1/3); % upper left serif
480 numeric inner_jut; pickup tiny.nib;
481 if rt x.D2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
482 else: rt x.D2r+jut+.5u+1=lft x4l-inner_jut; fi
483 dish_biserif(2,1,d,1/3,jut,de,1/3,e,1/3,jut); % lower left serif
484 dish_serif(4,3,f,1/3,inner_jut,g,1/3,jut); % lower middle serif
485 dish_serif(6,5,h,1/3,inner_jut,i,1/3,jut); % lower right serif
486 else: mid_biserif(1,2,c,1/3); % upper left terminal
487 mid_biserif(2,1,de,1/3); fi % lower left terminal
488 penlabels(G1,D1,G2,D2,3,4,5,6); endchar;
489
490 cmchar "The letter n";
491 beginchar("n",10u#,x_height#,0);
492 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
493 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
494 pen_duplicate(1,1',2,2');
495 pickup tiny.nib; %pos1(.5stem,0); pos2(.5stem,0);
496 numeric shaved_stem; shaved_stem=hround(.5stem-stem_corr);
497 pos1(shaved_stem,0); pos2(shaved_stem,0);
498 pos1'(shaved_stem,0); pos2'(shaved_stem,0); pos3(stem,0);
499 Delta_x = hround(interspace+.5stem);
500 lft x.G1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3r=w-x.G1l;
501 top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
502 double filldraw stroke z1'e--z2'e; % left (double) stem
503 h_stroke(D2,a,3,4); % arch and right stem
504 if serifs: sloped_biserif.l(1',2',b,1/3,jut,serif_drop,b',1/3); % upper left serif
505 numeric inner_jut; pickup tiny.nib;
506 if rt x.D2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
507 else: rt x.D2r+jut+.5u+1=lft x4l-inner_jut; fi
508 dish_biserif(2,1,c,1/3,jut,cd,1/3,d,1/3,jut); % lower left serif
509 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); % lower right serif
510 else: mid_biserif(1,2,b,1/3); % upper left terminal
511 mid_biserif(2,1,cd,1/3); fi % lower left terminal
512 penlabels(G1,D1,G2,D2,3,4); endchar;
513
514 cmchar "The letter o";
515 beginchar("o",9u#,x_height#,0);
516 italcorr .7x_height#*slant;
517 adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
518 pen_duplicate(2);
519 penpos1(vair,90); penpos3(vair',-90);
520 penpos2(.5curve,180); penpos4(curve,0);
521 x.G2r=hround max(.5u,1.25u-.5curve);
522 x4r=w-x.G2r; x1=x3=.5w; y1r=h+vround 1.5oo; y3r=-oo;
523 y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
524 penstroke pulled_arc.e(1,G2) & pulled_arc.e(G2,3)
525 & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
526 Delta_x = min(hround(curve_interspace+.5curve),x1r-x.G2l);
527 define_upper_and_lower(D1,D3,D2,pulled_arc.r(1,G2) & pulled_arc.r(G2,3));
528 filldraw stroke z.D1e--z.D3e; % inner stroke
529 penlabels(1,G2,3,D1,D2,D3,4); endchar;
530
531 cmchar "The letter p";
532 beginchar("p",10u#+serif_fit#,x_height#,desc_depth#);
533 italcorr .5x_height#*slant+min(.5curve#-.85u#,-.1u#);
534 adjust_fit(serif_fit#,0);
535 pen_duplicate(0,0',1,2);
536 pickup tiny.nib; pos1(.5stem',0); pos2(.5stem,0);
537 pos0'(.5stem',0); pos0(.5stem,0); z0l=z0'l; x0'=x1; x0=x2;
538 Delta_x = hround(interspace+.5stem);
539 lft x.G1l=hround(2.5u-.5stem'); top y1=h if serifs: +min(oo,serif_drop) fi;
540 numeric edge; edge=rt x.D2r;
541 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
542 pos4(vair',90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
543 rt x3l=max(rt x3l-(lft x3r-tiny.lft x.D2l), 1/3[rt x.D2,edge]);
544 y3=1/8[bar_height,x_height];
545 x4l=w-.5(w-serif_fit)+.5u+.5interspace; top y4r=x_height+oo;
546 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
547 x6l=x4l-.2u; bot y6r=-oo;
548 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
549 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x5r,x4]);
550 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x5r,x6]);
551 filldraw stroke z3e{up}...{right}z4e&super_arc.e(4,5)
552 &super_arc.e(5,6)&z6e{left}...{up}z7e; % bowl
553 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
554 pickup tiny.nib; bot y2=-d;
555 double filldraw stroke z1e--z0'e--z0e--z2e; % double stem
556 %pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
557 %z7'=z2; x8l=x7'l; bot y8=0;
558 %filldraw stroke z7'e--z8e; % point
559 if serifs: sloped_biserif.l(1,0',a,1/3,jut,serif_drop,a',1/3); % upper serif
560 dish_biserif(2,0,b,1/3,jut,bc,1/3,c,1/3,jut); % lower serif
561 else: mid_biserif(1,0,a,1/3); % upper terminal
562 mid_biserif(2,0,bc,1/3); fi % lower terminal
563 penlabels(G0,D0,G1,D1,G2,D2,3,4,5,6,7,8); endchar;
564
565 cmchar "The letter q";
566 beginchar("q",10u#+serif_fit#,x_height#,desc_depth#);
567 italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
568 adjust_fit(0,serif_fit# if serifs: -.5u# fi);
569 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
570 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
571 rt x1r=hround(w-2.5u+.5stem');
572 numeric edge; edge=lft x2l;
573 pen_duplicate(5);
574 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
575 pos4(vair',90); pos5(.5curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
576 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
577 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
578 lft x.G5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
579 x6l=x4l-.2u; bot y6r=-oo; y7=min(y3,y6+y4-y3+.6vair);
580 lft x7l=min(lft x7l-(rt x7r-tiny.rt x2r),1/3[lft x2,edge]);
581 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x.G5r,x4]);
582 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x.G5r,x6]);
583 filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,G5)
584 &super_arc.e(G5,6)&z6e{right}...{up}z7e; % bowl
585 Delta_x = min(hround(curve_interspace+.5curve),x6r-x.G5l);
586 define_upper_and_lower(D4,D6,D5,super_arc.r(4,G5) & super_arc.r(G5,6));
587 filldraw stroke z.D4e--z.D6e; % inner stroke
588 y1=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
589 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{right}...{up}z7l));
590 pickup tiny.nib; bot y2=-d;
591 filldraw stroke z1e--z0'e--z0e--z2e; % stem
592 pickup crisp.nib;
593 pos8(hround(hair-stem_corr),0); pos7'(stem',0);
594 z7'=z1; x8r=x7'r; top y8=h+oo;
595 filldraw stroke z7'e--z8e; % point
596 if serifs: dish_serif(2,0,b,1/3,jut,c,1/3,jut); fi % lower serif
597 penlabels(0,1,2,3,4,G5,6,D4,D5,D6,7,8); endchar;
598
599 cmchar "The letter r";
600 numeric r_flare#; r_flare#=.75[if serifs: stem# else: vair# fi,flare#];
601 define_whole_blacker_pixels(r_flare);
602 beginchar("r",if serifs:max(7u#,5.5u#+r_flare#) else:6.5u# fi,x_height#,0);
603 italcorr x_height#*slant if not serifs: +.25u# fi;
604 adjust_fit(serif_fit#,0);
605 pickup fine.nib; top y4r=h+oo;
606 if serifs: pos4(vair,90); pos5(hair,0);
607 x4=w-max(1.75u,.25u+r_flare);
608 rt x5r=hround(w-.5u+.5); y5+.5r_flare=.9[bar_height,h]+oo;
609 pos6(r_flare,0); bulb(4,5,6); % bulb
610 else: pos4(r_flare,90); rt x4=hround(w-.25u); fi
611 pos3(thin_join,180); rt x3l=hround(2.5u-.5stem')+stem'+interspace; top y3=bar_height;
612 filldraw stroke z3e{up}...{right}z4e; % arc
613 pen_duplicate(0,0',1,2);
614 pickup tiny.nib; pos0(hround(.5stem-stem_corr),0); pos2(hround(.5stem-stem_corr),0);
615 pos1(hround(.5stem-stem_corr),0); top y1=h+min(oo,serif_drop);
616 pos0'(hround(.5stem-stem_corr),0); y0=y0'=y3; x1l=x0l=x0'l=x2l;
617 Delta_x = hround(interspace+.5stem-stem_corr);
618 lft x.G1l=hround(2.5u-.5stem+stem_corr); bot y2=0;
619 double filldraw stroke z1e--z0'e--z0e--z2e; % double stem
620 if serifs: sloped_biserif.l(1,0',a,1/3,jut,serif_drop,a',1/3); % upper serif
621 dish_biserif(2,0,b,1/3,jut,bc,1/3,c,1/3,1.25jut); % lower serif
622 else: mid_biserif(1,0,a,1/3); % upper terminal
623 mid_biserif(2,0,bc,1/3); fi % lower terminal
624 penlabels(G1,D1,G2,D2,3,4,5,6); endchar;
625
626 cmchar "The letter s";
627 beginchar("s",7.1u#,x_height#,0);
628 italcorr x_height#*slant-if serifs:.55u# else:.3u# fi;
629 adjust_fit(if monospace: .5u#,.4u# else: 0,if serifs:0 else:-.2u# fi fi);
630 numeric theta; theta=90-angle(40u,h); slope:=-h/40u; % angle at middle
631 numeric s_slab; s_slab=if serifs:vair else:Vround .1[vair,stem] fi;
632 numeric ess'; ess'=max(fine.breadth,ess);
633 pen_duplicate(3,6);
634 pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-100);
635 pos0(ess',theta); pos7(s_slab,-90); x2l=x0=x7=.5w;
636 top y2l=h+vround 1.5oo; bot y7r=-oo;
637 y0-.5ess'=y7l+if serifs:.54 else: .52 fi\\(y2r-y7l-ess');
638 lft x.G3l=hround .6u; rt x.D6r=hround(w-.6u);
639 x3r-x3l=x6r-x6l=hround .5[.75s_slab,.75ess']-fine;
640 Delta_x = min(hround(curve_interspace+x3r-x3l+fine),x2l-x.G3r); % x2l-x.G3r=x.D6l-x7r
641 ellipse_set(2l,G3l,4l,0l); ellipse_set(2r,G3r,4r,0r); y3=y3r;
642 ellipse_set(7l,D6l,5l,0l); ellipse_set(7r,D6r,5r,0r); y6=y6r;
643 interim superness:=more_super;
644 filldraw stroke super_arc.e(2,G3) & z.G3e{down}
645 ..z4e---z5e..z.D6e{down} & super_arc.e(D6,7); % main stroke
646 define_upper_and_lower(D2,D4,D3,super_arc.l(2,G3) & z.G3l{down}..z4l---z5l);
647 define_upper_and_lower(G5,G7,G6,z4r---z5r..z.D6r{down} & super_arc.r(D6,7));
648 filldraw stroke z.D2e--z.D4e; filldraw stroke z.G5e--z.G7e; % inner strokes
649 if serifs: pos1(hair,180); pos8(hair,180);
650 rt x1l=hround(w-1.05u); lft x8r=hround .6u;
651 bot y1=min(bot y2r,vround 1/5[top y5r,h]);
652 top y8=max(top y7l,vround 5/6 bot y4l);
653 filldraw stroke z1e{up}....{left}z2e; % upper arc
654 filldraw stroke z7e{left}....{x8-x7,5(y8-y7)}z8e; % lower arc
655 path upper_arc, lower_arc;
656 upper_arc=z1{up}....{left}z2; lower_arc=z7{left}....{x8-x7,5(y8-y7)}z8;
657 pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
658 x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
659 x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
660 numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
661 filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle; % upper barb
662 t:=xpart(lower_arc intersectiontimes(z9r--z8'));
663 filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle; % lower barb
664 else: pos1(4/7[s_slab,flare],-100); pos8(flare,-100);
665 x1l=good.x(x1l+w-u-rt x1); lft x8r=hround .5u;
666 top y1l=vround(.93h+1.5oo); bot y8r=vround .1h-oo;
667 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
668 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
669 penlabels(0,1,1',2,G3,4,D2,D3,D4,5,D6,7,G5,G6,G7,8,8',9,10); endchar;
670
671 cmchar "The letter t";
672 beginchar("t",6u#+max(u#,.5stem#),
673 min(asc_height#,if hefty:9/7 else:10/7 fi\\ x_height#),0);
674 italcorr x_height#*slant if serifs: -.9u# else: -.4u# fi;
675 adjust_fit(0,if serifs: 0 else: -.5u# fi);
676 pen_duplicate(2,3);
677 numeric shaved_stem; shaved_stem=hround(.5stem if hefty:-\\stem_corr fi);
678 pickup fine.nib; pos2(shaved_stem,180);pos3(shaved_stem,180);
679 lft x.G2r=lft x.G3r=hround(2.5u-.5shaved_stem);
680 y2=y8; y3=max(.5bar_height,2vair);
681 pickup crisp.nib; pos8(bar,90);
682 rt x8=hround(w-1.3u); top y8r=x_height; lft x7=hround 1/3u; y7l=y8l;
683 pickup fine.nib; interim superness:=more_super;
684 pos4(vair',-90); bot y4r=-oo; rt x5r=hround(w-u);
685 if serifs: pos5(hair,0); y5=y3; x4l=.5[x.G3l,x5l];
686 (x,y4r)=whatever[z4l,z5l]; x4r:=max(x,.5[x.G3r,x4]);
687 filldraw stroke z.G2e..super_arc.e(G3,4)...{up}z5e; % stem and hook
688 Delta_x = min(hround(interspace+shaved_stem),x4r-x.G3l);
689 define_lower(D4,D3,super_arc.r(G3,4));
690 filldraw stroke z.D2e--z.D4e; % inner stroke
691 pickup crisp.nib; pos6(hair,0); pos5'(hair,0);
692 x6=x5=x5'; top y6=max(vround .75bar_height,top y5); y5=y5';
693 filldraw stroke z5'e--z6e; % terminal
694 else: pos5(vair,-75); top y5l=vround .2[top y4l,bar_height];
695 x5l:=good.x x5l; x4l=1/3[x.G3l,x5l]; x4r:=1/3[x.G3r,x5r]; y3l:=y3l+.2vair;
696 filldraw stroke z.G2e..super_arc.e(G3,4); % stem and hook
697 path p; p=stroke z4e{right}..tension .9 and atleast 1..z5e; % terminal
698 Delta_x = min(hround(interspace+shaved_stem),x5r-x.G3l);
699 if (xpart(z5l-precontrol 1 of p)<0) or (xpart(z5r-postcontrol 2 of p)<0):
700 filldraw stroke z4e{right}...{up}z5e;
701 define_lower(D4,D3,super_arc.r(G3,4)&z4r{right}...{up}z5r);
702 else: filldraw p; define_lower(D4,D3,super_arc.r(G3,4)
703 & z4r{right}..tension .9 and atleast 1..z5r); fi;
704 filldraw stroke z.D2e--z.D4e; fi % inner stroke
705 if hefty: pos7(bar,90);
706 filldraw stroke z7e--z8e; % crossbar
707 pickup tiny.nib; pos1(hround(shaved_stem-stem_corr),0);
708 rt x1r=fine.rt x.D2l; top y1=h;
709 penpos2'(x1r-x1l,0); x2'=x1; y2'=y2;
710 filldraw stroke z1e--z2'e; % upper terminal
711 else: pos7(vair,90); pos1(hair,0);
712 rt x1r=fine.rt x.D2l; top y1=h;
713 filldraw z1l{down}...{left}z7r--z7l--z8l
714 --z8r--(x1r,y8r)--z1r--cycle; fi % upper terminal and crossbar
715 penlabels(1,G2,D2,G3,D3,4,D4,5,6,7,8); endchar;
716
717 cmchar "The letter u";
718 beginchar("u",10u#,x_height#,0);
719 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
720 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
721 numeric light_vair; light_vair=vair if hefty: -vround 2vair_corr fi;
722 if light_vair<fine.breadth: light_vair:=fine.breadth; fi
723 pen_duplicate(1,2);
724 pickup tiny.nib; pos1(.5stem,0); pos2(.5stem,0);
725 pos3(stem,0); pos4(stem',0);
726 lft x.G1l=hround(2.5u-.5stem); x1=x2; x3r=w-x.G1l; x3r=x4r;
727 if serifs: top y1=h+min(oo,serif_drop); bot y4=-min(oo,serif_drop);
728 else: top y1=h; bot y4=0; fi
729 pos0(stem,0); pos0'(stem',0); x0=x3; x0'=x4; y0=y0';
730 pen_duplicate(2');
731 penpos2'(.5stem-fine,-180); z2'=z2; y3=y1; y2=.5bar_height;
732 penpos5(max(eps,light_vair-fine),-90); penpos6(thin_join-fine,0);
733 y6=y0=2/3bar_height;
734 filldraw stroke z3e..z0e--z0'e..z4e; % right stem
735 pickup fine.nib; bot y5r=-oo; x5l=.5w-.25u; lft x6l=tiny.lft x0l;
736 (x,y5r)=whatever[z5l,z6l]; x5r:=max(x,.5[x5,x.G2'r]);
737 filldraw stroke {{interim superness:=hein_super;
738 pulled_arc.e(G2',5)}} & z5e{right}...{up}z6e; % arc
739 pickup tiny.nib;
740 Delta_x = min(hround(interspace+.5stem),x5r-x.G2r);
741 define_lower(D5,D2,{{interim superness:=hein_super;
742 pulled_arc.r(G2',5)}} & z5r{right}...{up}z6r);
743 double filldraw stroke z1e--z2e; % left (double) stem
744 filldraw stroke z.D2e--z.D5e; % inner stroke
745 pickup fine.nib;
746 if serifs: sloped_biserif.l(1,2,a,1/3,jut,serif_drop,a',1/3); % upper left serif
747 sloped_serif.l(3,0,b,1/3,jut,serif_drop); % upper right serif
748 sloped_serif.r(4,0',c,1/3,jut,min(oo,serif_drop)); % lower right serif
749 else: mid_biserif(1,2,a,1/3); fi % upper left terminal
750 penlabels(G1,D1,G2,D2,3,4,5,D5); labels(6); endchar;
751
752 cmchar "The letter v";
753 beginchar("v",if serifs: 9.5u# else:9u# fi,x_height#,0);
754 italcorr x_height#*slant+.25u#;
755 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
756 numeric left_stem,right_stem,outer_jut,alpha;
757 left_stem=fudged.stem-stem_corr;
758 right_stem=min(fudged.hair if hefty:-2stem_corr fi,left_stem);
759 pen_duplicate(1,2);
760 outer_jut=.75jut; x.G1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
761 x2-x1=x4-x3; x.D2r=x3r; y2=y3=-apex_oo;
762 alpha=diag_ratio(2,right_stem,y1-y2,x4r-x.G1l-apex_corr-interspace);
763 penpos1(alpha*.5left_stem,0); penpos2(alpha*.5left_stem,0);
764 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
765 Delta_x = hround(alpha*(interspace+.5left_stem));
766 z0=whatever[z.D1r,z.D2r]=whatever[z3l,z4l];
767 if y0>notch_cut: y0:=notch_cut;
768 fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
769 --diag_end(4r,3r,1,1,D2l,D1l)--diag_end(D2l,D1l,1,1,D1r,D2r){z2-z1}
770 ...{down}z0+.5left--cycle; % left and right diagonals
771 else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,D2l,D1l)
772 --diag_end(D2l,D1l,1,1,D1r,0)--cycle; fi % left and right diagonals
773 fill diag_end(G2l,G1l,1,1,G1r,G2r)--diag_end(G1r,G2r,1,1,G2l,G1l)--cycle;
774 if serifs: numeric inner_jut; pickup tiny.nib;
775 prime_points_inside(1,2); prime_points_inside(4,3);
776 prime_points_inside(2,1); pen_duplicate(1',2');
777 if rt x.D1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
778 else: rt x.D1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
779 dish_biserif(1',2,a,1/3,outer_jut,ab,1/3,b,1/2,inner_jut); % left serif
780 mid_biserif(2',1,ab',1/3); % lower terminal
781 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); % right serif
782 else: mid_biserif(1,2,ab,1/3); % upper terminal
783 mid_biserif(2,1,ab',1/3); fi % lower terminal
784 penlabels(0,G1,D1,G2,D2,3,4); endchar;
785
786 cmchar "The letter w";
787 beginchar("w",13u#,x_height#,0);
788 italcorr x_height#*slant+.25u#;
789 adjust_fit(serif_fit#,serif_fit#);
790 numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
791 outer_jut=.7jut; x.G1l=w-x8r=l+letter_fit+outer_jut+.25u;
792 stem1=fudged.stem-stem_corr;
793 stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
794 stem2=if hefty:.1[vair,stem4] else: stem4 fi;
795 stem3=max(stem2,stem1-3stem_corr);
796 pen_duplicate(1,2);
797 x2-x1=x4-x3=x6-x5=x8-x7; x.D2r=x3r; x6l+apex_corr=x7l;
798 y1=y8=h; y2=y3=y6=y7=-apex_oo;
799 y4=y5=if monospace: vround .6 fi\\ h; upper_notch=y4-notch_cut;
800 mid_corr=if monospace or hefty:-.3apex_corr else: .5jut fi;
801 alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x.G1l+mid_corr-2apex_corr+interspace);
802 penpos1(alpha*.5stem1,0); penpos2(alpha*.5stem1,0);
803 penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
804 penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
805 penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
806 Delta_x = hround(alpha*(interspace+.5stem1));
807 x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r| $\approx$ |x4r+mid_corr|
808 z23=whatever[z.D1r,z.D2r]=whatever[z3l,z4l];
809 z45=whatever[z3r,z4r]=whatever[z5l,z6l];
810 z67=whatever[z5r,z6r]=whatever[z7l,z8l];
811 fill diag_end(D1l,D2l,1,1,3r,4r){z4-z3}
812 ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
813 --(x45,upper_notch)+.5right{down} else: z45&z45 fi
814 ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
815 ...if y67>notch_cut:(x67,notch_cut)+.5right{down}
816 --(x67,notch_cut)+.5left{up} else: z67&z67 fi
817 ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
818 ...if y23>notch_cut:(x23,notch_cut)+.5right{down}
819 --(x23,notch_cut)+.5left{up} else: z23&z23 fi
820 ...{z1-z2}diag_end(D2r,D1r,1,1,D1l,D2l)--cycle; % diagonals
821 fill diag_end(G2r,G1r,1,1,G1l,G2l)--diag_end(G1l,G2l,1,1,G2r,G1r)--cycle;
822 if serifs: numeric inner_jut[]; pickup tiny.nib;
823 prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
824 prime_points_inside(2,1); pen_duplicate(1',2');
825 if monospace: inner_jut1=inner_jut4=1.5jut;
826 elseif hefty: inner_jut1=inner_jut4=jut;
827 else: fill diag_end(6r,5r,1,1,5l,6l)--.9[z5l,z6l]
828 ..{z5-z6}.1[z5r,z6r]--cycle; % middle stem
829 inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
830 if rt x1'r+jut+.5u+1<=lft x5'l-.7jut: inner_jut1=jut;
831 else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
832 if rt x5'r+jut+.5u+1<=lft x8'l-1.1jut: inner_jut3=jut;
833 else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
834 dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi % middle serif
835 dish_biserif(1',2,a,1/3,outer_jut,ab,1/3,b,1/2,inner_jut1); % left serif
836 mid_biserif(2',1,ab',1/3); % lower left terminal
837 dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); % right serif
838 else: mid_biserif(1,2,ab,1/3); % upper terminal
839 mid_biserif(2,1,ab',1/3); fi % lower terminal
840 penlabels(0,G1,D1,G2,D2,3,4,5,6,7,8,23,45,67); endchar;
841
842 cmchar "The letter x";
843 beginchar("x",if serifs:9.5u# else:9u# fi,x_height#,0);
844 italcorr x_height#*slant-.05u#;
845 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
846 numeric stem[],outer_jut,xjut,alpha[];
847 stem1=fudged.stem-4stem_corr; stem2=min(fudged.hair,stem1);
848 outer_jut=.75jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
849 pen_duplicate(1,4);
850 x.G1l=l+letter_fit+.1u+outer_jut; x2r=r-letter_fit-.3u-outer_jut-xjut;
851 x3l=l+letter_fit+outer_jut+xjut; x.D4r=r-letter_fit-outer_jut;
852 y1=y2=h; y3=y4=0;
853 alpha1=diag_ratio(1,stem1,h,x.D4r-x.G1l);
854 alpha2=diag_ratio(1,stem2,h,x2r-x3l);
855 penpos1(alpha1*.5stem1,0); penpos2(alpha2*stem2,0);
856 penpos3(alpha2*stem2,0); penpos4(alpha1*.5stem1,0);
857 Delta_x = hround(alpha1*(interspace+.5stem1));
858 if hefty:
859 z12=whatever[z2l,z3l]=whatever[z.D1r,z.D4r];
860 z13=whatever[z2l,z3l]=whatever[z.G1l,z.G4l];
861 z24=whatever[z2r,z3r]=whatever[z.D1r,z.D4r];
862 z34=whatever[z2r,z3r]=whatever[z.G1l,z.G4l];
863 fill diag_end(12,D1r,.5,1,D1l,D4l)--diag_end(D1l,D4l,.5,1,D4r,24)--z24
864 --diag_end(24,2r,1,.5,2l,12)--z12--cycle; % upper diagonals
865 fill diag_end(34,G4l,.5,1,G4r,G1r)--diag_end(G4r,G1r,.5,1,G1l,13)--z13
866 --diag_end(13,3l,1,.5,3r,34)--z34--cycle; % lower diagonals
867 else: forsuffixes e=l,r: forsuffixes $=G,D:
868 z$0e = whatever[z2e,z3e] = whatever[z$1,z$4]; endfor endfor
869 fill diag_end(D4r,D1r,.5,1,D1l,D4l)
870 --diag_end(D1l,D4l,.5,1,D4r,D1r)--cycle; % upper left diagonal
871 fill diag_end(G4r,G1r,.5,1,G1l,G4l)
872 --diag_end(G1l,G4l,.5,1,G4r,G1r)--cycle; % lower left diagonal
873 fill z.D0l--z.D0r--diag_end(D0r,2r,.5,1,2l,D0l)--cycle; % upper right diagonal
874 fill diag_end(G0l,3l,.5,1,3r,G0r)--z.G0r--z.G0l--cycle; fi % lower right diagonal
875 if serifs: numeric inner_jut[]; pickup tiny.nib;
876 prime_points_inside(1,4); prime_points_inside(2,3);
877 prime_points_inside(3,2); prime_points_inside(4,1);
878 pen_duplicate(1',4');
879 if rt x.D1'r+jut+.5u+1<=lft x2'l-jut-xjut: inner_jut1=jut;
880 else: rt x.D1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
881 if rt x3'r+jut+.5u+1<=lft x.G4'l-jut-xjut: inner_jut2=jut;
882 else: rt x3'r+inner_jut2+.5u+1=lft x.G4'l-inner_jut2-xjut; fi
883 dish_biserif(1',4,a,1/3,outer_jut,ab,1/2,b,2/3,inner_jut1); % upper left serif
884 dish_biserif(4',1,c,2/3,inner_jut2,cd,1/2,d,1/3,outer_jut); % lower right serif
885 dish_serif(2',3,e,2/3,inner_jut1+xjut,
886 f,1/2,outer_jut+xjut)(dark); % upper right serif
887 dish_serif(3',2,g,1/2,outer_jut+xjut,
888 h,2/3,inner_jut2+xjut)(dark); % lower left serif
889 else: mid_biserif(1,4,ab,1/2); % upper left terminal
890 mid_biserif(4,1,cd,1/2); fi % lower right terminal
891 penlabels(0,G0,D0,G1,D1,2,3,G4,D4,12,13,24,34); endchar;
892
893 cmchar "The letter y";
894 beginchar("y",if serifs:9.5u# else:9u# fi,x_height#,desc_depth#);
895 italcorr x_height#*slant+.25u#;
896 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
897 numeric left_stem,right_stem,bot_stem,bot_vair,outer_jut;
898 left_stem=fudged.stem-stem_corr;
899 right_stem=fudged.hair if hefty:-2stem_corr fi;
900 bot_stem=fudged.hair if hefty:-8stem_corr fi;
901 bot_vair=Vround(if serifs: vair else:.5[vair,bot_stem] fi);
902 outer_jut=.75jut;
903 pen_duplicate(1,2);
904 x.G1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4r=h; y2=y3=0; x.G2l=x3l;
905 numeric alpha,alpha[]; x9=3u; y9=bot_vair-d-oo;
906 alpha1=diag_ratio(2,bot_stem,y1-y3,x4r-x.G1l-apex_corr-interspace);
907 alpha2=diag_ratio(1,bot_stem,y1-y9,x4r-x9);
908 if alpha1<alpha2: x2l-x1l=x4r-x3r+apex_corr; alpha=alpha1;
909 else: alpha=alpha2; z3l=whatever[z9,z4r-(alpha*bot_stem,0)]; fi
910 penpos3(alpha*bot_stem,0); penpos4(alpha*right_stem,0);
911 alpha3=(y1++(x2l-x1l))/y1;
912 penpos1(alpha3*.5left_stem,0); penpos2(alpha3*.5left_stem,0);
913 Delta_x = hround(alpha3*(interspace+.5left_stem));
914 z.D0r=whatever[z.D1r,z.D2r]=z4l+whatever*(z3r-z4r);
915 z.G0l=z.G2l;%=z3l
916 z.G0r=whatever[z.G1r,z.G2r]=whatever[z.G0l,z.D0r];
917 z.D0l=whatever[z.D1l,z.D2l]=whatever[z.G0l,z.D0r];
918 if y.G0r>notch_cut: y0:=notch_cut;
919 %y.G0l:=y.G0l-0/3*(y.G0r-y0);
920 y.G0r:=y.G0r-1/3*(y.G0r-y0);
921 %y.D0l:=y.D0l-0/3*(y.G0r-y0);
922 y.D0r:=y.D0r-1/3*(y.G0r-y0);
923 fill z.D0r+.5right{up}...{z4r-z3r}diag_end(D0r,4l,1,1,4r,3r)
924 --z3r--z.G0l--diag_end(G0l,G1l,1,1,G1r,G0r){z2-z1}
925 ...{down}z.G0r--z.D0l--diag_end(D0l,D1l,1,1,D1r,D0r){z2-z1}
926 ...{down}z.D0r+.5left--cycle; % left and right diagonals
927 else: fill z.D0r--diag_end(D0r,4l,1,1,4r,3r)--z3r--z.G0l
928 --diag_end(G0l,G1l,1,1,G1r,G0r)--z.G0r--z.D0l
929 --diag_end(D0l,D1l,1,1,D1r,D0l)--cycle; fi % left and right diagonals
930 penpos5(alpha*bot_stem,0); z5r=whatever[z3r,z4r]; y5-.5vair=-.5d;
931 if serifs: numeric light_bulb; light_bulb=hround 7/8[hair,flare]; clearpen;
932 penpos6(vair,-90); penpos7(hair,-180); penpos8(light_bulb,-180);
933 x6=2u; y6r=-d-oo; y8-.5light_bulb=-.85d; x8r=hround .35u;
934 fill stroke z3e---z5e...{left}z6e; bulb(6,7,8); % arc and bulb
935 numeric inner_jut; pickup tiny.nib;
936 prime_points_inside(1,2); prime_points_inside(4,3);
937 pen_duplicate(1');
938 if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
939 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
940 dish_biserif(1',2,a,1/3,outer_jut,ab,1/3,b,1/2,inner_jut); % left serif
941 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); % right serif
942 else: penpos6(bot_vair,-90); x6=2.5u; y6r=-d-oo;
943 fill stroke z3e---z5e...{left}z6e; % arc
944 pickup fine.nib; pos6'(bot_vair,-90); z6'=z6;
945 pos7(2/3[bot_vair,flare],-85);
946 lft x7l=hround u; bot y7r=vround-.96d-oo; y7l:=good.y y7l;
947 filldraw stroke term.e(6',7,left,1,4); % arc and terminal
948 mid_biserif(1,2,ab,1/3); fi % left terminal
949 penlabels(G0,D0,G1,D1,G2,D2,3,4,5,6,7,8,9); endchar;
950
951 cmchar "The letter z";
952 beginchar("z",8u#,x_height#,0);
953 italcorr x_height#*slant-.5serif_fit#-.3u#;
954 adjust_fit(0,.5serif_fit#);
955 numeric arm_thickness[],z_stem;
956 if hefty: arm_thickness1=Vround(vair-vair_corr); arm_thickness2=vair;
957 z_stem=max(.6[vair,.5stem],tiny+eps);
958 else: arm_thickness1=vair; arm_thickness2=vair';
959 z_stem=max(.9[vair,.5stem],tiny+eps); fi
960 pen_duplicate(1,2,3,4);
961 pickup tiny.nib; rt x.D1r=rt x.D2r=hround(w-.8u); lft x.G3l=lft x.G4l=hround .5u;
962 top y1=h; y2=min(y1,h-2/3arm_thickness1);
963 bot y4=0; y3=max(y4,2/3arm_thickness2);
964 numeric alpha; alpha=diag_ratio(1,z_stem+interspace-tiny,y2-y3,x.D2r-x.G3l-slant*(y2-y3));
965 penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
966 penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
967 Delta_x = hround(alpha*(interspace+z_stem));
968 pair delta; delta=penoffset z3-z2 of currentpen;
969 double
970 fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
971 ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
972 ---cycle; % double diagonal
973 pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
974 top y5r=h; x5=x.D1; lft x6r=hround .75u; y6=good.y(y5l-beak/1.4)-eps;
975 arm(5,6,a,beak_darkness,-.4beak_jut); % upper arm and beak
976 pos7(arm_thickness2,-90); pos8(hair,0);
977 bot y7r=0; x7=x.G4; rt x8r=hround(w-.75u); y8=good.y(y7l+beak/1.2)+eps;
978 arm(7,8,b,beak_darkness,.6beak_jut); % lower arm and beak
979 penlabels(G1,D1,G2,D2,G3,D3,G4,D4,5,6,7,8); endchar;