Debian Codegraph @

texmf-dist/bibtex/bst/smflatex/smfplain.bst

raw
1 %%
2 %% This is file `smfplain.bst',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% smflatex.dtx (with options: `smfplain')
8 %% BibTeX style for the smflatex bundle, version v1.6
9 %% \CharacterTable
10 %% {Upper-case \A\B\C\D\E\F\G\H\I\J\K\L\M\N\O\P\Q\R\S\T\U\V\W\X\Y\Z
11 %% Lower-case \a\b\c\d\e\f\g\h\i\j\k\l\m\n\o\p\q\r\s\t\u\v\w\x\y\z
12 %% Digits \0\1\2\3\4\5\6\7\8\9
13 %% Exclamation \! Double quote \" Hash (number) \#
14 %% Dollar \$ Percent \% Ampersand \&
15 %% Acute accent \' Left paren \( Right paren \)
16 %% Asterisk \* Plus \+ Comma \,
17 %% Minus \- Point \. Solidus \/
18 %% Colon \: Semicolon \; Less than \<
19 %% Equals \= Greater than \> Question mark \?
20 %% Commercial at \@ Left bracket \[ Backslash \\
21 %% Right bracket \] Circumflex \^ Underscore \_
22 %% Grave accent \` Left brace \{ Vertical bar \|
23 %% Right brace \} Tilde \~}
24 %%
25 %% @BibTeX-style-file{"smfplain.bst"
26 %% date="1998/06/15",
27 %% version="v0.1"}
28 %% Types of entries currently allowed in a BibTeX file:
29 %% ARTICLE -- An article from a journal or magazine.
30 %% BOOK -- A book with an explicit publisher.
31 %% BOOKLET -- A work that is printed and bound,
32 %% but without a named publisher or sponsoring institution.
33 %% CONFERENCE -- The same as INPROCEEDINGS,
34 %% included for Scribe compatibility.
35 %% INBOOK -- A part of a book,
36 %% which may be a chapter (or section or whatever) and/or a range of pages.
37 %% INCOLLECTION -- A part of a book having its own title.
38 %% INPROCEEDINGS -- An article in a conference proceedings.
39 %% MANUAL -- Technical documentation.
40 %% MASTERSTHESIS -- A Master's thesis.
41 %% MISC -- Use this type when nothing else fits.
42 %% PHDTHESIS -- A PhD thesis.
43 %% PROCEEDINGS -- The proceedings of a conference.
44 %% TECHREPORT -- A report published by a school or other institution,
45 %% usually numbered within a series.
46 %% UNPUBLISHED -- A document having an author and title, but not formally
47 %% published.
48 ENTRY
49 { address
50 author
51 booktitle
52 chapter
53 edition
54 editor
55 howpublished
56 institution
57 journal
58 key
59 language
60 month
61 note
62 number
63 organization
64 pages
65 publisher
66 school
67 series
68 title
69 type
70 volume
71 year
72 }
73 {}
74 { label extra.label }
75
76 INTEGERS { output.state before.all mid.sentence after.name }
77
78 FUNCTION {init.state.consts}
79 { #0 'before.all :=
80 #1 'after.name :=
81 #2 'mid.sentence :=
82 }
83
84 STRINGS { s t }
85 FUNCTION {not}
86 { { #0 }
87 { #1 }
88 if$
89 }
90
91 FUNCTION {and}
92 { 'skip$
93 { pop$ #0 }
94 if$
95 }
96
97 FUNCTION {or}
98 { { pop$ #1 }
99 'skip$
100 if$
101 }
102
103 FUNCTION {field.or.null}
104 { duplicate$ empty$
105 { pop$ "" }
106 'skip$
107 if$
108 }
109
110 FUNCTION {emphasize}
111 { duplicate$ empty$
112 { pop$ "" }
113 { "\emph{" swap$ * "}" * }
114 if$
115 }
116
117 FUNCTION {guillemetize}
118 { duplicate$ empty$
119 { pop$ "" }
120 { "{\og " swap$ * "\fg}" * }
121 if$
122 }
123
124 FUNCTION {scapify}
125 { duplicate$ empty$
126 { pop$ "" }
127 { "{\scshape " swap$ * "}" * }
128 if$
129 }
130
131 FUNCTION {n.dashify}
132 { 't :=
133 ""
134 { t empty$ not }
135 { t #1 #1 substring$ "-" =
136 { t #1 #2 substring$ "--" = not
137 { "--" *
138 t #2 global.max$ substring$ 't :=
139 }
140 { { t #1 #1 substring$ "-" = }
141 { "-" *
142 t #2 global.max$ substring$ 't :=
143 }
144 while$
145 }
146 if$
147 }
148 { t #1 #1 substring$ *
149 t #2 global.max$ substring$ 't :=
150 }
151 if$
152 }
153 while$
154 }
155
156 FUNCTION {tie.or.space.connect}
157 { duplicate$ text.length$ #3 <
158 { "~" }
159 { " " }
160 if$
161 swap$ * *
162 }
163
164 FUNCTION {add.space.if.necessary}
165 { duplicate$ "" =
166 'skip$
167 { " " * }
168 if$
169 }
170
171 FUNCTION {either.or.check}
172 { empty$
173 'pop$
174 { "can't use both " swap$ * " fields in " * cite$ * warning$ }
175 if$
176 }
177
178 FUNCTION {output.nonnull}
179 { 's :=
180 output.state after.name =
181 { extra.label "\bysame" =
182 { ", " * write$ }
183 { " -- " * write$ }
184 if$
185 mid.sentence 'output.state := }
186 { output.state mid.sentence =
187 { ", " * write$ }
188 { output.state before.all =
189 'write$
190 { add.period$ " " * write$ }
191 if$
192 after.name 'output.state := }
193 if$ }
194 if$
195 s
196 }
197
198 FUNCTION {output}
199 { duplicate$ empty$
200 'pop$
201 'output.nonnull
202 if$
203 }
204
205 FUNCTION {missing.warning}
206 { "missing " swap$ * " in " * cite$ * warning$ }
207
208 FUNCTION {output.check}
209 { 't :=
210 duplicate$ empty$
211 { pop$ t missing.warning }
212 'output.nonnull
213 if$
214 }
215
216 FUNCTION {output.bibitem}
217 { newline$
218 "\bibitem{" write$
219 cite$ write$
220 "}" write$
221 newline$
222 ""
223 before.all 'output.state :=
224 }
225
226 FUNCTION {fin.entry}
227 { add.period$
228 write$
229 newline$
230 }
231
232 FUNCTION {format.language}
233 { language empty$
234 { "" }
235 { " (" language * ")" * }
236 if$
237 }
238 INTEGERS { nameptr namesleft numnames }
239
240 FUNCTION {format.names}
241 { 's :=
242 #1 'nameptr :=
243 s num.names$ 'numnames :=
244 numnames 'namesleft :=
245 { namesleft #0 > }
246 { s nameptr "{f.~}{vv~}{ll}{, jj}" format.name$ 't :=
247 nameptr #1 >
248 { namesleft #1 >
249 { ", " * t * }
250 { numnames #2 >
251 { "" * }
252 'skip$
253 if$
254 t "others" =
255 { " {\normalfont et~al.}" * }
256 { " {\normalfont \smfandname} " * t * }
257 if$
258 }
259 if$
260 }
261 't
262 if$
263 nameptr #1 + 'nameptr :=
264 namesleft #1 - 'namesleft :=
265 }
266 while$
267 }
268
269 FUNCTION {format.authors}
270 { author empty$
271 { "" }
272 { extra.label "\bysame" =
273 { "\bysame " }
274 { author format.names scapify }
275 if$
276 }
277 if$
278 }
279
280 FUNCTION {format.editors}
281 { editor empty$
282 { "" }
283 { extra.label "\bysame" =
284 { "\bysame " }
285 { editor format.names scapify }
286 if$
287 editor num.names$ #1 >
288 { " (\smfedsname)" * }
289 { " (\smfedname)" * }
290 if$
291 "\nomorebysame" 'extra.label :=
292 }
293 if$
294 }
295
296 FUNCTION {format.nonauthor.editors}
297 { editor empty$
298 { "" }
299 { editor format.names
300 editor num.names$ #1 >
301 { ", \smfedsname" * }
302 { ", \smfedname" * }
303 if$
304 }
305 if$
306 }
307
308 FUNCTION {format.booktitle}
309 { title empty$
310 { "" }
311 { title "t" change.case$ emphasize }
312 if$
313 }
314
315 FUNCTION {format.title}
316 { title empty$
317 { "" }
318 { title "t" change.case$ guillemetize }
319 if$
320 }
321
322 FUNCTION {format.journal.vol.year}
323 { journal empty$
324 { "journal name" missing.warning ""}
325 { journal emphasize }
326 if$
327 volume empty$
328 'skip$
329 { " \textbf{" * volume * "}" * }
330 if$
331 year empty$
332 { "year" missing.warning }
333 { " (" * year * ")" * }
334 if$
335 }
336
337 FUNCTION {format.number}
338 { number empty$
339 { "" }
340 { "no.~" number * }
341 if$
342 }
343
344 FUNCTION {format.date}
345 { year empty$
346 { month empty$
347 { "" }
348 { "there's a month but no year in " cite$ * warning$
349 month
350 }
351 if$
352 }
353 { month empty$
354 'year
355 { month " " * year * }
356 if$
357 }
358 if$
359 }
360
361 FUNCTION {format.bookvolume.series.number}
362 { volume empty$
363 { "" % Push the empty string as a placeholder in case everything else
364 % is empty too.
365 series empty$
366 'skip$
367 { pop$ series } % if series is not empty put in stack
368 if$
369 number empty$
370 'skip$
371 { duplicate$ empty$ % if no preceding material,
372 'skip$ % do nothing, otherwise
373 { ", " * } % add a comma and space to separate.
374 if$
375 "no." number tie.or.space.connect * % add the number information
376 }
377 if$
378 }
379 %% If the volume is NOT EMPTY:
380 { "vol." volume tie.or.space.connect % vol. XX
381 number empty$
382 { series empty$
383 'skip$
384 { series ", " * swap$ *} % Series Name, vol. XX
385 if$
386 }
387 { series empty$
388 { "can't use both volume and number if series info is missing"
389 warning$
390 "in BibTeX entry type `" type$ * "'" * top$
391 }
392 { ", " * series * ", no." * number tie.or.space.connect }
393 if$
394 }
395 if$
396 }
397 if$
398
399 } % end of format.bookvolume.series.number
400
401 %% format.inproc.title.where.editors is used by inproceedings entry types
402
403 FUNCTION {format.inproc.title.address.editors}
404 { booktitle empty$
405 { "" }
406 %% Emphasizing the title. We want initial caps, roman.
407 { "in " booktitle emphasize * }
408 if$
409 %% We add parentheses around the address (place where conference
410 %% was held).
411 address empty$
412 'skip$
413 { add.space.if.necessary "(" * address * ")" * }
414 if$
415 %% Likewise we add parentheses around the editors' names.
416 editor empty$
417 'skip$
418 { add.space.if.necessary "(" * format.nonauthor.editors * ")" * }
419 if$
420 }
421
422 %% format.incoll.title.editors is similar to format.inproc... but
423 %% omits the address. For collections that are not proceedings volumes.
424
425 FUNCTION {format.incoll.title.editors}
426 { booktitle empty$
427 { "" }
428 %% Emphasizing the title. We want initial caps
429 { "in " booktitle emphasize * }
430 if$
431 %% We add parentheses around the editors' names.
432 editor empty$
433 'skip$
434 { add.space.if.necessary "(" * format.nonauthor.editors * ")" * }
435 if$
436 }
437
438 FUNCTION {format.number.series}
439 { series empty$
440 { number empty$
441 { "" }
442 { "there's a number but no series in " cite$ * warning$ }
443 if$
444 }
445 { series
446 number empty$
447 'skip$
448 { "\ \textbf{" * number * "}" * }
449 if$
450 }
451 if$
452 }
453
454 FUNCTION {format.edition}
455 { edition empty$
456 { "" }
457 { output.state mid.sentence =
458 { edition "l" change.case$ " \smfedname" * }
459 { edition "t" change.case$ " \smfedname" * }
460 if$
461 }
462 if$
463 }
464
465 INTEGERS { multiresult }
466
467 FUNCTION {multi.page.check}
468 { 't :=
469 #0 'multiresult :=
470 { multiresult not
471 t empty$ not
472 and
473 }
474 { t #1 #1 substring$
475 duplicate$ "-" =
476 swap$ duplicate$ "," =
477 swap$ "+" =
478 or or
479 { #1 'multiresult := }
480 { t #2 global.max$ substring$ 't := }
481 if$
482 }
483 while$
484 multiresult
485 }
486
487 FUNCTION {format.pages}
488 { pages empty$
489 { "" }
490 { "p.~" pages n.dashify * }
491 if$
492 }
493
494 FUNCTION {format.book.pages}
495 { pages empty$
496 { "" }
497 { pages multi.page.check
498 { "p.~" pages n.dashify * }
499 { "p.~" pages * }
500 if$
501 }
502 if$
503 }
504
505 FUNCTION {format.chapter.pages}
506 { chapter empty$
507 'format.pages
508 { type empty$
509 { "ch.~" }
510 { type "l" change.case$ " " * }
511 if$
512 chapter *
513 pages empty$
514 'skip$
515 { ", " * format.book.pages * }
516 if$
517 }
518 if$
519 }
520
521 FUNCTION {empty.misc.check}
522 { author empty$ title empty$ howpublished empty$
523 month empty$ year empty$ note empty$
524 and and and and and
525 key empty$ not and
526 { "all relevant fields are empty in " cite$ * warning$ }
527 'skip$
528 if$
529 }
530
531 FUNCTION {format.thesis.type}
532 { type empty$
533 'skip$
534 { pop$
535 type "t" change.case$
536 }
537 if$
538 }
539
540 FUNCTION {format.tr.number}
541 { type empty$
542 { "Tech. Report" }
543 'type
544 if$
545 number empty$
546 { "t" change.case$ }
547 { number tie.or.space.connect }
548 if$
549 }
550
551 FUNCTION {format.article.crossref}
552 { key empty$
553 { journal empty$
554 { "need key or journal for " cite$ * " to crossref " * crossref *
555 warning$
556 ""
557 }
558 { "in " journal * }
559 if$
560 }
561 { "in " key * }
562 if$
563 " \cite{" * crossref * "}" *
564 }
565
566 FUNCTION {format.crossref.editor}
567 { editor #1 "{vv~}{ll}" format.name$
568 editor num.names$ duplicate$
569 #2 >
570 { pop$ " et~al." * }
571 { #2 <
572 'skip$
573 { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
574 { " et~al." * }
575 { " \smfandname\ " * editor #2 "{vv~}{ll}" format.name$ * }
576 if$
577 }
578 if$
579 }
580 if$
581 }
582
583 FUNCTION {format.book.crossref}
584 { volume empty$
585 { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
586 "in "
587 }
588 { "vol." volume tie.or.space.connect
589 " de " *
590 }
591 if$
592 editor empty$
593 editor field.or.null author field.or.null =
594 or
595 { key empty$
596 { series empty$
597 { "need editor, key, or series for " cite$ * " to crossref " *
598 crossref * warning$
599 "" *
600 }
601 { series * }
602 if$
603 }
604 { key * }
605 if$
606 }
607 { format.crossref.editor * }
608 if$
609 " \cite{" * crossref * "}" *
610 }
611
612 FUNCTION {format.incoll.inproc.crossref}
613 { key empty$
614 { booktitle empty$
615 { editor empty$
616 editor field.or.null author field.or.null =
617 or
618 { "need editor, key, or booktitle for " cite$ * "to crossref " *
619 crossref * warning$ "" }
620 { "in " format.crossref.editor * }
621 if$ }
622 { "in " booktitle emphasize * }
623 if$ }
624 { "in " key * }
625 if$
626 " \cite{" * crossref * "}" *
627 }
628
629 FUNCTION {article}
630 { output.bibitem
631 format.authors "author" output.check
632 format.title "title" output.check
633 crossref missing$
634 { format.journal.vol.year output
635 format.number output
636 format.pages "pages" output.check
637 }
638 { format.article.crossref output.nonnull
639 format.pages output
640 }
641 if$
642 format.language *
643 note output
644 fin.entry
645 }
646
647 FUNCTION {book}
648 { output.bibitem
649 author empty$
650 { format.editors "author and editor" output.check }
651 { format.authors output.nonnull
652 crossref missing$
653 { "author and editor" editor either.or.check }
654 'skip$
655 if$
656 }
657 if$
658 format.booktitle "title" output.check
659 format.edition output
660 crossref missing$
661 { format.bookvolume.series.number output
662 publisher "publisher" output.check
663 address output
664 }
665 { format.book.crossref output.nonnull
666 }
667 if$
668 format.date "year" output.check
669 format.language *
670 note output
671 fin.entry
672 }
673 FUNCTION {booklet}
674 { output.bibitem
675 format.authors output
676 format.booktitle "title" output.check
677 howpublished output
678 address output
679 format.date output
680 note output
681 fin.entry
682 }
683
684 FUNCTION {inbook}
685 { output.bibitem
686 author empty$
687 { format.editors "author and editor" output.check }
688 { format.authors output.nonnull
689 crossref missing$
690 { "author and editor" editor either.or.check }
691 'skip$
692 if$
693 }
694 if$
695 format.title "title" output.check
696 crossref missing$
697 { format.bookvolume.series.number output
698 format.chapter.pages "chapter and pages" output.check
699 format.number.series output
700 publisher "publisher" output.check
701 address output
702 }
703 { format.chapter.pages "chapter and pages" output.check
704 format.book.crossref output.nonnull
705 }
706 if$
707 format.edition output
708 format.date "year" output.check
709 format.language *
710 note output
711 fin.entry
712 }
713
714 FUNCTION {incollection}
715 { output.bibitem
716 format.authors "author" output.check
717 format.title "title" output.check
718 crossref missing$
719 { format.incoll.title.editors "booktitle" output.check
720 format.bookvolume.series.number output
721 publisher "publisher" output.check
722 address output
723 format.edition output
724 format.date "year" output.check
725 }
726 { format.incoll.inproc.crossref output.nonnull
727 }
728 if$
729 note output
730 format.book.pages output
731 format.language *
732 fin.entry
733 }
734
735 FUNCTION {inproceedings}
736 { output.bibitem
737 format.authors "author" output.check
738 format.title "title" output.check
739 crossref missing$
740 { format.inproc.title.address.editors "booktitle" output.check
741 format.bookvolume.series.number output
742 organization output
743 publisher output
744 format.date "year" output.check
745 }
746 { format.incoll.inproc.crossref output.nonnull
747 }
748 if$
749 note output
750 format.book.pages output
751 format.language *
752 fin.entry
753 }
754
755 FUNCTION {conference} { inproceedings }
756
757 FUNCTION {manual}
758 { output.bibitem
759 author empty$
760 { organization empty$
761 'skip$
762 { organization output.nonnull
763 address output
764 }
765 if$
766 }
767 { format.authors output.nonnull }
768 if$
769 format.booktitle "title" output.check
770 author empty$
771 { organization empty$
772 { address output }
773 'skip$
774 if$
775 }
776 { organization output
777 address output
778 }
779 if$
780 format.edition output
781 format.date output
782 note output
783 fin.entry
784 }
785
786 FUNCTION {mastersthesis}
787 { output.bibitem
788 format.authors "author" output.check
789 format.booktitle "title" output.check
790 "\smfmastersthesisname" format.thesis.type output.nonnull
791 school "school" output.check
792 address output
793 format.date "year" output.check
794 note output
795 fin.entry
796 }
797
798 FUNCTION {phdthesis}
799 { output.bibitem
800 format.authors "author" output.check
801 format.title "title" output.check
802 "\smfphdthesisname" format.thesis.type output.nonnull
803 school "school" output.check
804 address output
805 format.date "year" output.check
806 note output
807 format.book.pages output
808 fin.entry
809 }
810
811 FUNCTION {proceedings}
812 { output.bibitem
813 editor empty$
814 { organization output }
815 { format.editors output.nonnull }
816 if$
817 format.booktitle "title" output.check
818 format.bookvolume.series.number output
819 address empty$
820 { editor empty$
821 'skip$
822 { organization output }
823 if$
824 publisher output
825 format.date "year" output.check
826 }
827 { address output.nonnull
828 editor empty$
829 'skip$
830 { organization output }
831 if$
832 publisher output
833 format.date "year" output.check
834 }
835 if$
836 note output
837 fin.entry
838 }
839
840 FUNCTION {techreport}
841 { output.bibitem
842 format.authors "author" output.check
843 format.title "title" output.check
844 format.tr.number output.nonnull
845 institution "institution" output.check
846 address output
847 format.date "year" output.check
848 note output
849 fin.entry
850 }
851
852 FUNCTION {misc}
853 { output.bibitem
854 format.authors output
855 format.title output
856 howpublished output
857 format.date output
858 note output
859 format.book.pages output
860 fin.entry
861 empty.misc.check
862 }
863
864 FUNCTION {unpublished}
865 { output.bibitem
866 format.authors "author" output.check
867 format.title "title" output.check
868 note "note" output.check
869 format.date output
870 fin.entry
871 }
872 FUNCTION {default.type} { misc }
873 READ
874
875 FUNCTION {sortify}
876 { purify$
877 "l" change.case$
878 }
879
880 INTEGERS { len }
881
882 FUNCTION {chop.word}
883 { 's :=
884 'len :=
885 s #1 len substring$ =
886 { s len #1 + global.max$ substring$ }
887 's
888 if$
889 }
890
891 FUNCTION {sort.format.names}
892 { 's :=
893 #1 'nameptr :=
894 ""
895 s num.names$ 'numnames :=
896 numnames 'namesleft :=
897 { namesleft #0 > }
898 { nameptr #1 >
899 { " " * }
900 'skip$
901 if$
902 %% s nameptr "{vv{ } }{ll{ }}{ ff{ }}{ jj{ }}" format.name$ 't :=
903 s nameptr "{ll{ }}{ ff{ }}{ jj{ }}" format.name$ 't :=
904 nameptr numnames = t "others" = and
905 { "et~al" * }
906 { t sortify * }
907 if$
908 nameptr #1 + 'nameptr :=
909 namesleft #1 - 'namesleft :=
910 }
911 while$
912 }
913
914 FUNCTION {sort.format.title}
915 { 't :=
916 "A " #2
917 "An " #3
918 "The " #4 t chop.word
919 chop.word
920 chop.word
921 sortify
922 #1 global.max$ substring$
923 }
924
925 FUNCTION {author.sort}
926 { author empty$
927 { key empty$
928 { "to sort, need author or key in " cite$ * warning$
929 ""
930 }
931 { key sortify }
932 if$
933 }
934 { author sort.format.names }
935 if$
936 }
937
938 FUNCTION {author.editor.sort}
939 { author empty$
940 { editor empty$
941 { key empty$
942 { "to sort, need author, editor, or key in " cite$ * warning$
943 ""
944 }
945 { key sortify }
946 if$
947 }
948 { editor sort.format.names }
949 if$
950 }
951 { author sort.format.names }
952 if$
953 }
954
955 FUNCTION {author.organization.sort}
956 { author empty$
957 { organization empty$
958 { key empty$
959 { "to sort, need author, organization, or key in " cite$ * warning$
960 ""
961 }
962 { key sortify }
963 if$
964 }
965 { "The " #4 organization chop.word sortify }
966 if$
967 }
968 { author sort.format.names }
969 if$
970 }
971
972 FUNCTION {editor.organization.sort}
973 { editor empty$
974 { organization empty$
975 { key empty$
976 { "to sort, need editor, organization, or key in " cite$ * warning$
977 ""
978 }
979 { key sortify }
980 if$
981 }
982 { "The " #4 organization chop.word sortify }
983 if$
984 }
985 { editor sort.format.names }
986 if$
987 }
988
989 FUNCTION {presort}
990 {
991 type$ "book" =
992 type$ "inbook" =
993 or
994 'author.editor.sort
995 { type$ "proceedings" =
996 'editor.organization.sort
997 { type$ "manual" =
998 'author.organization.sort
999 'author.sort
1000 if$
1001 }
1002 if$
1003 }
1004 if$
1005 " "
1006 *
1007 year field.or.null sortify
1008 *
1009 " "
1010 *
1011 title field.or.null
1012 sort.format.title
1013 *
1014 #1 entry.max$ substring$
1015 'sort.key$ :=
1016 }
1017
1018 ITERATE {presort}
1019
1020 SORT
1021 STRINGS { longest.label prev.author this.author }
1022
1023 INTEGERS { number.label longest.label.width }
1024
1025 FUNCTION {initialize.longest.label}
1026 { "" 'longest.label :=
1027 #1 'number.label :=
1028 #0 'longest.label.width :=
1029 "abcxyz" 'prev.author :=
1030 "" 'this.author :=
1031 }
1032
1033 FUNCTION {longest.label.pass}
1034 { number.label int.to.str$ 'label :=
1035 number.label #1 + 'number.label :=
1036 label width$ longest.label.width >
1037 { label 'longest.label :=
1038 label width$ 'longest.label.width :=
1039 }
1040 'skip$
1041 if$
1042 author empty$
1043 { editor empty$
1044 { "" }
1045 'editor
1046 if$
1047 }
1048 'author
1049 if$
1050 'this.author :=
1051 this.author prev.author =
1052 { "\bysame" 'extra.label := }
1053 { "" 'extra.label :=
1054 this.author "" =
1055 { "abcxyz" }
1056 'this.author
1057 if$
1058 'prev.author :=
1059 }
1060 if$
1061 }
1062
1063 EXECUTE {initialize.longest.label}
1064
1065 ITERATE {longest.label.pass}
1066 FUNCTION {begin.bib}
1067 {
1068 preamble$ empty$
1069 'skip$
1070 { preamble$ write$ newline$ }
1071 if$
1072 "\providecommand{\bysame}{\leavevmode ---\ }" write$ newline$
1073 "\providecommand{\og}{``}" write$ newline$
1074 "\providecommand{\fg}{''}" write$ newline$
1075 "\providecommand{\smfandname}{\&}" write$ newline$
1076 "\providecommand{\smfedsname}{\'eds.}" write$ newline$
1077 "\providecommand{\smfedname}{\'ed.}" write$ newline$
1078 "\providecommand{\smfmastersthesisname}{M\'emoire}" write$ newline$
1079 "\providecommand{\smfphdthesisname}{Th\`ese}" write$ newline$
1080 "\begin{thebibliography}{" longest.label * "}" * write$ newline$
1081 }
1082
1083 EXECUTE {begin.bib}
1084
1085 EXECUTE {init.state.consts}
1086
1087 ITERATE {call.type$}
1088
1089 FUNCTION {end.bib}
1090 { newline$
1091 "\end{thebibliography}" write$ newline$
1092 }
1093
1094 EXECUTE {end.bib}
1095 %%
1096 %%
1097 %% End of file `smfplain.bst'.