Debian Codegraph @

texmf-dist/bibtex/bst/multibib/mbplain.bst

raw
1 %
2 % This is file `mbplain.bst', modified from file `plain.bst'
3 % to be used with package multibib.
4 %
5 % 1999/12/28 Thorsten Hansen, [email protected]
6 %
7 % Changes:
8 % . Function longest.label.pass modified to count the labels.
9 %
10 % version 0.99a for BibTeX versions 0.99a or later, LaTeX version 2.09.
11 % Copyright (C) 1985, all rights reserved.
12 % Copying of this file is authorized only if either
13 % (1) you make absolutely no changes to your copy, including name, or
14 % (2) if you do make changes, you name it something other than
15 % btxbst.doc, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
16 % This restriction helps ensure that all standard styles are identical.
17 % The file btxbst.doc has the documentation for this style.
18
19 ENTRY
20 { address
21 author
22 booktitle
23 chapter
24 edition
25 editor
26 howpublished
27 institution
28 journal
29 key
30 month
31 note
32 number
33 organization
34 pages
35 publisher
36 school
37 series
38 title
39 type
40 volume
41 year
42 }
43 {}
44 { label }
45
46 INTEGERS { output.state before.all mid.sentence after.sentence after.block }
47
48 FUNCTION {init.state.consts}
49 { #0 'before.all :=
50 #1 'mid.sentence :=
51 #2 'after.sentence :=
52 #3 'after.block :=
53 }
54
55 STRINGS { s t }
56
57 FUNCTION {output.nonnull}
58 { 's :=
59 output.state mid.sentence =
60 { ", " * write$ }
61 { output.state after.block =
62 { add.period$ write$
63 newline$
64 "\newblock " write$
65 }
66 { output.state before.all =
67 'write$
68 { add.period$ " " * write$ }
69 if$
70 }
71 if$
72 mid.sentence 'output.state :=
73 }
74 if$
75 s
76 }
77
78 FUNCTION {output}
79 { duplicate$ empty$
80 'pop$
81 'output.nonnull
82 if$
83 }
84
85 FUNCTION {output.check}
86 { 't :=
87 duplicate$ empty$
88 { pop$ "empty " t * " in " * cite$ * warning$ }
89 'output.nonnull
90 if$
91 }
92
93 FUNCTION {output.bibitem}
94 { newline$
95 "\bibitem{" write$
96 cite$ write$
97 "}" write$
98 newline$
99 ""
100 before.all 'output.state :=
101 }
102
103 FUNCTION {fin.entry}
104 { add.period$
105 write$
106 newline$
107 }
108
109 FUNCTION {new.block}
110 { output.state before.all =
111 'skip$
112 { after.block 'output.state := }
113 if$
114 }
115
116 FUNCTION {new.sentence}
117 { output.state after.block =
118 'skip$
119 { output.state before.all =
120 'skip$
121 { after.sentence 'output.state := }
122 if$
123 }
124 if$
125 }
126
127 FUNCTION {not}
128 { { #0 }
129 { #1 }
130 if$
131 }
132
133 FUNCTION {and}
134 { 'skip$
135 { pop$ #0 }
136 if$
137 }
138
139 FUNCTION {or}
140 { { pop$ #1 }
141 'skip$
142 if$
143 }
144
145 FUNCTION {new.block.checka}
146 { empty$
147 'skip$
148 'new.block
149 if$
150 }
151
152 FUNCTION {new.block.checkb}
153 { empty$
154 swap$ empty$
155 and
156 'skip$
157 'new.block
158 if$
159 }
160
161 FUNCTION {new.sentence.checka}
162 { empty$
163 'skip$
164 'new.sentence
165 if$
166 }
167
168 FUNCTION {new.sentence.checkb}
169 { empty$
170 swap$ empty$
171 and
172 'skip$
173 'new.sentence
174 if$
175 }
176
177 FUNCTION {field.or.null}
178 { duplicate$ empty$
179 { pop$ "" }
180 'skip$
181 if$
182 }
183
184 FUNCTION {emphasize}
185 { duplicate$ empty$
186 { pop$ "" }
187 { "{\em " swap$ * "}" * }
188 if$
189 }
190
191 INTEGERS { nameptr namesleft numnames }
192
193 FUNCTION {format.names}
194 { 's :=
195 #1 'nameptr :=
196 s num.names$ 'numnames :=
197 numnames 'namesleft :=
198 { namesleft #0 > }
199 { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ 't :=
200 nameptr #1 >
201 { namesleft #1 >
202 { ", " * t * }
203 { numnames #2 >
204 { "," * }
205 'skip$
206 if$
207 t "others" =
208 { " et~al." * }
209 { " and " * t * }
210 if$
211 }
212 if$
213 }
214 't
215 if$
216 nameptr #1 + 'nameptr :=
217 namesleft #1 - 'namesleft :=
218 }
219 while$
220 }
221
222 FUNCTION {format.authors}
223 { author empty$
224 { "" }
225 { author format.names }
226 if$
227 }
228
229 FUNCTION {format.editors}
230 { editor empty$
231 { "" }
232 { editor format.names
233 editor num.names$ #1 >
234 { ", editors" * }
235 { ", editor" * }
236 if$
237 }
238 if$
239 }
240
241 FUNCTION {format.title}
242 { title empty$
243 { "" }
244 { title "t" change.case$ }
245 if$
246 }
247
248 FUNCTION {n.dashify}
249 { 't :=
250 ""
251 { t empty$ not }
252 { t #1 #1 substring$ "-" =
253 { t #1 #2 substring$ "--" = not
254 { "--" *
255 t #2 global.max$ substring$ 't :=
256 }
257 { { t #1 #1 substring$ "-" = }
258 { "-" *
259 t #2 global.max$ substring$ 't :=
260 }
261 while$
262 }
263 if$
264 }
265 { t #1 #1 substring$ *
266 t #2 global.max$ substring$ 't :=
267 }
268 if$
269 }
270 while$
271 }
272
273 FUNCTION {format.date}
274 { year empty$
275 { month empty$
276 { "" }
277 { "there's a month but no year in " cite$ * warning$
278 month
279 }
280 if$
281 }
282 { month empty$
283 'year
284 { month " " * year * }
285 if$
286 }
287 if$
288 }
289
290 FUNCTION {format.btitle}
291 { title emphasize
292 }
293
294 FUNCTION {tie.or.space.connect}
295 { duplicate$ text.length$ #3 <
296 { "~" }
297 { " " }
298 if$
299 swap$ * *
300 }
301
302 FUNCTION {either.or.check}
303 { empty$
304 'pop$
305 { "can't use both " swap$ * " fields in " * cite$ * warning$ }
306 if$
307 }
308
309 FUNCTION {format.bvolume}
310 { volume empty$
311 { "" }
312 { "volume" volume tie.or.space.connect
313 series empty$
314 'skip$
315 { " of " * series emphasize * }
316 if$
317 "volume and number" number either.or.check
318 }
319 if$
320 }
321
322 FUNCTION {format.number.series}
323 { volume empty$
324 { number empty$
325 { series field.or.null }
326 { output.state mid.sentence =
327 { "number" }
328 { "Number" }
329 if$
330 number tie.or.space.connect
331 series empty$
332 { "there's a number but no series in " cite$ * warning$ }
333 { " in " * series * }
334 if$
335 }
336 if$
337 }
338 { "" }
339 if$
340 }
341
342 FUNCTION {format.edition}
343 { edition empty$
344 { "" }
345 { output.state mid.sentence =
346 { edition "l" change.case$ " edition" * }
347 { edition "t" change.case$ " edition" * }
348 if$
349 }
350 if$
351 }
352
353 INTEGERS { multiresult }
354
355 FUNCTION {multi.page.check}
356 { 't :=
357 #0 'multiresult :=
358 { multiresult not
359 t empty$ not
360 and
361 }
362 { t #1 #1 substring$
363 duplicate$ "-" =
364 swap$ duplicate$ "," =
365 swap$ "+" =
366 or or
367 { #1 'multiresult := }
368 { t #2 global.max$ substring$ 't := }
369 if$
370 }
371 while$
372 multiresult
373 }
374
375 FUNCTION {format.pages}
376 { pages empty$
377 { "" }
378 { pages multi.page.check
379 { "pages" pages n.dashify tie.or.space.connect }
380 { "page" pages tie.or.space.connect }
381 if$
382 }
383 if$
384 }
385
386 FUNCTION {format.vol.num.pages}
387 { volume field.or.null
388 number empty$
389 'skip$
390 { "(" number * ")" * *
391 volume empty$
392 { "there's a number but no volume in " cite$ * warning$ }
393 'skip$
394 if$
395 }
396 if$
397 pages empty$
398 'skip$
399 { duplicate$ empty$
400 { pop$ format.pages }
401 { ":" * pages n.dashify * }
402 if$
403 }
404 if$
405 }
406
407 FUNCTION {format.chapter.pages}
408 { chapter empty$
409 'format.pages
410 { type empty$
411 { "chapter" }
412 { type "l" change.case$ }
413 if$
414 chapter tie.or.space.connect
415 pages empty$
416 'skip$
417 { ", " * format.pages * }
418 if$
419 }
420 if$
421 }
422
423 FUNCTION {format.in.ed.booktitle}
424 { booktitle empty$
425 { "" }
426 { editor empty$
427 { "In " booktitle emphasize * }
428 { "In " format.editors * ", " * booktitle emphasize * }
429 if$
430 }
431 if$
432 }
433
434 FUNCTION {empty.misc.check}
435 { author empty$ title empty$ howpublished empty$
436 month empty$ year empty$ note empty$
437 and and and and and
438 key empty$ not and
439 { "all relevant fields are empty in " cite$ * warning$ }
440 'skip$
441 if$
442 }
443
444 FUNCTION {format.thesis.type}
445 { type empty$
446 'skip$
447 { pop$
448 type "t" change.case$
449 }
450 if$
451 }
452
453 FUNCTION {format.tr.number}
454 { type empty$
455 { "Technical Report" }
456 'type
457 if$
458 number empty$
459 { "t" change.case$ }
460 { number tie.or.space.connect }
461 if$
462 }
463
464 FUNCTION {format.article.crossref}
465 { key empty$
466 { journal empty$
467 { "need key or journal for " cite$ * " to crossref " * crossref *
468 warning$
469 ""
470 }
471 { "In {\em " journal * "\/}" * }
472 if$
473 }
474 { "In " key * }
475 if$
476 " \cite{" * crossref * "}" *
477 }
478
479 FUNCTION {format.crossref.editor}
480 { editor #1 "{vv~}{ll}" format.name$
481 editor num.names$ duplicate$
482 #2 >
483 { pop$ " et~al." * }
484 { #2 <
485 'skip$
486 { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
487 { " et~al." * }
488 { " and " * editor #2 "{vv~}{ll}" format.name$ * }
489 if$
490 }
491 if$
492 }
493 if$
494 }
495
496 FUNCTION {format.book.crossref}
497 { volume empty$
498 { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
499 "In "
500 }
501 { "Volume" volume tie.or.space.connect
502 " of " *
503 }
504 if$
505 editor empty$
506 editor field.or.null author field.or.null =
507 or
508 { key empty$
509 { series empty$
510 { "need editor, key, or series for " cite$ * " to crossref " *
511 crossref * warning$
512 "" *
513 }
514 { "{\em " * series * "\/}" * }
515 if$
516 }
517 { key * }
518 if$
519 }
520 { format.crossref.editor * }
521 if$
522 " \cite{" * crossref * "}" *
523 }
524
525 FUNCTION {format.incoll.inproc.crossref}
526 { editor empty$
527 editor field.or.null author field.or.null =
528 or
529 { key empty$
530 { booktitle empty$
531 { "need editor, key, or booktitle for " cite$ * " to crossref " *
532 crossref * warning$
533 ""
534 }
535 { "In {\em " booktitle * "\/}" * }
536 if$
537 }
538 { "In " key * }
539 if$
540 }
541 { "In " format.crossref.editor * }
542 if$
543 " \cite{" * crossref * "}" *
544 }
545
546 FUNCTION {article}
547 { output.bibitem
548 format.authors "author" output.check
549 new.block
550 format.title "title" output.check
551 new.block
552 crossref missing$
553 { journal emphasize "journal" output.check
554 format.vol.num.pages output
555 format.date "year" output.check
556 }
557 { format.article.crossref output.nonnull
558 format.pages output
559 }
560 if$
561 new.block
562 note output
563 fin.entry
564 }
565
566 FUNCTION {book}
567 { output.bibitem
568 author empty$
569 { format.editors "author and editor" output.check }
570 { format.authors output.nonnull
571 crossref missing$
572 { "author and editor" editor either.or.check }
573 'skip$
574 if$
575 }
576 if$
577 new.block
578 format.btitle "title" output.check
579 crossref missing$
580 { format.bvolume output
581 new.block
582 format.number.series output
583 new.sentence
584 publisher "publisher" output.check
585 address output
586 }
587 { new.block
588 format.book.crossref output.nonnull
589 }
590 if$
591 format.edition output
592 format.date "year" output.check
593 new.block
594 note output
595 fin.entry
596 }
597
598 FUNCTION {booklet}
599 { output.bibitem
600 format.authors output
601 new.block
602 format.title "title" output.check
603 howpublished address new.block.checkb
604 howpublished output
605 address output
606 format.date output
607 new.block
608 note output
609 fin.entry
610 }
611
612 FUNCTION {inbook}
613 { output.bibitem
614 author empty$
615 { format.editors "author and editor" output.check }
616 { format.authors output.nonnull
617 crossref missing$
618 { "author and editor" editor either.or.check }
619 'skip$
620 if$
621 }
622 if$
623 new.block
624 format.btitle "title" output.check
625 crossref missing$
626 { format.bvolume output
627 format.chapter.pages "chapter and pages" output.check
628 new.block
629 format.number.series output
630 new.sentence
631 publisher "publisher" output.check
632 address output
633 }
634 { format.chapter.pages "chapter and pages" output.check
635 new.block
636 format.book.crossref output.nonnull
637 }
638 if$
639 format.edition output
640 format.date "year" output.check
641 new.block
642 note output
643 fin.entry
644 }
645
646 FUNCTION {incollection}
647 { output.bibitem
648 format.authors "author" output.check
649 new.block
650 format.title "title" output.check
651 new.block
652 crossref missing$
653 { format.in.ed.booktitle "booktitle" output.check
654 format.bvolume output
655 format.number.series output
656 format.chapter.pages output
657 new.sentence
658 publisher "publisher" output.check
659 address output
660 format.edition output
661 format.date "year" output.check
662 }
663 { format.incoll.inproc.crossref output.nonnull
664 format.chapter.pages output
665 }
666 if$
667 new.block
668 note output
669 fin.entry
670 }
671
672 FUNCTION {inproceedings}
673 { output.bibitem
674 format.authors "author" output.check
675 new.block
676 format.title "title" output.check
677 new.block
678 crossref missing$
679 { format.in.ed.booktitle "booktitle" output.check
680 format.bvolume output
681 format.number.series output
682 format.pages output
683 address empty$
684 { organization publisher new.sentence.checkb
685 organization output
686 publisher output
687 format.date "year" output.check
688 }
689 { address output.nonnull
690 format.date "year" output.check
691 new.sentence
692 organization output
693 publisher output
694 }
695 if$
696 }
697 { format.incoll.inproc.crossref output.nonnull
698 format.pages output
699 }
700 if$
701 new.block
702 note output
703 fin.entry
704 }
705
706 FUNCTION {conference} { inproceedings }
707
708 FUNCTION {manual}
709 { output.bibitem
710 author empty$
711 { organization empty$
712 'skip$
713 { organization output.nonnull
714 address output
715 }
716 if$
717 }
718 { format.authors output.nonnull }
719 if$
720 new.block
721 format.btitle "title" output.check
722 author empty$
723 { organization empty$
724 { address new.block.checka
725 address output
726 }
727 'skip$
728 if$
729 }
730 { organization address new.block.checkb
731 organization output
732 address output
733 }
734 if$
735 format.edition output
736 format.date output
737 new.block
738 note output
739 fin.entry
740 }
741
742 FUNCTION {mastersthesis}
743 { output.bibitem
744 format.authors "author" output.check
745 new.block
746 format.title "title" output.check
747 new.block
748 "Master's thesis" format.thesis.type output.nonnull
749 school "school" output.check
750 address output
751 format.date "year" output.check
752 new.block
753 note output
754 fin.entry
755 }
756
757 FUNCTION {misc}
758 { output.bibitem
759 format.authors output
760 title howpublished new.block.checkb
761 format.title output
762 howpublished new.block.checka
763 howpublished output
764 format.date output
765 new.block
766 note output
767 fin.entry
768 empty.misc.check
769 }
770
771 FUNCTION {phdthesis}
772 { output.bibitem
773 format.authors "author" output.check
774 new.block
775 format.btitle "title" output.check
776 new.block
777 "PhD thesis" format.thesis.type output.nonnull
778 school "school" output.check
779 address output
780 format.date "year" output.check
781 new.block
782 note output
783 fin.entry
784 }
785
786 FUNCTION {proceedings}
787 { output.bibitem
788 editor empty$
789 { organization output }
790 { format.editors output.nonnull }
791 if$
792 new.block
793 format.btitle "title" output.check
794 format.bvolume output
795 format.number.series output
796 address empty$
797 { editor empty$
798 { publisher new.sentence.checka }
799 { organization publisher new.sentence.checkb
800 organization output
801 }
802 if$
803 publisher output
804 format.date "year" output.check
805 }
806 { address output.nonnull
807 format.date "year" output.check
808 new.sentence
809 editor empty$
810 'skip$
811 { organization output }
812 if$
813 publisher output
814 }
815 if$
816 new.block
817 note output
818 fin.entry
819 }
820
821 FUNCTION {techreport}
822 { output.bibitem
823 format.authors "author" output.check
824 new.block
825 format.title "title" output.check
826 new.block
827 format.tr.number output.nonnull
828 institution "institution" output.check
829 address output
830 format.date "year" output.check
831 new.block
832 note output
833 fin.entry
834 }
835
836 FUNCTION {unpublished}
837 { output.bibitem
838 format.authors "author" output.check
839 new.block
840 format.title "title" output.check
841 new.block
842 note "note" output.check
843 format.date output
844 fin.entry
845 }
846
847 FUNCTION {default.type} { misc }
848
849 MACRO {jan} {"January"}
850
851 MACRO {feb} {"February"}
852
853 MACRO {mar} {"March"}
854
855 MACRO {apr} {"April"}
856
857 MACRO {may} {"May"}
858
859 MACRO {jun} {"June"}
860
861 MACRO {jul} {"July"}
862
863 MACRO {aug} {"August"}
864
865 MACRO {sep} {"September"}
866
867 MACRO {oct} {"October"}
868
869 MACRO {nov} {"November"}
870
871 MACRO {dec} {"December"}
872
873 MACRO {acmcs} {"ACM Computing Surveys"}
874
875 MACRO {acta} {"Acta Informatica"}
876
877 MACRO {cacm} {"Communications of the ACM"}
878
879 MACRO {ibmjrd} {"IBM Journal of Research and Development"}
880
881 MACRO {ibmsj} {"IBM Systems Journal"}
882
883 MACRO {ieeese} {"IEEE Transactions on Software Engineering"}
884
885 MACRO {ieeetc} {"IEEE Transactions on Computers"}
886
887 MACRO {ieeetcad}
888 {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
889
890 MACRO {ipl} {"Information Processing Letters"}
891
892 MACRO {jacm} {"Journal of the ACM"}
893
894 MACRO {jcss} {"Journal of Computer and System Sciences"}
895
896 MACRO {scp} {"Science of Computer Programming"}
897
898 MACRO {sicomp} {"SIAM Journal on Computing"}
899
900 MACRO {tocs} {"ACM Transactions on Computer Systems"}
901
902 MACRO {tods} {"ACM Transactions on Database Systems"}
903
904 MACRO {tog} {"ACM Transactions on Graphics"}
905
906 MACRO {toms} {"ACM Transactions on Mathematical Software"}
907
908 MACRO {toois} {"ACM Transactions on Office Information Systems"}
909
910 MACRO {toplas} {"ACM Transactions on Programming Languages and Systems"}
911
912 MACRO {tcs} {"Theoretical Computer Science"}
913
914 READ
915
916 FUNCTION {sortify}
917 { purify$
918 "l" change.case$
919 }
920
921 INTEGERS { len }
922
923 FUNCTION {chop.word}
924 { 's :=
925 'len :=
926 s #1 len substring$ =
927 { s len #1 + global.max$ substring$ }
928 's
929 if$
930 }
931
932 FUNCTION {sort.format.names}
933 { 's :=
934 #1 'nameptr :=
935 ""
936 s num.names$ 'numnames :=
937 numnames 'namesleft :=
938 { namesleft #0 > }
939 { nameptr #1 >
940 { " " * }
941 'skip$
942 if$
943 s nameptr "{vv{ } }{ll{ }}{ ff{ }}{ jj{ }}" format.name$ 't :=
944 nameptr numnames = t "others" = and
945 { "et al" * }
946 { t sortify * }
947 if$
948 nameptr #1 + 'nameptr :=
949 namesleft #1 - 'namesleft :=
950 }
951 while$
952 }
953
954 FUNCTION {sort.format.title}
955 { 't :=
956 "A " #2
957 "An " #3
958 "The " #4 t chop.word
959 chop.word
960 chop.word
961 sortify
962 #1 global.max$ substring$
963 }
964
965 FUNCTION {author.sort}
966 { author empty$
967 { key empty$
968 { "to sort, need author or key in " cite$ * warning$
969 ""
970 }
971 { key sortify }
972 if$
973 }
974 { author sort.format.names }
975 if$
976 }
977
978 FUNCTION {author.editor.sort}
979 { author empty$
980 { editor empty$
981 { key empty$
982 { "to sort, need author, editor, or key in " cite$ * warning$
983 ""
984 }
985 { key sortify }
986 if$
987 }
988 { editor sort.format.names }
989 if$
990 }
991 { author sort.format.names }
992 if$
993 }
994
995 FUNCTION {author.organization.sort}
996 { author empty$
997 { organization empty$
998 { key empty$
999 { "to sort, need author, organization, or key in " cite$ * warning$
1000 ""
1001 }
1002 { key sortify }
1003 if$
1004 }
1005 { "The " #4 organization chop.word sortify }
1006 if$
1007 }
1008 { author sort.format.names }
1009 if$
1010 }
1011
1012 FUNCTION {editor.organization.sort}
1013 { editor empty$
1014 { organization empty$
1015 { key empty$
1016 { "to sort, need editor, organization, or key in " cite$ * warning$
1017 ""
1018 }
1019 { key sortify }
1020 if$
1021 }
1022 { "The " #4 organization chop.word sortify }
1023 if$
1024 }
1025 { editor sort.format.names }
1026 if$
1027 }
1028
1029 FUNCTION {presort}
1030 { type$ "book" =
1031 type$ "inbook" =
1032 or
1033 'author.editor.sort
1034 { type$ "proceedings" =
1035 'editor.organization.sort
1036 { type$ "manual" =
1037 'author.organization.sort
1038 'author.sort
1039 if$
1040 }
1041 if$
1042 }
1043 if$
1044 " "
1045 *
1046 year field.or.null sortify
1047 *
1048 " "
1049 *
1050 title field.or.null
1051 sort.format.title
1052 *
1053 #1 entry.max$ substring$
1054 'sort.key$ :=
1055 }
1056
1057 ITERATE {presort}
1058
1059 SORT
1060
1061 STRINGS { longest.label }
1062
1063 INTEGERS { number.label longest.label.width }
1064
1065 FUNCTION {initialize.longest.label}
1066 { "" 'longest.label :=
1067 #1 'number.label :=
1068 #0 'longest.label.width :=
1069 }
1070
1071 FUNCTION {longest.label.pass}
1072 { number.label int.to.str$ 'label :=
1073 number.label #1 + 'number.label :=
1074 label width$ longest.label.width >
1075 label width$ longest.label.width = %% added to count the labels
1076 or %% added to count the labels
1077 { label 'longest.label :=
1078 label width$ 'longest.label.width :=
1079 }
1080 'skip$
1081 if$
1082 }
1083
1084 EXECUTE {initialize.longest.label}
1085
1086 ITERATE {longest.label.pass}
1087
1088 FUNCTION {begin.bib}
1089 { preamble$ empty$
1090 'skip$
1091 { preamble$ write$ newline$ }
1092 if$
1093 "\begin{thebibliography}{" longest.label * "}" * write$ newline$
1094 }
1095
1096 EXECUTE {begin.bib}
1097
1098 EXECUTE {init.state.consts}
1099
1100 ITERATE {call.type$}
1101
1102 FUNCTION {end.bib}
1103 { newline$
1104 "\end{thebibliography}" write$ newline$
1105 }
1106
1107 EXECUTE {end.bib}