Debian Codegraph @

texmf-dist/bibtex/bst/dinat/dinat.bst

raw
1 %% DINAT.BST Version 2.5 2000-11-14
2 %% (c) Helge Baumann email:[email protected]
3 %%------------------------------------------------------------------------------
4 %% For use with BibTeX version 0.99a or later.
5 %%------------------------------------------------------------------------------
6 %% Copying of this file is authorized only if either
7 %% (1) you make absolutely no changes to your copy, including name, or
8 %% (2) if you do make changes, you name it something other than dinat.bst,
9 %% natdin.bst, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
10 %% This restriction helps ensure that all standard styles are identical.
11 %%------------------------------------------------------------------------------
12 %% This is a full author-year citation style bibliography. As such, it is
13 %% non-standard LaTeX, and requires the natbib-package by Patrick W. Daly,
14 %% version 7 or higher to function properly.
15 %% It should be used with the following configuration in natbib.cfg:
16 %% \newcommand{\bibstyle@dinat}%
17 %% {\bibpunct{(}{)}{;}{a}{}{,~}%
18 %% \gdef\NAT@biblabelnum##1{\textbf{##1}}}
19 %%------------------------------------------------------------------------------
20 %% The form of the \bibitem entries is
21 %% \bibitem[Jones u. a.(1990)Jones, Baker und Smith]{key}...
22 %% If there are more [Jones u. a. 1990], a single character is added to
23 %% the year like in [Jones u.a.(1990{\natexlab{a}})Jones, Baker und Smith].
24 %% The resulting bibliography entry is
25 %% \textsc{Jones}, \textsc{Baker} und \textsc{Smith} ...
26 %% The \cite command functions as follows:
27 %% \cite{key} ==>> Jones u. a. (1990)
28 %% \cite[chap. 2]{key} ==>> (Jones u. a. 1990, chap. 2)
29 %% \cite[e.g.][]{key} ==>> (e.g. Jones u. a. 1990)
30 %% \cite[e.g.][p. 32]{key} ==>> (e.g. Jones u. a. p. 32)
31 %% \citep{key} ==>> (Jones u. a. 1990)
32 %% \citep*{key} ==>> (Jones, Baker und Smith 1990)
33 %% \citet{key} ==>> Jones u. a. (1990)
34 %% \citet*{key} ==>> Jones, Baker und Smith (1990)
35 %% \citeauthor{key} ==>> Jones u. a.
36 %% \citeauthor*{key} ==>> Jones, Baker und Smith
37 %% \citeyear{key} ==>> 1990
38 %%------------------------------------------------------------------------------
39 %% This bibliography style file is intended for texts in german.
40 %% It draws up bibliographies in accordance with the german DIN 1505,
41 %% part 2 and 3, as discribed in the german text
42 %% http://www.fh-hamburg.de/pers/Lorenzen/tum/litverz.ps
43 %%------------------------------------------------------------------------------
44 %% This style is based on the natdin.bst style.
45 %% The intention for designing a new style for the same result
46 %% were the many bugs and the poor design of the original style.
47 %% So i simplified the programming and add some comments for rework.
48 %% The names of the functions were changed to reflect their functionality:
49 %% out.*: write the top of the stack to the bbl-file
50 %% format.*: format the top of the stack
51 %% push.*: put one item on top of the stack
52 %%------------------------------------------------------------------------------
53 %% There are some non standard fields for most entries:
54 %% isbn: international book number
55 %% issn: internation journal number
56 %% url: for electronic published documents or additional information
57 %% if there is no publisher and address, the url is used instead,
58 %% else it acts like a additional note
59 %% urldate: the date of the access to the url
60 %%------------------------------------------------------------------------------
61 %% Author(s):
62 %% HB: Helge Baumann, [email protected]
63 %%------------------------------------------------------------------------------
64 %% History:
65 %% (only main changes are listed, for others see the webpage)
66 %% 2000-04-10 (HB): Initial release
67 %% 2000-04-18 (HB): Version 1.1:
68 %% corrected some typos and oversights
69 %% minor changes in output
70 %% 2000-04-25 (HB): Version 1.2:
71 %% dinat only: added \natexlab
72 %% using full key/cite for label
73 %% 2000-05-02 (HB): Version 2.0:
74 %% added urldate for date of visit
75 %% added labels in bibliography, so the seperate
76 %% style dinnat.bst is not needed anymore
77 %% 2000-05-09 (HB): Version 2.1:
78 %% removed blanc in bibpunct
79 %% put text ("u.\,a." ...) in functions
80 %% rebuild some push functions
81 %% changed \cite to \citep
82 %% removed push.crossref.editor (not used)
83 %% 2000-07-12 (HB): version 2.2:
84 %% added push.crossref
85 %% changed many crossrefs
86 %% corrected typos
87 %% put \, in curly braces
88 %% 2000-10-03 (HB): version 2.3:
89 %% changed remaining "u.~a."
90 %% added \labelsep behind dinatlabel
91 %% added mastersthesis again, keeping (wrong)
92 %% masterthesis (sorry for that)
93 %% minor changes in proceedings
94 %% 2000-11-05 (HB): version 2.4:
95 %% improved inbook
96 %% removed extra period from proceedings
97 %% added missing colon in misc
98 %% improved name formatting
99 %% removed long dashes from ISBN/ISSN
100 %% restructured format.dashes
101 %% 2000-11-14 (HB): version 2.5:
102 %% always use key for label if present
103 %%------------------------------------------------------------------------------
104
105
106 %%------------------------------------------------------------------------------
107 %% push standard text items on top of the stack
108 %%------------------------------------------------------------------------------
109 FUNCTION {push.bd} { "Bd." }
110 FUNCTION {push.diplom} { "Diplomarbeit" }
111 FUNCTION {push.disser} { "Dissertation" }
112 FUNCTION {push.forschung} { "Forschungsbericht" }
113 FUNCTION {push.hrsg} { "Hrsg." }
114 FUNCTION {push.in} { "In:" }
115 FUNCTION {push.isbn} { "ISBN" }
116 FUNCTION {push.issn} { "ISSN" }
117 FUNCTION {push.kap} { "Kap." }
118 FUNCTION {push.nr} { "Nr." }
119 FUNCTION {push.sn} { "S" }
120 FUNCTION {push.s} { "S." }
121 FUNCTION {push.siehe} { "Siehe" }
122 FUNCTION {push.ua} { "u.\,a." }
123 FUNCTION {push.und} { "und" }
124 FUNCTION {push.url.name} { "URL" }
125 FUNCTION {push.veranst} { "Veranst." }
126 FUNCTION {push.von} { "von" }
127 FUNCTION {push.zugriff} { "Zugriffsdatum" }
128
129 FUNCTION {push.cite} { "\citep" }
130
131
132 %%------------------------------------------------------------------------------
133 %% Definitions for every bibliography entry
134 %%------------------------------------------------------------------------------
135 ENTRY
136 % fields (crossref is default)
137 { address
138 author
139 booktitle
140 chapter
141 edition
142 editor
143 howpublished
144 institution
145 isbn
146 issn
147 journal
148 key
149 month
150 note
151 number
152 organization
153 pages
154 publisher
155 school
156 series
157 title
158 type
159 url
160 urldate
161 volume
162 year
163 }
164 % INTEGERS
165 {}
166 % STRINGS (sort.key$ is default)
167 { label extra.label sort.label short.list dinat.label }
168
169
170 %%------------------------------------------------------------------------------
171 %% required macros for abbr. names of month
172 %%------------------------------------------------------------------------------
173 MACRO {jan} {"Januar"}
174
175 MACRO {feb} {"Februar"}
176
177 MACRO {mar} {"M\^^b{a}rz"}
178
179 MACRO {apr} {"April"}
180
181 MACRO {may} {"Mai"}
182
183 MACRO {jun} {"Juni"}
184
185 MACRO {jul} {"Juli"}
186
187 MACRO {aug} {"August"}
188
189 MACRO {sep} {"September"}
190
191 MACRO {oct} {"Oktober"}
192
193 MACRO {nov} {"November"}
194
195 MACRO {dec} {"Dezember"}
196
197
198 %%------------------------------------------------------------------------------
199 %% macros for common journals
200 %%------------------------------------------------------------------------------
201 MACRO {acmcs} {"ACM Computing Surveys"}
202
203 MACRO {acta} {"Acta Informatica"}
204
205 MACRO {cacm} {"Communications of the ACM"}
206
207 MACRO {ibmjrd} {"IBM Journal of Research and Development"}
208
209 MACRO {ibmsj} {"IBM Systems Journal"}
210
211 MACRO {ieeese} {"IEEE Transactions on Software Engineering"}
212
213 MACRO {ieeetc} {"IEEE Transactions on Computers"}
214
215 MACRO {ieeetcad}
216 {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
217
218 MACRO {ipl} {"Information Processing Letters"}
219
220 MACRO {jacm} {"Journal of the ACM"}
221
222 MACRO {jcss} {"Journal of Computer and System Sciences"}
223
224 MACRO {scp} {"Science of Computer Programming"}
225
226 MACRO {sicomp} {"SIAM Journal on Computing"}
227
228 MACRO {tocs} {"ACM Transactions on Computer Systems"}
229
230 MACRO {tods} {"ACM Transactions on Database Systems"}
231
232 MACRO {tog} {"ACM Transactions on Graphics"}
233
234 MACRO {toms} {"ACM Transactions on Mathematical Software"}
235
236 MACRO {toois} {"ACM Transactions on Office Information Systems"}
237
238 MACRO {toplas} {"ACM Transactions on Programming Languages and Systems"}
239
240 MACRO {tcs} {"Theoretical Computer Science"}
241
242
243 %%------------------------------------------------------------------------------
244 %% for debugging (not used)
245 %%------------------------------------------------------------------------------
246 FUNCTION {show}
247 % show quoted top of stack
248 { duplicate$ ":::: `" swap$ * "'" * top$
249 }
250
251 FUNCTION {show.stack}
252 % show and clear whole stack
253 { "STACK====================================================================="
254 top$
255 stack$
256 "ENDSTACK=================================================================="
257 top$
258 }
259
260
261 %%------------------------------------------------------------------------------
262 %% logical functions
263 %%------------------------------------------------------------------------------
264 FUNCTION {not}
265 { { #0 }
266 { #1 }
267 if$
268 }
269
270 FUNCTION {and}
271 { { skip$ }
272 { pop$ #0 }
273 if$
274 }
275
276 FUNCTION {or}
277 { { pop$ #1 }
278 { skip$ }
279 if$
280 }
281
282
283 %%------------------------------------------------------------------------------
284 %% variables for the recent output state
285 %%------------------------------------------------------------------------------
286 INTEGERS { output.state
287 before.all
288 mid.sentence
289 after.sentence
290 after.block
291 colon.after
292 period.dash }
293
294 FUNCTION {init.state.consts}
295 % initialisation of the state variables
296 { #0 'before.all :=
297 #1 'mid.sentence :=
298 #2 'after.sentence :=
299 #3 'after.block :=
300 #4 'colon.after :=
301 #5 'period.dash :=
302 }
303
304 FUNCTION {set.period.dash}
305 % set ". -- "
306 { output.state before.all =
307 { skip$ }
308 { period.dash 'output.state := }
309 if$
310 }
311
312 FUNCTION {set.period.dash.check}
313 % only if not empty
314 { empty$
315 { skip$ }
316 { set.period.dash }
317 if$
318 }
319
320 FUNCTION {set.colon.after}
321 % set ": "
322 { output.state before.all =
323 { skip$ }
324 { colon.after 'output.state := }
325 if$
326 }
327
328 FUNCTION {new.sentence}
329 % set ". "
330 { output.state before.all =
331 { skip$ }
332 { after.sentence 'output.state := }
333 if$
334 }
335
336 FUNCTION {new.sentence.check}
337 % only if not empty
338 { empty$
339 { skip$ }
340 { new.sentence }
341 if$
342 }
343
344 FUNCTION {part.of.sentence}
345 % set ", "
346 { output.state before.all =
347 { skip$ }
348 { mid.sentence 'output.state := }
349 if$
350 }
351
352
353 %%------------------------------------------------------------------------------
354 %% output lines to bbl. file
355 %%------------------------------------------------------------------------------
356 STRINGS { h s t u v }
357
358 FUNCTION {out.block}
359 % writes the second but last element with seperator
360 { 's :=
361 output.state after.block =
362 { add.period$ write$
363 newline$
364 "\newblock " write$
365 }
366 { output.state before.all =
367 { write$ }
368 { output.state colon.after =
369 { ": " * write$
370 newline$
371 "\newblock " write$
372 }
373 { output.state period.dash =
374 { ". -- " * write$
375 newline$
376 "\newblock " write$
377 }
378 { output.state mid.sentence =
379 { ", " * write$ }
380 { write$
381 newline$
382 "\newblock " write$
383 }
384 if$
385 }
386 if$
387 }
388 if$
389 }
390 if$
391 after.block 'output.state :=
392 }
393 if$
394 s
395 }
396
397 FUNCTION {out}
398 % write only if not empty
399 { duplicate$ empty$
400 { pop$ }
401 { out.block }
402 if$
403 }
404
405 FUNCTION {out.check.required}
406 % write if not empty, else drop warning
407 { 't :=
408 duplicate$ empty$
409 { pop$ "empty " t * " in " * cite$ * warning$ }
410 { out.block }
411 if$
412 }
413
414 FUNCTION {out.check.din}
415 % write if not empty, else drop note
416 { 't :=
417 duplicate$ empty$
418 { pop$ "DIN: empty " t * " in " * cite$ * top$ }
419 { out.block }
420 if$
421 }
422
423
424 %%------------------------------------------------------------------------------
425 %% format entries for full author/editor citations
426 %%------------------------------------------------------------------------------
427 INTEGERS { nameptr namesleft pos len }
428
429 FUNCTION {format.full.names}
430 % format all names
431 { 's :=
432 ""
433 #1 'nameptr :=
434 s num.names$ 'namesleft :=
435 { namesleft #0 > } % while
436 { s nameptr "{vv~}{ll}" format.name$ 't :=
437 nameptr #1 =
438 { % first name
439 t *
440 }
441 { namesleft #1 =
442 { % last name
443 t "others" =
444 { " " * push.ua * }
445 { " " * push.und * " " * t * }
446 if$
447 }
448 { % other names
449 ", " * t *
450 }
451 if$
452 }
453 if$
454 nameptr #1 + 'nameptr :=
455 namesleft #1 - 'namesleft :=
456 }
457 while$ % { namesleft #0 > }
458 }
459
460 FUNCTION {key.full}
461 { key empty$
462 { cite$ }
463 { key }
464 if$
465 }
466
467 FUNCTION {author.key.full}
468 { author empty$
469 { key.full }
470 { author format.full.names }
471 if$
472 }
473
474 FUNCTION {editor.key.full}
475 { editor empty$
476 { key.full }
477 { editor format.full.names }
478 if$
479 }
480
481 FUNCTION {author.editor.key.full}
482 { author empty$
483 { editor.key.full }
484 { author format.full.names }
485 if$
486 }
487
488 FUNCTION {make.full.names}
489 { type$ "book" =
490 type$ "inbook" =
491 or
492 { author.editor.key.full }
493 { type$ "proceedings" =
494 { editor.key.full }
495 { author.key.full }
496 if$
497 }
498 if$
499 }
500
501
502 %%------------------------------------------------------------------------------
503 %% write bibentry to bbl. file
504 %%------------------------------------------------------------------------------
505 FUNCTION {out.bibitem.start}
506 % start of entry
507 { newline$
508 "\bibitem[" label * ")" *
509 make.full.names
510 duplicate$ short.list =
511 { pop$ }
512 { * }
513 if$
514 "]{" * cite$ * "}" *
515 write$
516 newline$
517 "\dinatlabel{" dinat.label * "} " *
518 write$
519 ""
520 before.all 'output.state :=
521 }
522
523 FUNCTION {out.bibitem.end}
524 % end of entry
525 { write$
526 newline$
527 }
528
529
530 %%------------------------------------------------------------------------------
531 %% format text
532 %%------------------------------------------------------------------------------
533 FUNCTION {format.emphasize}
534 % emphasize top of stack
535 { duplicate$ empty$
536 { pop$ "" }
537 { "\emph{" swap$ * "}" * }
538 if$
539 }
540
541 FUNCTION {format.smallcaps}
542 % top of stack in small caps
543 { duplicate$ empty$
544 { pop$ "" }
545 { "\textsc{" swap$ * "}" * }
546 if$
547 }
548
549 FUNCTION {format.dashes}
550 % replace single dashes (-) with tex-styled dashes (--)
551 { 't :=
552 ""
553 { t empty$ not } % while$
554 { t #1 #2 substring$ "--" =
555 { { t #1 #1 substring$ "-" = }
556 { "-" *
557 t #2 global.max$ substring$ 't :=
558 }
559 while$
560 }
561 { t #1 #1 substring$ "-" =
562 { "--" * }
563 { t #1 #1 substring$ * }
564 if$
565 t #2 global.max$ substring$ 't :=
566 }
567 if$
568 }
569 while$ % { t empty$ not }
570 }
571
572
573 %%------------------------------------------------------------------------------
574 %% manipulte entries on the stack
575 %%------------------------------------------------------------------------------
576 FUNCTION {tie.or.space.connect}
577 % connect two top items with space or ~, if second is shorter than 3
578 { duplicate$ text.length$ #3 <
579 { "~" }
580 { " " }
581 if$
582 swap$ * *
583 }
584
585 FUNCTION {push.field.or.null}
586 % push an empty item on the stack if it's a missing entry
587 { duplicate$ empty$
588 { pop$ "" }
589 { skip$ }
590 if$
591 }
592
593
594 %%------------------------------------------------------------------------------
595 %% format text on stack
596 %%------------------------------------------------------------------------------
597 STRINGS { hrsg }
598
599 FUNCTION {format.names}
600 % format all names on top of stack
601 { 's :=
602 ""
603 #1 'nameptr :=
604 s num.names$ 'namesleft :=
605 { namesleft #0 > } % while names left
606 { % first get last name in small caps
607 s nameptr "{ll}" format.name$ 't :=
608 t format.smallcaps 't :=
609 % second get all first names
610 s nameptr "{, ff}" format.name$ 'u :=
611 u text.length$ 'len :=
612 #1 'pos :=
613 "" 'v :=
614 { pos len < } % while
615 { u pos #1 substring$ "~" =
616 { v "" =
617 { u #1 pos #1 - substring$ 'v := }
618 { skip$ }
619 if$
620 % cut second and more first names
621 v u pos #2 substring$ * "." * 'v :=
622 }
623 { skip$ }
624 if$
625 pos #1 + 'pos :=
626 }
627 while$ % { pos len < }
628 v "" =
629 { u 'v := }
630 { skip$ }
631 if$
632 % third get all "von"
633 s nameptr "{ vv}" format.name$ 'u :=
634 % put it all together
635 t v * u * hrsg * 't :=
636
637 nameptr #1 =
638 { %first name
639 t *
640 }
641 { namesleft #1 =
642 { % last name
643 t "others" format.smallcaps =
644 t "others" format.smallcaps hrsg * =
645 or
646 { " " * push.ua * }
647 { "~; " * t * }
648 if$
649 }
650 { % other names
651 "~; " * t *
652 }
653 if$
654 }
655 if$
656 nameptr #1 + 'nameptr :=
657 namesleft #1 - 'namesleft :=
658 }
659 while$ % { namesleft #0 > }
660 "" 'hrsg :=
661 }
662
663
664 %%------------------------------------------------------------------------------
665 %% push formatted or empty field(s) on top of the stack
666 %%------------------------------------------------------------------------------
667 FUNCTION {push.authors}
668 % format author names
669 { author empty$
670 { "" }
671 { author format.names }
672 if$
673 }
674
675 FUNCTION {push.editors}
676 % format editor names
677 { editor empty$
678 { "" }
679 { " (" push.hrsg * ")" * 'hrsg :=
680 editor format.names
681 }
682 if$
683 }
684
685 FUNCTION {push.authors.editors}
686 % format author and/or editor names
687 { author empty$
688 { push.editors }
689 { push.authors
690 editor empty$
691 { skip$ }
692 { "~; " * push.editors * }
693 if$
694 }
695 if$
696 }
697
698
699 FUNCTION {push.organization}
700 % format organization
701 { organization empty$
702 { "" }
703 { organization
704 " (" * push.veranst * ")" *
705 }
706 if$
707 }
708
709 FUNCTION {push.title}
710 % title as in entry
711 { title empty$
712 { "" }
713 { title }
714 if$
715 }
716
717 FUNCTION {push.url}
718 % prefixed with "URL" and special formatting
719 { url empty$
720 { "" }
721 { push.url.name " \url{" * url * "}" *
722 urldate empty$
723 { skip$ }
724 { ". -- " * push.zugriff * ": " * urldate * }
725 if$
726 }
727 if$
728 }
729
730 FUNCTION {push.date}
731 % format: month year
732 { year empty$
733 { month empty$
734 { "" }
735 { "there's a month but no year in " cite$ * warning$
736 month
737 }
738 if$
739 }
740 { month empty$
741 { year }
742 { month " " * year * }
743 if$
744 }
745 if$
746 }
747
748 FUNCTION {push.address.publisher.year}
749 % the whole imprint
750 { address empty$
751 { publisher empty$
752 { url empty$
753 { year empty$
754 { "no publisher, address, url or date in " cite$ * warning$
755 "" }
756 { push.date }
757 if$
758 }
759 { "no proper publisher, using url in " cite$ * warning$
760 push.url
761 year empty$
762 { skip$ }
763 { ", " * push.date * }
764 if$
765 }
766 if$
767 }
768 { publisher
769 year empty$
770 { "there's a publisher but no year in " cite$ * warning$ }
771 { ", " * push.date * }
772 if$
773 }
774 if$
775 }
776 { address
777 publisher empty$
778 { "there's an address but no publisher in " cite$ * warning$ }
779 { "~: " * publisher * }
780 if$
781 year empty$
782 { skip$ }
783 { ", " * push.date * }
784 if$
785 }
786 if$
787 }
788
789 FUNCTION {push.btitle}
790 % the booktitle
791 { title empty$
792 { "" }
793 { title format.emphasize }
794 if$
795 }
796
797 FUNCTION {push.btitle.vol}
798 % booktitle in multivolume works
799 { number empty$
800 { series empty$
801 { push.btitle
802 volume empty$
803 { skip$ }
804 { ". " * push.bd * volume tie.or.space.connect }
805 if$
806 }
807 { volume empty$
808 { push.btitle }
809 { series format.emphasize ". " *
810 push.bd * volume tie.or.space.connect
811 ": " * push.btitle *
812 }
813 if$
814 }
815 if$
816 }
817 { push.btitle }
818 if$
819 }
820
821 FUNCTION {push.article.in.journal}
822 % source of article
823 { journal empty$
824 { "" }
825 { author missing$
826 title missing$
827 and
828 { journal format.emphasize }
829 { push.in " " * journal format.emphasize * }
830 if$
831 }
832 if$
833 }
834
835 FUNCTION {push.series.number}
836 % series and number like DIN
837 { volume empty$
838 { series empty$
839 { number empty$
840 { "" }
841 { "there's a number but no series in " cite$ * warning$
842 "(" number * ")" * }
843 if$
844 }
845 { "(" series *
846 number empty$
847 { skip$ }
848 { number tie.or.space.connect }
849 if$
850 ")" *
851 }
852 if$
853 }
854 { series empty$
855 { "" }
856 { type$ "proceedings" =
857 { "(" series *
858 number empty$
859 { skip$ }
860 { number tie.or.space.connect }
861 if$
862 ")" *
863 }
864 { "" }
865 if$
866 }
867 if$
868 }
869 if$
870 }
871
872 FUNCTION {push.misc.series}
873 % series in MISC
874 { series empty$
875 { "" }
876 { "(" series * ")" * }
877 if$
878 }
879
880 FUNCTION {push.edition}
881 % like in entry
882 { edition empty$
883 { "" }
884 { edition }
885 if$
886 }
887
888 FUNCTION {push.isbn.issn}
889 % preceeded with ISSN/ISBN
890 { isbn empty$
891 { issn empty$
892 { "" }
893 { push.issn " " * issn * }
894 if$
895 }
896 { push.isbn " " * isbn * }
897 if$
898 }
899
900 FUNCTION {push.pages.book}
901 % as length of a book
902 { pages empty$
903 { "" }
904 { pages format.dashes "~" * push.sn * }
905 if$
906 }
907
908 FUNCTION {push.pages}
909 % as part of a book
910 { pages empty$
911 { "" }
912 { push.s "~" * pages format.dashes * }
913 if$
914 }
915
916 FUNCTION {push.vol.year.num.pages}
917 % for journals etc.
918 { volume push.field.or.null
919 year empty$
920 { "there's no year in " cite$ * warning$ }
921 { duplicate$ empty$
922 { pop$ "(" }
923 { " (" * }
924 if$
925 year * ")" *
926 }
927 if$
928 month empty$
929 { skip$ }
930 { duplicate$ empty$
931 { pop$ month }
932 { ", " * month * }
933 if$
934 }
935 if$
936 number empty$
937 { skip$ }
938 { duplicate$ empty$
939 { pop$ push.nr }
940 { ", " * push.nr * }
941 if$
942 "~" * number *
943 }
944 if$
945 pages empty$
946 { skip$ }
947 { duplicate$ empty$
948 { skip$ }
949 { ", " *
950 title missing$
951 { push.pages.book * }
952 { push.pages * }
953 if$
954 }
955 if$
956 }
957 if$
958 }
959
960 FUNCTION {push.chapter.pages}
961 % chapter and pages
962 { chapter empty$
963 { push.pages }
964 { type empty$
965 { push.kap }
966 { type }
967 if$
968 chapter tie.or.space.connect
969 pages empty$
970 { skip$ }
971 { ", " * push.pages * }
972 if$
973 }
974 if$
975 }
976
977 FUNCTION {push.in.ed.booktitle}
978 % main title and volume
979 { booktitle empty$
980 { "" }
981 { push.in " " *
982 editor empty$
983 { skip$ }
984 { push.editors * ": " * }
985 if$
986 booktitle format.emphasize *
987 volume empty$
988 { skip$ }
989 { " " * push.bd * "~" * volume * }
990 if$
991 }
992 if$
993 }
994
995 FUNCTION {push.mastersthesis.type}
996 % type of a mastersthesis
997 { type empty$
998 { push.diplom }
999 { type }
1000 if$
1001 }
1002
1003 FUNCTION {push.phdthesis.type}
1004 % type of a phdthesis
1005 { type empty$
1006 { push.disser }
1007 { type }
1008 if$
1009 }
1010
1011 FUNCTION {push.tr.number}
1012 % type and number of a technical report
1013 { number empty$
1014 { " " }
1015 { "(" number * "). " * }
1016 if$
1017 "-- " *
1018 type empty$
1019 { push.forschung * }
1020 { type * }
1021 if$
1022 }
1023
1024 FUNCTION {push.article.crossref}
1025 % article from a journal
1026 { key empty$
1027 { journal empty$
1028 { "need key or journal for " cite$ * " to crossref " * crossref *
1029 warning$
1030 ""
1031 }
1032 { push.in " " * journal format.emphasize * }
1033 if$
1034 }
1035 { push.in " " * key * }
1036 if$
1037 " " * push.cite * "{" * crossref * "}" *
1038 pages empty$
1039 { skip$ }
1040 { ", " * push.pages * }
1041 if$
1042 }
1043
1044 FUNCTION {push.book.crossref}
1045 % crossreference in BOOKs
1046 { volume empty$
1047 { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
1048 push.siehe
1049 }
1050 { ". -- " push.bd * "~" * volume *
1051 " " * push.von *
1052 }
1053 if$
1054 " " * push.cite * "{" * crossref * "}" *
1055 }
1056
1057 FUNCTION {push.incoll.inproc.crossref}
1058 % crossreference with In:
1059 { editor empty$
1060 editor push.field.or.null author push.field.or.null =
1061 or
1062 { key empty$
1063 { booktitle empty$
1064 { push.siehe }
1065 { push.in " " * booktitle format.emphasize * "." * }
1066 if$
1067 }
1068 { push.in }
1069 if$
1070 }
1071 { push.in }
1072 if$
1073 " " * push.cite * "{" * crossref * "}" *
1074 chapter empty$
1075 { skip$ }
1076 { ", " *
1077 type empty$
1078 { push.kap * }
1079 { type * }
1080 if$
1081 chapter tie.or.space.connect
1082 }
1083 if$
1084 pages empty$
1085 { skip$ }
1086 { ", " * push.pages * }
1087 if$
1088 }
1089
1090 FUNCTION {push.crossref}
1091 % a simple crossref
1092 { crossref empty$
1093 { "" }
1094 { push.siehe " " * push.cite * "{" * crossref * "}" * }
1095 if$
1096 }
1097
1098
1099 %%------------------------------------------------------------------------------
1100 %% functions for the different entries
1101 %%------------------------------------------------------------------------------
1102 FUNCTION {article}
1103 % required: author, title, journal, year
1104 % optional: volume, number, pages, month, note, url, issn
1105 { out.bibitem.start
1106 push.authors "author" out.check.required
1107 set.colon.after
1108 push.title "title" out.check.required
1109 crossref missing$
1110 { push.article.in.journal out.block
1111 new.sentence
1112 push.vol.year.num.pages out
1113 }
1114 { push.article.crossref out.block }
1115 if$
1116 url set.period.dash.check
1117 push.url out
1118 note set.period.dash.check
1119 note out
1120 issn set.period.dash.check
1121 push.isbn.issn out
1122 out.bibitem.end
1123 }
1124
1125 FUNCTION {book}
1126 % required: author/editor, title, publisher, year
1127 % optional: volume oder number, series, address, edition, pages, month,
1128 % note, url, isbn
1129 { out.bibitem.start
1130 author empty$
1131 { push.editors "author and editor" out.check.required }
1132 { push.authors.editors out.block }
1133 if$
1134 set.colon.after
1135 crossref missing$
1136 { push.btitle.vol }
1137 { push.btitle }
1138 if$
1139 "title" out.check.required
1140 push.edition out
1141 push.address.publisher.year "publisher" out.check.required
1142 new.sentence
1143 crossref missing$
1144 { push.series.number out }
1145 { push.book.crossref out.block }
1146 if$
1147 pages set.period.dash.check
1148 push.pages.book out
1149 address empty$
1150 publisher empty$
1151 and
1152 { skip$ }
1153 { url set.period.dash.check
1154 push.url out
1155 }
1156 if$
1157 note set.period.dash.check
1158 note out
1159 isbn set.period.dash.check
1160 push.isbn.issn out
1161 out.bibitem.end
1162 }
1163
1164 % booklet see below
1165
1166 % conference see below
1167
1168 FUNCTION {inbook}
1169 % required: author/editor, title, chapter/pages, publisher, year
1170 % optional: volume oder number, series, type, address, month, note, url, isbn
1171 { out.bibitem.start
1172 author empty$
1173 { push.editors "author and editor" out.check.required }
1174 { push.authors out.block }
1175 if$
1176 set.colon.after
1177 push.btitle.vol "title" out.check.required
1178 push.chapter.pages out
1179 crossref missing$
1180 { push.in.ed.booktitle "booktitle" out.check.required
1181 address empty$
1182 { part.of.sentence
1183 push.address.publisher.year out
1184 }
1185 { push.address.publisher.year "publisher" out.check.required }
1186 if$
1187 new.sentence
1188 series empty$
1189 { skip$ }
1190 { push.series.number out }
1191 if$
1192 part.of.sentence
1193 address empty$
1194 publisher empty$
1195 and
1196 { skip$ }
1197 { url set.period.dash.check
1198 push.url out
1199 }
1200 if$
1201 }
1202 { push.crossref out.block
1203 url set.period.dash.check
1204 push.url out
1205 }
1206 if$
1207 note set.period.dash.check
1208 note out
1209 isbn set.period.dash.check
1210 push.isbn.issn out
1211 out.bibitem.end
1212 }
1213
1214 FUNCTION {incollection}
1215 % required: author, title, booktitle, publisher, year
1216 % optional: editor, volume oder number, series, type, chapter,
1217 % pages, address, edition, month, note, url
1218 { out.bibitem.start
1219 push.authors "author" out.check.required
1220 set.colon.after
1221 push.title "title" out.check.required
1222 crossref missing$
1223 { push.in.ed.booktitle "booktitle" out.check.required
1224 push.edition out
1225 push.address.publisher.year "publisher" out.check.required
1226 new.sentence
1227 push.series.number out
1228 part.of.sentence
1229 push.chapter.pages "pages" out.check.required
1230 address empty$
1231 publisher empty$
1232 and
1233 { skip$ }
1234 { url set.period.dash.check
1235 push.url out
1236 }
1237 if$
1238 }
1239 { push.incoll.inproc.crossref out.block
1240 url set.period.dash.check
1241 push.url out
1242 }
1243 if$
1244 note set.period.dash.check
1245 note out
1246 isbn set.period.dash.check
1247 issn set.period.dash.check
1248 push.isbn.issn out
1249 out.bibitem.end
1250 }
1251
1252 FUNCTION {inproceedings}
1253 % required: author, title, booktitle, year
1254 % optional: editor, volume oder number, series, pages, address, month,
1255 % organization, publisher, note, url
1256 { out.bibitem.start
1257 push.authors "author" out.check.required
1258 set.colon.after
1259 push.title "title" out.check.required
1260 crossref missing$
1261 { push.in.ed.booktitle "booktitle" out.check.required
1262 address empty$
1263 { organization new.sentence.check
1264 push.organization out
1265 part.of.sentence
1266 push.address.publisher.year out
1267 }
1268 { push.address.publisher.year "publisher" out.check.required }
1269 if$
1270 new.sentence
1271 series empty$
1272 { skip$ }
1273 { push.series.number out }
1274 if$
1275 part.of.sentence
1276 push.pages "pages" out.check.required
1277 address empty$
1278 publisher empty$
1279 and
1280 { skip$ }
1281 { url set.period.dash.check
1282 push.url out
1283 }
1284 if$
1285 }
1286 { push.incoll.inproc.crossref out.block
1287 url set.period.dash.check
1288 push.url out
1289 }
1290 if$
1291 note set.period.dash.check
1292 note out
1293 isbn set.period.dash.check
1294 issn set.period.dash.check
1295 push.isbn.issn out
1296 out.bibitem.end
1297 }
1298
1299 FUNCTION {manual}
1300 % required: title
1301 % optional: author, organization, address, edition, month, year, note, url
1302 { out.bibitem.start
1303 author empty$
1304 { organization empty$
1305 { title empty$
1306 { skip$ }
1307 { push.btitle "title" out.check.required }
1308 if$
1309 }
1310 { push.organization out.block
1311 set.colon.after
1312 push.btitle "title" out.check.required
1313 }
1314 if$
1315 }
1316 { push.authors out.block
1317 set.colon.after
1318 push.btitle "title" out.check.required
1319 }
1320 if$
1321 push.edition "edition" out.check.required
1322 author empty$
1323 { organization empty$
1324 { address out
1325 part.of.sentence
1326 }
1327 { skip$ }
1328 if$
1329 }
1330 { address ": " * push.organization * out
1331 part.of.sentence
1332 }
1333 if$
1334 push.date out
1335 pages set.period.dash.check
1336 push.pages.book out
1337 url set.period.dash.check
1338 push.url out
1339 note set.period.dash.check
1340 note out
1341 out.bibitem.end
1342 }
1343
1344 FUNCTION {mastersthesis}
1345 % required: author, title, school, year
1346 % optional: type, address, month, note, url
1347 { out.bibitem.start
1348 push.authors "author" out.check.required
1349 set.colon.after
1350 push.btitle "title" out.check.required
1351 address out
1352 part.of.sentence
1353 school "school" out.check.required
1354 part.of.sentence
1355 push.mastersthesis.type out.block
1356 part.of.sentence
1357 push.date "year" out.check.required
1358 pages set.period.dash.check
1359 push.pages.book out
1360 url set.period.dash.check
1361 push.url out
1362 note set.period.dash.check
1363 note out
1364 out.bibitem.end
1365 }
1366
1367 FUNCTION {misc}
1368 % required:
1369 % optional: author, title, howpublished, month, year, note, url
1370 { out.bibitem.start
1371 note empty$
1372 { title empty$
1373 { skip$ }
1374 { push.authors.editors out.block
1375 set.colon.after
1376 push.btitle out
1377 howpublished out
1378 push.date out
1379 push.crossref out
1380 url set.period.dash.check
1381 push.url out
1382 }
1383 if$
1384 }
1385 { note #1 #4 substring$ "u" change.case$ "NORM" =
1386 { note out
1387 part.of.sentence
1388 push.date out
1389 push.title format.emphasize out
1390 push.crossref out
1391 }
1392 { author empty$
1393 { editor empty$
1394 { organization empty$
1395 { skip$ }
1396 { push.organization out.block
1397 set.colon.after
1398 }
1399 if$
1400 }
1401 { push.editors push.organization * out.block
1402 set.colon.after
1403 }
1404 if$
1405 }
1406 { push.authors.editors out.block
1407 set.colon.after
1408 }
1409 if$
1410 push.btitle out
1411 push.crossref out
1412 howpublished out
1413 push.date out
1414 new.sentence
1415 push.misc.series out
1416 url set.period.dash.check
1417 push.url out
1418 note set.period.dash.check
1419 note out
1420 }
1421 if$
1422 }
1423 if$
1424 out.bibitem.end
1425 }
1426
1427 FUNCTION {phdthesis}
1428 % required: author, title, school, year
1429 % optional: type, address, month, note, url
1430 { out.bibitem.start
1431 push.authors "author" out.check.required
1432 set.colon.after
1433 push.btitle "title" out.check.required
1434 address out
1435 part.of.sentence
1436 school "school" out.check.required
1437 part.of.sentence
1438 push.phdthesis.type out.block
1439 part.of.sentence
1440 push.date "year" out.check.required
1441 pages set.period.dash.check
1442 push.pages.book out
1443 url set.period.dash.check
1444 push.url out
1445 note set.period.dash.check
1446 note out
1447 out.bibitem.end
1448 }
1449
1450 FUNCTION {proceedings}
1451 % required: title, year
1452 % optional: editor, volume oder number, series, address, month,
1453 % organization, publisher, note, url
1454 { out.bibitem.start
1455 editor empty$
1456 { push.organization }
1457 { push.editors
1458 organization empty$
1459 { skip$ }
1460 { "~; " * push.organization * }
1461 if$
1462 }
1463 if$
1464 out.block
1465 set.colon.after
1466 push.btitle "title" out.check.required
1467 volume empty$
1468 { skip$ }
1469 { push.bd "~" * volume format.emphasize * out.block }
1470 if$
1471 push.address.publisher.year "publisher" out.check.required
1472 push.series.number out
1473 pages set.period.dash.check
1474 push.pages.book out
1475 address empty$
1476 publisher empty$
1477 and
1478 { skip$ }
1479 { url set.period.dash.check
1480 push.url out
1481 }
1482 if$
1483 note set.period.dash.check
1484 note out
1485 isbn set.period.dash.check
1486 issn set.period.dash.check
1487 push.isbn.issn out
1488 out.bibitem.end
1489 }
1490
1491 FUNCTION {techreport}
1492 % required: author, title, institution, year
1493 % optional: type, number, address, month, note, url
1494 { out.bibitem.start
1495 author empty$
1496 { push.editors "author and editor" out.check.required }
1497 { push.authors.editors out.block }
1498 if$
1499 set.colon.after
1500 push.title "title" out.check.required
1501 institution empty$
1502 { skip$ }
1503 { institution new.sentence.check
1504 "/ " institution * out.block
1505 }
1506 if$
1507 push.address.publisher.year out
1508 number new.sentence.check
1509 push.tr.number "number" out.check.required
1510 pages set.period.dash.check
1511 push.pages.book out
1512 address empty$
1513 publisher empty$
1514 and
1515 { skip$ }
1516 { url set.period.dash.check
1517 push.url out
1518 }
1519 if$
1520 note "note" out.check.required
1521 isbn set.period.dash.check
1522 issn set.period.dash.check
1523 push.isbn.issn out
1524 out.bibitem.end
1525 }
1526
1527 FUNCTION {booklet}
1528 % required: title
1529 % optional: author, howpublished, address, month, year, note, url
1530 { misc % so far
1531 }
1532
1533 FUNCTION {conference}
1534 % required: author, title, note
1535 % optional: month, year, url
1536 { inproceedings % like stated in BibTeXing by O. Patashnik
1537 }
1538
1539 FUNCTION {masterthesis}
1540 % required: author, title, school, year
1541 % optional: type, address, month, note, url
1542 { mastersthesis % just because of a typo in former version
1543 }
1544
1545 FUNCTION {unpublished}
1546 % required: author, title, note
1547 % optional: month, year, url
1548 { misc % so far
1549 }
1550
1551 FUNCTION {default.type}
1552 % all other types
1553 { misc
1554 }
1555
1556
1557 %%------------------------------------------------------------------------------
1558 %% for producing the labels
1559 %%------------------------------------------------------------------------------
1560 FUNCTION {sortify}
1561 % simplify for sorting
1562 { purify$
1563 "l" change.case$
1564 }
1565
1566 FUNCTION {chop.word}
1567 % cut a word
1568 { 's :=
1569 'len :=
1570 s #1 len substring$ =
1571 { s len #1 + global.max$ substring$ }
1572 { s }
1573 if$
1574 }
1575
1576 FUNCTION {chop.article}
1577 % cut article from a word
1578 { 't :=
1579 "A " #2
1580 "An " #3
1581 "Der " #4
1582 "Die " #4
1583 "Das " #4
1584 "Ein " #4
1585 "Eine " #5
1586 "The " #4 t chop.word
1587 chop.word
1588 chop.word
1589 chop.word
1590 chop.word
1591 chop.word
1592 chop.word
1593 chop.word
1594 }
1595
1596
1597 FUNCTION {format.lab.names}
1598 % format names for the label
1599 { 's :=
1600 s #1 "{vv~}{ll}" format.name$
1601 s num.names$ duplicate$
1602 #2 >
1603 { pop$ " " * push.ua * }
1604 { #2 <
1605 { skip$ }
1606 { s #2 "{ll}" format.name$ "others" =
1607 { " " * push.ua * }
1608 { " " * push.und * " " * s #2 "{vv~}{ll}" format.name$ * }
1609 if$
1610 }
1611 if$
1612 }
1613 if$
1614 }
1615
1616 FUNCTION {author.label}
1617 % label from key or author
1618 { key empty$
1619 { author empty$
1620 { cite$ }
1621 { author format.lab.names }
1622 if$
1623 }
1624 { key }
1625 if$
1626 }
1627
1628 FUNCTION {author.editor.label}
1629 % label from key, author or editor
1630 { key empty$
1631 { author empty$
1632 { editor empty$
1633 { cite$ }
1634 { editor format.lab.names }
1635 if$
1636 }
1637 { author format.lab.names }
1638 if$
1639 }
1640 { key }
1641 if$
1642 }
1643
1644 FUNCTION {author.organization.label}
1645 % label from key, author or organization
1646 { key empty$
1647 { author empty$
1648 { organization empty$
1649 { cite$ }
1650 { organization chop.article }
1651 if$
1652 }
1653 { author format.lab.names }
1654 if$
1655 }
1656 { key }
1657 if$
1658 }
1659
1660 FUNCTION {editor.organization.label}
1661 % label from key, editor or organization
1662 { key empty$
1663 { editor empty$
1664 { organization empty$
1665 { cite$ }
1666 { organization chop.article }
1667 if$
1668 }
1669 { editor format.lab.names }
1670 if$
1671 }
1672 { key }
1673 if$
1674 }
1675
1676 FUNCTION {calc.short.authors}
1677 % make short label (only first author)
1678 { type$ "book" =
1679 type$ "inbook" =
1680 or
1681 { author.editor.label }
1682 { type$ "proceedings" =
1683 { editor.organization.label }
1684 { type$ "manual" =
1685 { author.organization.label }
1686 { author.label }
1687 if$
1688 }
1689 if$
1690 }
1691 if$
1692 'short.list :=
1693 }
1694
1695 FUNCTION {calc.label}
1696 % make a full label
1697 { calc.short.authors
1698 short.list "(" *
1699 year push.field.or.null format.dashes * 'label :=
1700 short.list " " *
1701 year push.field.or.null format.dashes * 'dinat.label :=
1702 label sortify 'sort.label :=
1703 }
1704
1705
1706 %%------------------------------------------------------------------------------
1707 %% sorting
1708 %%------------------------------------------------------------------------------
1709 FUNCTION {sort.format.names}
1710 % format names for sorting
1711 { 's :=
1712 #1 'nameptr :=
1713 ""
1714 s num.names$ 'namesleft :=
1715 { namesleft #0 > } % while
1716 { nameptr #1 =
1717 { skip$ }
1718 { " " * }
1719 if$
1720 s nameptr "{ll{ }}{ ff{ }}{ vv{ }}{ jj{ }}" format.name$ 't :=
1721 namesleft #1 =
1722 t "others" =
1723 and
1724 { "[" * push.ua * "]" * }
1725 { t sortify * }
1726 if$
1727 nameptr #1 + 'nameptr :=
1728 namesleft #1 - 'namesleft :=
1729 }
1730 while$ % { namesleft #0 > }
1731 }
1732
1733 FUNCTION {sort.format.title}
1734 % format title for sorting (without article)
1735 { chop.article
1736 sortify
1737 #1 global.max$ substring$
1738 }
1739
1740 FUNCTION {author.sort}
1741 % author or key for sorting
1742 { key empty$
1743 { author empty$
1744 { "to sort, need author or key in " cite$ * warning$
1745 ""
1746 }
1747 { author sort.format.names }
1748 if$
1749 }
1750 { key sortify }
1751 if$
1752 }
1753
1754 FUNCTION {author.editor.sort}
1755 % author, editor or key for sorting
1756 { key empty$
1757 { author empty$
1758 { editor empty$
1759 { "to sort, need author, editor, or key in " cite$ * warning$
1760 ""
1761 }
1762 { editor sort.format.names }
1763 if$
1764 }
1765 { author sort.format.names }
1766 if$
1767 }
1768 { key sortify }
1769 if$
1770 }
1771
1772 FUNCTION {author.organization.sort}
1773 % author, organization or key for sorting
1774 { key empty$
1775 { author empty$
1776 { organization empty$
1777 { "to sort, need author, organization, or key in " cite$ * warning$
1778 ""
1779 }
1780 { organization chop.article sortify }
1781 if$
1782 }
1783 { author sort.format.names }
1784 if$
1785 }
1786 { key sortify }
1787 if$
1788 }
1789
1790 FUNCTION {editor.organization.sort}
1791 % editor, organization or key for sorting
1792 { key empty$
1793 { editor empty$
1794 { organization empty$
1795 { "to sort, need editor, organization, or key in " cite$ * warning$
1796 ""
1797 }
1798 { organization chop.article sortify }
1799 if$
1800 }
1801 { editor sort.format.names }
1802 if$
1803 }
1804 { key sortify }
1805 if$
1806 }
1807
1808 FUNCTION {presort}
1809 % first sort
1810 { calc.label
1811 sort.label
1812 " " *
1813 type$ "book" =
1814 type$ "inbook" =
1815 or
1816 { author.editor.sort }
1817 { type$ "proceedings" =
1818 { editor.organization.sort }
1819 { type$ "manual" =
1820 { author.organization.sort }
1821 { author.sort }
1822 if$
1823 }
1824 if$
1825 }
1826 if$
1827 " " *
1828 year push.field.or.null sortify *
1829 " " *
1830 title push.field.or.null sort.format.title *
1831 #1 entry.max$ substring$
1832 'sort.label :=
1833 sort.label *
1834 #1 entry.max$ substring$
1835 'sort.key$ :=
1836 }
1837
1838 STRINGS { last.label next.extra }
1839
1840 INTEGERS { last.extra.num label.count }
1841
1842 FUNCTION {initialize.label}
1843 { "" 'last.label :=
1844 #0 'label.count :=
1845 }
1846
1847 FUNCTION {forward.pass}
1848 % find maximum additional character for identical labels
1849 { last.label label =
1850 { last.extra.num #1 + 'last.extra.num :=
1851 last.extra.num int.to.chr$ 'extra.label :=
1852 }
1853 { "a" chr.to.int$ 'last.extra.num :=
1854 "" 'extra.label :=
1855 label 'last.label :=
1856 }
1857 if$
1858 label.count #1 + 'label.count :=
1859 }
1860
1861 FUNCTION {reverse.pass}
1862 % add additional characters to identical labels
1863 { next.extra "b" =
1864 { "a" 'extra.label := }
1865 { skip$ }
1866 if$
1867 extra.label 'next.extra :=
1868 extra.label empty$
1869 { "" }
1870 { "{\natexlab{" extra.label * "}}" * }
1871 if$
1872 'extra.label :=
1873 label extra.label * 'label :=
1874 dinat.label extra.label * 'dinat.label :=
1875 }
1876
1877 FUNCTION {bib.sort.order}
1878 { sort.label 'sort.key$ :=
1879 }
1880
1881
1882 %%------------------------------------------------------------------------------
1883 %% making the bbl. file
1884 %%------------------------------------------------------------------------------
1885 FUNCTION {begin.bib}
1886 % beginning of the file
1887 { preamble$ empty$
1888 { skip$ }
1889 { preamble$
1890 write$
1891 newline$
1892 }
1893 if$
1894 "\begin{thebibliography}{" label.count int.to.str$ * "}" *
1895 write$
1896 newline$
1897 "% this bibliography was produced with the style dinat.bst v2.5"
1898 write$
1899 newline$
1900 "\makeatletter"
1901 write$
1902 newline$
1903 "\newcommand{\dinatlabel}[1]%"
1904 write$
1905 newline$
1906 "{\ifNAT@numbers\else\NAT@biblabelnum{#1}\hspace{2\labelsep}\fi}"
1907 write$
1908 newline$
1909 "\makeatother"
1910 write$
1911 newline$
1912 "\expandafter\ifx\csname natexlab\endcsname\relax\def\natexlab#1{#1}\fi"
1913 write$
1914 newline$
1915 "\expandafter\ifx\csname url\endcsname\relax\def\url#1{\texttt{#1}}\fi"
1916 write$
1917 newline$
1918 }
1919
1920 FUNCTION {end.bib}
1921 % end of the bbl. file
1922 { newline$
1923 "\end{thebibliography}" write$ newline$
1924 }
1925
1926
1927 %%------------------------------------------------------------------------------
1928 %% processing the .bib file
1929 %%------------------------------------------------------------------------------
1930 READ
1931
1932 ITERATE {presort}
1933
1934 SORT
1935
1936 EXECUTE {initialize.label}
1937
1938 ITERATE {forward.pass}
1939
1940 REVERSE {reverse.pass}
1941
1942 ITERATE {bib.sort.order}
1943
1944 SORT
1945
1946 EXECUTE {begin.bib}
1947
1948 EXECUTE {init.state.consts}
1949
1950 ITERATE {call.type$}
1951
1952 EXECUTE {end.bib}