Debian Codegraph @

texmf-dist/bibtex/bst/din1505/alphadin.bst

raw
1 %% ALPHADIN.BST Ausgabe [8.2] 2006-01-02
2 %%
3 %% ersetzt ABBRVDIN.BST Ausgabe [8.1b4] 15/12/2004
4 %% wichtigste Aenderung gegenueber Version [8.1b4]:
5 %% die Standardergaenzung "Online-Ressource" bei Internetquellen
6 %% ist ersatzlos gestrichen worden (wegen ueberfluessiger Redundanz).
7 %%
8 %
9 %% K.F.Lorenzen (Copyright 1994-2006) email: [email protected]
10 %% ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
11 %% ALPHADIN.BST wurde entwickelt aus Oren Patashnik's BibTeX standard
12 %% bibliography style `alpha'. Eine vorgegebene Literaturdatenbank laesst sich
13 %% somit beliebig nach Us- oder deutscher DIN 1505-Zitierkonvention
14 %% verarbeiten.
15 %% Analog zu den 4 US standard styles werden 4 DIN-gerechte bst-style Dateien
16 %% veroeffentlicht (alphadin.bst, plaindin.bst, unsrtdin.bst, abbrvdin.bst).
17 %% Die gueltige Version ist am schnellsten aus dem WWW ueber folgende URL zu
18 %% beziehen:
19 %% http://www.haw-hamburg.de/pers/Lorenzen/bibtex/
20 %% Stand: 2006-01-02
21 %% ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
22 %% WAS IST ALPHADIN.BST ?
23 %% Dieser style produziert "deutsche" Literaturzitate in Literaturverzeichnis-
24 %% sen gemaess der deutschen Norm DIN 1505, Teil 2 vom Jan. 1984.
25 %% Die Literaturzitate werden alphabetisch nach Verfassern sortiert.
26 %% Die Zitiermarken im Text und die Ordnungsmarken im Literaturverzeichnis
27 %% bestehen aus abgekuerzten Verfasserbuchstaben plus Erscheinungsjahr in
28 %% eckigen Klammern. Die vorliegenden DIN-styles gehen ueber einige bibliogra-
29 %% phischen Beschraenkungen der Originalstyles hinaus.
30 %
31 %% Es werden nun auch Elektronische Online / Offline Ressourcen wie Internet-
32 %% quellen, CD-ROM usw. verarbeitet. Dazu kommen besondere Publikationsformen
33 %% wie Patente, Normen, Karten, Fernsehaufzeichnungen, Gesetzesstellen, Spiele.
34 %
35 %% Zur Gewaehrleistung der Allgemeingueltigkeit von bib-files gelten in den
36 %% DIN-styles die in der Tex-Literatur veroeffentlichten originalen
37 %% Definitionen und Regeln fuer die Publikationstypen (entry-types) und die
38 %% bibliographischen Felder (fields).
39 %% Treten kleinere "Schoenheitsfehler" im fertig gesetzten output auf,
40 %% lassen sich diese so gut wie immer durch eine veraenderte
41 %% Erfassung im bib-inputfile beseitigen. Oren Patashnik empfiehlt, die
42 %% Definition der Felder weit auszulegen. Last but not least koennen
43 %% Sie im output-file < *.bbl > noch letzte Hand zur Korrektur ansetzen.
44 %
45 %% WARN- UND FEHLERMELDUNGEN
46 %% Ursache von Warnmeldungen sind meistens ausgelassene Felder oder
47 %% Erfassungs-"Fehler". Letztere haengen teilweise mit den gegenueber US-
48 %% Gepflogenheiten andersartigen bibliographischen Regeln nach DIN 1505
49 %% zusammen. Sie sind also in Wahrheit keine "Fehler" und duerfen fast immer
50 %% ignoriert werden. Dennoch pruefen Sie diese Warnungen, um herauszufinden,
51 %% ob Publikationstyp (=entry-type) und "fields" eventuell unzulaessig
52 %% kombiniert worden sind.
53 %% Echte Fehler ("errors") treten nur noch in Verbindung mit falscher
54 %% Erfassung auf (nach meinen Tests!). Pruefen Sie die Syntax, den entry-type
55 %% und die fields.
56 %% Zu guter letzt: Qualitaetsmasstab ist einzig der DIN-konforme output!
57 %%
58 %% DANKSAGUNG
59 %% Hartmut Lueddecke, HAW Hamburg, hat viele Verbesserungsvorschlaege
60 %% in die frueheren Versionen eingebracht. Ihm danke ich herzlich.
61 %% Patrick W. Daly, dem Entwickler des Natbib-Stils, verdanke ich viele
62 %% Anregungen und den steten Ansporn, die DIN-Stile zu verbessern.
63 %% Viele an dieser Stelle ungenannt bleibende Anwender haben mich in
64 %% den vergangenen Jahren auf Fehler oder Verbesserungsmoeglichkeiten
65 %% aufmerksam gemacht und so diesen Stil mitentwickelt. Ihnen gilt mein
66 %% besonderer Dank. Ihr Feedback ist immer willkommen und eine Ermunterung.
67 %%
68 %% Klaus F. Lorenzen
69 %%
70 %%
71 %%
72 %% HINWEIS: Neben den vier bibliographischen DIN 1505 Standard-Stilen
73 %% nach den Original-styles von Oren Patashnik
74 %% gibt es noch vier DIN 1505 Adaptionen der NATBIB-style
75 %% Emulationen von Patrick W.Daly. Die Fuelle der darin
76 %% implementierten Zitierweisen geht weit ueber die urspruenglichen
77 %% Standardstyles hinaus.
78 %% Naeheres unter URL http://www.haw-hamburg.de/pers/Lorenzen/bibtex/
79 %%
80 %%~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
81 %% version 0.99c for BibTeX versions 0.99c or later, LaTeX2e version
82 %% Copyright (C) 1985, all rights reserved.
83 %% Copying of this file is authorized only if either
84 %% (1) you make absolutely no changes to your copy, including name, or
85 %% (2) if you do make changes, you name it something other than
86 %% alphadin.bst
87 %% This restriction helps ensure that all standard styles are identical.
88 %%
89 %%
90 %%
91 %%~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
92 %% NEUE FELDER
93 %% Zur Erfassung der neuen digitalen Online-Medien z.B. Internetquellen, E-journals, E-books,
94 %% E-mail u.a. gibt es die zusaetzlichen Felder: doi, url, urn, lastchecked
95 %% Internetquellen werden vorzugsweise mit dem BOOKLET-Typ erfasst.
96 %% Normen, Patente, Schutzrechte sind mit dem MISC-Typ zu erfassen.
97
98 ENTRY
99 { address %% Verlagsort (immer!)
100 author %% persoenlicher Urheber eines Werkes oder am Zustandekommen
101 %% beteiligte Personen(=Mitarbeiter, Uebersetzer, Redakteur u.a.)
102 booktitle %% a) Gesamttitel eines mehrbaendigen Werkes
103 % %% b) Titel des Sammelwerks, das einzelne selbstaendige
104 % %% Beitraege mit eigenem Titel enthaelt ->incollection
105 chapter %% Kapitel in einem Buch (Monographie)
106 doi %%% Digital Object Identifier ->article
107 edition %% a) Auflagevermerk
108 % %% b) bei selbst. elektron. Quellen == Version ->booklet
109 editor %% Persoenl.Herausgeber oder Koerperschaftlicher Herausgeber
110 howpublished %% beliebiger Verlegervermerk: veroeffentlicht "von wem, wo"
111 institution %% Institution, die e.verlagsfreie Veroeffentlichung betreibt
112 isbn %% Standardnr fuer Buecher
113 issn %% - " - : Zeitschriften u. Serien
114 journal %% Titel einer Zeitschrift
115 key %% Zusaetzlich vergebener Sortierschluessel, mitunter notwend.
116 lastchecked %% neues Feld fuer das Datum des Online-Abrufs
117 % %% einer Internetquelle (n. GRAY )
118 month %% naehere Bestimmung des Erscheinungsjahres -> macro 's
119 note %% freies Eingabefeld fuer zusaetzliche Informationen z. Quelle
120 number %% Versch. Bedeutungen in Abhaengigkeit vom Eingabetyp:
121 % %% a) Bandnummer einer gezaehlten Reihe (series)
122 % %% b) Heftnummer einer Zeitschrift ->article
123 % %% c) Nummer eines Forschungsberichts ->techreport
124 organization %% a) Name der Organisation/des Organisators e. Tagung,Konferenz
125 % %% b) Name einer Firma/Gesellschaft, die ein ->manual herausgab
126 pages %% Umfangsangaben, meist Seitenzahlen
127 publisher %% Verlag
128 school %% Hochschule/Universitaet, die eine Dipl.-Arb./Dissertation veroeff.
129 series %% Titel e.Reihe, in der ein best. Buchtitel erschienen ist
130 title %% Titel einer (namentlich gekennzeichneten) Veroeffentlichung
131 type %% Zusatzfeld z.Kennzeichnung e.besonderen Publikationstyps
132 url %% neues Feld URL ( Uniform Resource Locator ):
133 % %% Serveradresse einer Internetquelle
134 urn %% neues Feld URN ( Uniform Resource Name ):
135 % %% Persistent Identifier einer Internetquelle
136 volume %% a) Zaehlung bei einem mehrbaendigen Werk ->book/->proceedings
137 % %% b) Jahrgang einer Zeitschrift ->article
138 year %% Erscheinungsjahr
139 }
140 {}
141 { label extra.label sort.label short.list }
142
143 %%%----------------------------------------------------------------------------
144 % Einige Standardvorgaben, die vom Benutzer veraendert werden koennen.
145 %%%----------------------------------------------------------------------------
146
147 % Abkuerzung ("... und andere") bei Mehrverfasserquellen:
148
149 FUNCTION { ua.etal } { " u.\,a." } %% evtl. auch in eckigen Klammern " [u.\,a.]"
150
151 %% oder lateinisch: FUNCTION { ua.etal } { " et~al." }
152
153 FUNCTION { und } { " u. " }
154
155 %% oder ausgeschrieben: FUNCTION { und } { " und " }
156 %
157 % Einige elektronische Medien erhalten nach DIN 1505 eine "Ergaenzende Angabe"
158 % zusaetzlich zum materiellen Typ, z.B. CD ROM oder DVD u.a.:
159
160 FUNCTION { eress } { "Elektronische Ressource" }
161
162 %%%-----------------------------------------------------------------------------------
163
164 INTEGERS { output.state before.all mid.sentence after.sentence after.block }
165
166 INTEGERS { colon.after period.dash }
167
168 INTEGERS { after.firstblock }
169
170 INTEGERS { zahl lang }
171
172 INTEGERS { nameptr namesleft numnames }
173
174 INTEGERS { ptr collation collrest }
175
176 INTEGERS { len }
177
178 INTEGERS { et.al.char.used }
179
180 INTEGERS { longest.label.width last.extra.num }
181 %-------------------------
182 STRINGS { longest.label last.sort.label next.extra }
183
184 STRINGS { h s t u v w }
185
186 STRINGS { fkt }
187 %-------------------------
188
189 FUNCTION {init.state.consts}
190 { #0 'before.all :=
191 #1 'mid.sentence :=
192 #2 'after.sentence :=
193 #3 'after.block :=
194 #4 'colon.after :=
195 #5 'period.dash :=
196 #6 'after.firstblock :=
197 }
198
199 FUNCTION {output.nonnull}
200 { 's :=
201 output.state after.block =
202 { add.period$ write$
203 newline$
204 "\newblock " write$
205 }
206 { output.state before.all =
207 { write$ }
208 { output.state colon.after =
209 { ": " * write$
210 newline$
211 "\newblock " write$
212 }
213 { output.state period.dash =
214 { ". -- " * write$
215 newline$
216 "\newblock " write$
217 }
218 { output.state mid.sentence =
219 { ", " * write$ }
220 { output.state after.sentence =
221 { " " * write$ }
222 { output.state after.firstblock =
223 { add.period$ write$
224 newline$
225 "\newblock " write$
226 }
227 { write$
228 newline$
229 "\newblock " write$
230 }
231 if$
232 }
233 if$
234 }
235 if$
236 }
237 if$
238 }
239 if$
240 }
241 if$
242 after.block 'output.state :=
243 }
244 if$
245 s
246 }
247
248 FUNCTION {output}
249 { duplicate$ empty$
250 'pop$
251 'output.nonnull
252 if$
253 }
254
255 FUNCTION {output.check}
256 { 't :=
257 duplicate$ empty$
258 { pop$ "empty " t * " in " * cite$ * warning$ }
259 'output.nonnull
260 if$
261 }
262
263 FUNCTION {new.block}
264 { output.state before.all =
265 'skip$
266 { after.block 'output.state := }
267 if$
268 }
269
270 FUNCTION {not}
271 { { #0 }
272 { #1 }
273 if$
274 }
275
276 FUNCTION {and}
277 { 'skip$
278 { pop$ #0 }
279 if$
280 }
281
282 FUNCTION {or}
283 { { pop$ #1 }
284 'skip$
285 if$
286 }
287
288
289 FUNCTION {output.bibitem}
290 { newline$
291 "\bibitem[" write$
292 label write$%
293 "]{" write$
294 cite$ write$
295 "}" write$
296 newline$
297 ""
298 before.all 'output.state :=
299 }
300
301 FUNCTION {fin.entry}
302 { write$
303 newline$
304 }
305
306 FUNCTION {set.period.dash} %% Wenn ein ". - " die Satzteile trennen soll.!
307 { output.state before.all =
308 'skip$
309 { period.dash 'output.state := }
310 if$
311 }
312
313 FUNCTION {set.period.dash.check}
314 { empty$
315 'skip$
316 'set.period.dash
317 if$
318 }
319
320 FUNCTION {set.colon.after} %%$$$ Wenn ein ": " d. Satzteile trennen soll!
321 { output.state before.all =
322 'skip$
323 { colon.after 'output.state := }
324 if$
325 }
326
327 %% Wenn ein " " die Satzteile trennen soll.!
328 FUNCTION {new.sentence}
329 { output.state before.all =
330 'skip$
331 { after.sentence 'output.state := }
332 if$
333 }
334
335 %% Wenn ein ", " die Satzteile trennen soll.!
336 FUNCTION { part.of.sentence }
337 { output.state before.all =
338 'skip$
339 { mid.sentence 'output.state := }
340 if$
341 }
342
343 FUNCTION {new.sentence.checka}
344 { empty$
345 'skip$
346 'new.sentence
347 if$
348 }
349
350 FUNCTION {field.or.null}
351 { duplicate$ empty$
352 { pop$ "" }
353 'skip$
354 if$
355 }
356
357 FUNCTION {emphasize}
358 { duplicate$ empty$
359 { pop$ "" }
360 { "\emph{" swap$ * "}" * }
361 if$
362 }
363
364 FUNCTION { capitalize }
365 { duplicate$ empty$
366 { pop$ "" }
367 { "\textsc{" swap$ * "}" * }
368 if$
369 }
370
371
372 %% Adelspraedikate beim Sortieren nach den(m) Vornamen auffuehren
373 %% Abweichend v. DIN !!!
374 FUNCTION {format.names}
375 { 's :=
376 "" 'u :=
377 #1 'nameptr :=
378 s num.names$ 'numnames :=
379 numnames 'namesleft :=
380 { namesleft #0 > }
381 {
382 s nameptr "{ll}" format.name$ 't :=
383 t capitalize 't :=
384 s nameptr "{ jj}" format.name$ 'w :=
385 s nameptr "{, ff}{ vv}{ jj}" format.name$ 'u :=
386 u text.length$ 'lang :=
387 #1 'zahl :=
388 "" 'v :=
389 { zahl lang < }
390 { u zahl #1 substring$ "~" =
391 { v "" =
392 { u #1 zahl #1 - substring$ 'v := }
393 'skip$
394 if$
395 v u zahl #2 substring$ * "." * w * 'v :=
396 }
397 'skip$
398 if$
399 zahl #1 + 'zahl := }
400 while$
401 v "" =
402 { u 'v := }
403 'skip$
404 if$
405 t v * fkt * 't :=
406 nameptr #1 >
407 { namesleft #1 >
408 { " ; " * t * }
409 { numnames #2 >
410 { " " * }
411 'skip$
412 if$
413 t "\textsc{others}" = t "\textsc{others} (Hrsg.)" = or
414 { ua.etal * }
415 { " ; " * t * }
416 if$
417 }
418 if$ %% Ende der namesleft-Pruefung
419 }
420 't
421 if$ %% Ende der nameptr-Pruefung
422
423 nameptr #1 + 'nameptr :=
424 namesleft #1 - 'namesleft :=
425 }
426 while$ %% Ende von { namesleft #0 > } ganz oben
427 "" 'fkt := %% fkt wird zurueckgesetzt
428 }
429
430 FUNCTION {format.authors}
431 { author empty$
432 { "" }
433 { author format.names }
434 if$
435 }
436
437 FUNCTION {format.editors}
438 { editor empty$
439 { author empty$
440 { "empty author and editor in " cite$ * warning$ "" }
441 'skip$
442 if$
443 }
444 { author empty$
445 { " (Hrsg.)" 'fkt :=
446 editor format.names
447 }
448 { " (Hrsg.)" 'fkt :=
449 " ; " * editor format.names *
450 }
451 if$
452 }
453 if$
454 }
455
456 %% 2005-11-11
457 FUNCTION { format.authors.organization }
458 { type$ "misc" =
459 { organization empty$
460 { author empty$
461 { "" }
462 { author format.names " (Erfinder)" * }
463 if$
464 }
465 { author empty$
466 { organization }
467 { author format.names " (Erfinder); " *
468 organization * " (Anmelder)" *
469 }
470 if$
471 }
472 if$
473 }
474 { type$ "manual" =
475 { organization empty$
476 { author empty$
477 { "" }
478 { author format.names }
479 if$
480 }
481 { author empty$
482 { organization capitalize " (Hrsg.)" * }
483 { author format.names " ; " *
484 organization capitalize * " (Hrsg.)" *
485 }
486 if$
487 }
488 if$
489 }
490 'skip$
491 if$
492 }
493 if$
494 }
495
496
497 FUNCTION { format.editors.organization }
498 { organization empty$
499 'skip$
500 { type$ "misc" =
501 { organization }
502 { * " ; " * organization " (Veranst.)" *}
503 if$
504 }
505 if$
506 }
507
508 FUNCTION { format.tr.institution }
509 { institution empty$
510 'skip$
511 { institution capitalize }
512 if$
513 }
514
515 FUNCTION {format.ed.incoll}
516 { editor empty$
517 { "" }
518 { " (Hrsg.)" 'fkt :=
519 editor format.names
520 format.editors.organization
521 }
522 if$
523 }
524
525 FUNCTION {article.in.journal}
526 { duplicate$ empty$
527 { pop$ "" }
528 { author missing$ title missing$ and
529 { emphasize }
530 { emphasize "{In: }" swap$ * }
531 if$
532 }
533 if$
534 }
535
536 FUNCTION {format.title}
537 { title empty$
538 { "" }
539 { title } %% Text so wie er dasteht im Feld title
540 if$
541 }
542
543 FUNCTION {format.number}
544 { number empty$
545 { "" }
546 { number " " * } %% Text so wie er im Feld number steht plus " "
547 if$
548 }
549
550
551 FUNCTION {format.digital.type}
552 { type empty$
553 { "" }
554 { type #-1 #4 substring$ "mail" =
555 type #1 #4 substring$ "Mail" =
556 OR
557 { "" }
558 { type } %% Typ einer digitalen Ressource in Form einer
559 %% "Ergaenzenden Angabe", so wie er dasteht;
560 %% Alternativ kann dieser Text auch in NOTE erfasst werden.
561 if$
562 }
563 if$
564 }
565
566 FUNCTION {n.dashify}
567 { 't :=
568 ""
569 { t empty$ not }
570 { t #1 #1 substring$ "-" =
571 { t #1 #2 substring$ "--" = not
572 { "--" *
573 t #2 global.max$ substring$ 't :=
574 }
575 { { t #1 #1 substring$ "-" = }
576 { "-" *
577 t #2 global.max$ substring$ 't :=
578 }
579 while$
580 }
581 if$
582 }
583 { t #1 #1 substring$ *
584 t #2 global.max$ substring$ 't :=
585 }
586 if$
587 }
588 while$
589 }
590
591 %% Auflagenvermerke gibt man komplett, einschliesslich Abkuerzungen in
592 %% das Feld edition ein: ---> EDITION= { 3., erw. und verb. Aufl. }
593 %% oder fremdsprachlich: EDITION= { 2nd edition }
594
595 FUNCTION {format.edition}
596 { edition empty$
597 { "" }
598 { edition }
599 if$
600 }
601
602 FUNCTION {format.date}
603 { year duplicate$ empty$
604 { "empty year in " cite$ * warning$
605 pop$ "" }
606 'skip$
607 if$
608 month empty$
609 'skip$
610 { type$ "book" =
611 type$ "inbook" =
612 OR
613 'skip$
614 { month " " * swap$ * }
615 if$
616 }
617 if$
618 }
619
620
621 FUNCTION {format.edition.or.date}
622 { edition empty$ year empty$ and
623 { "" }
624 { edition empty$
625 { type empty$ NOT
626 { type #-1 #4 substring$ "mail" =
627 type #1 #4 substring$ "Mail" =
628 OR
629 { " gesendet: " "-- " type * swap$ *
630 format.date *
631 }
632 { "\,Version:\,"
633 format.date *
634 }
635 if$
636 }
637 { "\,Version:\,"
638 format.date *
639 }
640 if$
641 }
642 { year empty$
643 { "\,Version:\," edition * }
644 { "\,Version:\," edition * ", " *
645 format.date *
646 }
647 if$
648 }
649 if$
650 }
651 if$
652 }
653
654 FUNCTION {format.doi}
655 { doi empty$
656 { "" }
657 { new.block "\url{http://dx.doi.org/" doi * "}" *
658 %% { new.block "\url{http://dx.medra.org/" doi * "}" *
659 }
660 if$
661 }
662
663 FUNCTION {format.url}
664 { urn missing$
665 { doi missing$
666 { url empty$
667 { "" }
668 { type empty$ NOT
669 { type #-1 #4 substring$ "mail" =
670 type #1 #4 substring$ "Mail" =
671 OR
672 { type$ "incollection" =
673 { "" }
674 { "\,Absenderadresse: \url{" url * "}" * }
675 if$
676 }
677 { "\url{" url * "}" * }%% evtl. "URL" oder "<...>"
678 if$
679 }
680 { "\url{" url * "}" * } %% evtl. "URL" oder "<...>"
681 if$
682 }
683 if$
684 }
685 { format.doi }
686 if$
687 }
688 { "\url{http://nbn-resolving.de/urn/resolver.pl?urn=" urn * "}" *
689 }
690 if$
691 }
692
693 FUNCTION {format.maillist.url}
694 { url empty$
695 { "" }
696 { type empty$
697 { "" }
698 { type #-1 #4 substring$ "mail" =
699 type #1 #4 substring$ "Mail" =
700 OR
701 { "\url{" url * "}" * }
702 { "" }
703 if$
704 }
705 if$
706 }
707 if$
708 }
709
710
711 FUNCTION {format.version.url}
712 { url empty$ doi empty$ urn empty$ and and
713 { type$ "techreport" =
714 { format.edition }
715 { "" }
716 if$
717 }
718 { format.edition.or.date output format.url }
719 if$
720 }
721
722 FUNCTION {format.edition.or.version}
723 { url empty$ doi empty$ urn empty$ and and
724 { format.edition }
725 { format.edition.or.date }
726 if$
727 }
728
729 FUNCTION {format.online.lastcheck}
730 { lastchecked empty$
731 { url empty$ doi empty$ urn empty$ and and
732 { skip$ }
733 { "" output }
734 if$
735 }
736 { url empty$ doi empty$ urn empty$ and and
737 { "there's a lastchecked date but no url, urn or doi in "
738 cite$ * warning$
739 }
740 { part.of.sentence
741 lastchecked "Abruf: " swap$ * output
742 }
743 if$
744 }
745 if$
746 }
747
748
749 FUNCTION {format.maillist.lastcheck}
750 { type empty$ NOT
751 { type #-1 #4 substring$ "mail" =
752 type #1 #4 substring$ "Mail" =
753 OR
754 { format.online.lastcheck }
755 'skip$
756 if$
757 }
758 'skip$
759 if$
760 }
761
762 FUNCTION {format.address.publisher.year}
763 { publisher empty$
764 { address empty$
765 { year empty$
766 { "" }
767 { year }
768 if$
769 }
770 { "there's an address but no publisher in " cite$ * warning$
771 address ", " * format.date *
772 }
773 if$
774 }
775 { address empty$
776 { year empty$
777 { "neither address nor publication date in " cite$ * warning$
778 publisher
779 }
780 { publisher ", " * format.date * }
781 if$
782 }
783 { year empty$
784 { address " : " * publisher * }
785 { address " : " * publisher * ", " * format.date * }
786 if$
787 }
788 if$
789 }
790 if$
791 }
792
793 FUNCTION {format.address.publisher.year.alt}
794 { publisher empty$
795 { address empty$
796 { year empty$
797 { "" }
798 { url empty$
799 { year }
800 { "" }
801 if$
802 }
803 if$
804 }
805 { "there's an address but no publisher in " cite$ * warning$
806 address ", " * format.date *
807 }
808 if$
809 }
810 { url empty$%%%% wenn es URL gibt wird nur die service-provider Adresse
811 %%% ausgegeben, die im publisher-Feld steht
812 { address empty$
813 { year empty$
814 { "neither address nor publication date in " cite$ * warning$
815 publisher
816 }
817 { publisher ", " * format.date * }
818 if$
819 }
820 { year empty$
821 { address " : " * publisher * }
822 { address " : " * publisher * ", " * format.date * }
823 if$
824 }
825 if$
826 }
827 { publisher }
828 if$
829 }
830 if$
831 }
832
833 FUNCTION {format.howpublished}
834 { url missing$ urn missing$ doi missing$ AND AND
835 { howpublished empty$
836 { address empty$
837 { type empty$
838 { "" }
839 { type #-1 #4 substring$ "mail" =
840 { "(gesendet: " new.sentence
841 format.date * ")" *
842 }
843 { "" }
844 if$
845 }
846 if$
847 format.date *
848 }
849 { address ", " * format.date * }
850 if$
851 }
852 { address empty$
853 { howpublished ", " * format.date * }
854 { address " : " * howpublished * ", " * format.date * }
855 if$
856 }
857 if$
858 }
859 { howpublished empty$
860 { "" }
861 { howpublished }
862 if$
863 }
864 if$
865 }
866
867 FUNCTION {format.lastchecked.or.type}%% nur in misc-Funktion
868 { lastchecked empty$
869 { url empty$ doi empty$ urn empty$ and and
870 { type empty$
871 { skip$ }
872 { type set.period.dash.check
873 type output
874 }
875 if$
876 }
877 { type empty$
878 { skip$ }
879 { type #-1 #4 substring$ "mail" =
880 type #1 #4 substring$ "Mail" =
881 OR
882 { skip$ }
883 { type set.period.dash.check
884 type output }
885 if$
886 }
887 if$
888 }
889 if$
890 }
891 { url empty$ doi empty$ urn empty$ and and
892 { "there's a lastchecked date but no url, urn or doi in "
893 cite$ * warning$
894 }
895 { type empty$
896 { "there's a URL and a lastchecked date but no type in "
897 cite$ * warning$
898 }
899 { type set.period.dash.check
900 type output
901 part.of.sentence
902 lastchecked "Abruf: " swap$ * output
903 }
904 if$
905 }
906 if$
907 }
908 if$
909 }
910
911
912 FUNCTION {format.btitle}
913 { title emphasize
914 }
915
916 FUNCTION {tie.or.space.connect}
917 { duplicate$ text.length$ #3 <
918 { "~" }
919 { " " }
920 if$
921 swap$ * *
922 }
923
924 FUNCTION {format.btitle.vol}
925 { number empty$
926 { series empty$
927 { volume empty$
928 { title emphasize }
929 { title emphasize ". Bd." * volume tie.or.space.connect }
930 if$
931 }
932 { volume empty$
933 { title emphasize }%% ein Buch, das zusaetzl. SERIES=Reihentitel besitzt
934 %% jetzt kommt d. Fall des mehrbaendigen Werkes mit Gesamttitel=SERIES
935 %% Zaehlung=VOLUME und Bandtitel=TITLE;
936 { series emphasize ". Bd." * volume tie.or.space.connect
937 ": " * "{\emph{" * title * "}}" * }
938 if$
939 }
940 if$%% series-test
941 }
942 { title emphasize }%% wenn number ex., dann immer title-Feld
943 if$%% Ende number-test
944 }
945
946 FUNCTION {format.series.number.din}
947 { volume empty$
948 { number empty$
949 { series empty$
950 { "" }
951 { "(" series * ")" * } %% d. Seriennr koennte auch gleich hier
952 %% im SERIES-Feld miterfasst werden
953 if$
954 }
955 { series empty$
956 { "(" number * ")" *
957 "there's a number but no series in " cite$ * warning$
958 }
959 { "(" series * number tie.or.space.connect ")" * }
960 if$
961 }
962 if$
963 }
964 { series empty$
965 { "" }
966 { type$ "proceedings" = %% Sonderfall, es darf VOLUME und NUMBER ex. !
967 type$ "inproceedings" = OR
968 { number empty$
969 { "(" series * ")" * }
970 { "(" series * number tie.or.space.connect ")" * }
971 if$
972 }
973 { "" }%% Ausstieg mit Nullstring, s. Kommentar
974 if$
975 }%% bei gezaehlten Reihen MUSS die Reihennr. im Feld NUMBER stehen!
976 if$ %% wenn also d. Feld VOLUME nicht leer ist, dann liegt ausser bei
977 %% Typ PROCEEDINGS falsche
978 } %% Erfassung vor und es erfolgt d. Ausstieg mit d. Nullstring!
979 if$
980 }
981
982 FUNCTION {format.tr.series.or.number}
983 { number empty$
984 { series empty$
985 { "" }
986 { "(" series * ")" * }
987 if$
988 }
989 { series empty$
990 { "(" number * ")" * }
991 { "(" series * number tie.or.space.connect ")" * }
992 if$
993 }
994 if$
995 }
996
997 FUNCTION {format.misc.series}
998 { series empty$
999 { "" }
1000 { "(" series * ")" * }
1001 if$
1002 }
1003
1004 FUNCTION { format.doi.urn }
1005 { urn empty$
1006 { doi empty$
1007 { "" }
1008 { "DOI" doi n.dashify tie.or.space.connect }
1009 if$
1010 }
1011 { "URN" urn n.dashify tie.or.space.connect }
1012 if$
1013 }
1014
1015 FUNCTION { format.isbn.issn }
1016 { isbn empty$
1017 { issn empty$
1018 { "" }
1019 { "ISSN" issn n.dashify tie.or.space.connect }
1020 if$
1021 }
1022 { "ISBN" isbn n.dashify tie.or.space.connect }
1023 if$
1024 }
1025
1026 FUNCTION {format.pages}
1027 { pages empty$
1028 { "" }
1029 { url empty$
1030 { "S." pages n.dashify tie.or.space.connect }
1031 { pages }
1032 if$
1033 }
1034 if$
1035 }
1036
1037 FUNCTION {format.pages.book}
1038 { pages empty$
1039 { "" }
1040 { note empty$ isbn empty$ AND
1041 { "" pages n.dashify tie.or.space.connect " S" *
1042 add.period$ }
1043 { "" pages n.dashify tie.or.space.connect " S" * }
1044 if$
1045 }
1046 if$
1047 }
1048
1049 FUNCTION {format.pages.bkcollation}
1050 { pages empty$
1051 { "" }
1052 { "" pages n.dashify tie.or.space.connect }
1053 if$
1054 }
1055
1056 FUNCTION {format.bkpages.collat.check}
1057 { 's :=
1058 #1 'ptr :=
1059 s text.length$ 'collation :=
1060 collation #1 =
1061 { format.pages.book }
1062 {
1063 collation 'collrest :=
1064 { collrest #0 > }
1065 { s ptr #2 substring$ 't :=
1066 t "S." =
1067 { format.pages.bkcollation
1068 #0 'collrest := }
1069 { ptr #1 + 'ptr :=
1070 collrest #1 - 'collrest :=
1071 #1 collrest =
1072 { format.pages.book }
1073 { skip$ }
1074 if$
1075 }
1076 if$
1077 }
1078 while$
1079 }
1080 if$
1081 }
1082
1083 FUNCTION {format.vol.year.num.pages}
1084 { volume field.or.null
1085 year empty$
1086 { "there's no year in " cite$ * warning$ }
1087 { " (" year * ")" * * }
1088 if$
1089 month empty$
1090 'skip$
1091 { ", " month * * }
1092 if$
1093 number empty$
1094 'skip$
1095 { ", Nr. " number * * }
1096 if$
1097 pages empty$
1098 'skip$
1099 { duplicate$ empty$
1100 { pop$ "" }
1101 { title missing$
1102 { ", " pages format.bkpages.collat.check * *}
1103 { ", " format.pages * *}
1104 if$
1105 }
1106 if$
1107 }
1108 if$
1109 }
1110
1111 FUNCTION {format.chapter.inbook}
1112 { duplicate$ empty$
1113 { pop$ "empty chapter in " cite$ * warning$ }
1114 { type empty$
1115 { "\emph{Kapitel\/} " swap$ tie.or.space.connect }
1116 { type " " * swap$ * }%% wenn keine bes. Abschnittsform gen. werden soll,
1117 %% koennte e. kl. Zwischenraum gewaehlt werden, z.B. " \, "
1118 if$
1119 }
1120 if$
1121 }
1122
1123 FUNCTION {format.chapter.pages}
1124 { chapter empty$
1125 'format.pages
1126 { type empty$
1127 { "Kapitel " }
1128 { url empty$
1129 { type }
1130 { "Kapitel " }
1131 if$
1132 }
1133 if$
1134 chapter tie.or.space.connect
1135 pages empty$
1136 'skip$
1137 { ", " * format.pages * }
1138 if$
1139 }
1140 if$
1141 }
1142
1143 FUNCTION {format.in.ed.booktitle.din}
1144 { booktitle empty$
1145 { "" }
1146 { editor empty$
1147 { volume empty$
1148 { "{In: }" booktitle emphasize * }
1149 { "{In: }" booktitle emphasize *
1150 " Bd." volume tie.or.space.connect *
1151 }
1152 if$
1153 }
1154 { volume empty$
1155 { "{In: }" format.ed.incoll * ": " * booktitle emphasize * }
1156 { "{In: }" format.ed.incoll * ": " * booktitle emphasize *
1157 " Bd." volume tie.or.space.connect *
1158 }
1159 if$
1160 }
1161 if$
1162 }
1163 if$
1164 }
1165
1166 FUNCTION {format.thesis.tr.type}
1167 { type empty$
1168 'skip$
1169 { pop$
1170 type
1171 }
1172 if$
1173 }
1174
1175 FUNCTION {format.article.crossref}
1176 { key empty$
1177 { journal empty$
1178 { "need key or journal for " cite$ * " to crossref " * crossref *
1179 warning$
1180 ""
1181 }
1182 { "{In: }{\emph " journal * "}" * }
1183 if$
1184 }
1185 { "{In: }" key * }
1186 if$
1187 "\cite{" * crossref * "}" * ", " * format.pages *
1188 }
1189
1190 FUNCTION {format.crossref.editor}
1191 { editor #1 "{ll}" format.name$ " (Hrsg.)" *
1192 editor num.names$ duplicate$
1193 #2 >
1194 { pop$ ua.etal * }%% --->u. a.
1195 { #2 <
1196 'skip$
1197 { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
1198 { ua.etal }
1199 { " ; " * editor #2 "{vv~}{ll}" format.name$ * " (Hrsg.)" * }
1200 if$
1201 }
1202 if$
1203 }
1204 if$
1205 }
1206
1207 FUNCTION {format.inbk.vol.title}
1208 { volume empty$
1209 { " In: " }
1210 { title empty$
1211 { " In: Bd." volume tie.or.space.connect
1212 " von " *
1213 }
1214 { "In: Bd." volume tie.or.space.connect ": " * title emphasize *
1215 " (" * year * ") in " *
1216 }
1217 if$
1218 }
1219 if$
1220 }
1221
1222
1223 FUNCTION {format.book.crossref}
1224 { type$ "inbook" =
1225 { format.inbk.vol.title }
1226 { volume empty$
1227 { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
1228 " "
1229 }
1230 { ". -- Bd." volume tie.or.space.connect
1231 " von " *
1232 }
1233 if$
1234 }
1235 if$
1236 editor empty$
1237 editor field.or.null author field.or.null =
1238 or
1239 { key empty$
1240 { series empty$
1241 { "need editor, key, or series for " cite$ * " to crossref " *
1242 crossref * warning$
1243 "" *
1244 }
1245 { "" * }
1246 if$
1247 }
1248 { key * }
1249 if$
1250 }
1251 { "" * }
1252 if$
1253 "\cite{" * crossref * "}" *
1254 }
1255
1256 FUNCTION {format.incoll.inproc.crossref}
1257 { editor empty$
1258 editor field.or.null author field.or.null =
1259 or
1260 { key empty$
1261 { booktitle empty$
1262 { "need editor, key, or booktitle for " cite$ * " to crossref " *
1263 crossref * warning$
1264 ""
1265 }
1266 { "{In: }{\emph " booktitle * "}" * }%%
1267 if$
1268 }
1269 { "{In: }" }
1270 if$
1271 }
1272 { "{In: }" }
1273 if$
1274 "\cite{" * crossref * "}" * %% ", " * format.pages * 5.12.2005
1275 }
1276
1277 FUNCTION {article}
1278 { output.bibitem
1279 format.authors "author" output.check
1280 set.colon.after
1281 format.title "title" output.check
1282 crossref missing$
1283 { journal article.in.journal output.nonnull
1284 new.sentence
1285 format.vol.year.num.pages output
1286 format.url output
1287 }
1288 { format.article.crossref output.nonnull }
1289 if$
1290 format.online.lastcheck
1291 doi set.period.dash.check
1292 urn set.period.dash.check
1293 format.doi.urn output
1294 issn set.period.dash.check
1295 format.isbn.issn output
1296 note set.period.dash.check
1297 note output
1298 fin.entry
1299 }
1300
1301 FUNCTION {book}
1302 { output.bibitem
1303 author empty$
1304 { format.editors "author and editor" output.check }
1305 { format.authors format.editors output.nonnull }
1306 if$
1307 set.colon.after
1308 crossref missing$
1309 { format.btitle.vol "title" output.check }
1310 { format.btitle "title" output.check }
1311 if$
1312 format.edition output
1313 format.address.publisher.year "publisher" output.check
1314 new.sentence
1315 crossref missing$
1316 { format.series.number.din output }
1317 { format.book.crossref output.nonnull }
1318 if$
1319 pages empty$
1320 { skip$ }
1321 { pages set.period.dash.check
1322 pages format.bkpages.collat.check output
1323 }
1324 if$
1325 format.doi output
1326 format.url output
1327 new.block
1328 isbn set.period.dash.check
1329 format.isbn.issn output
1330 note set.period.dash.check
1331 note output
1332 fin.entry
1333 }
1334
1335 FUNCTION {booklet}
1336 { output.bibitem
1337 author empty$
1338 { format.editors "author and editor" output.check }
1339 { format.authors format.editors output.nonnull }
1340 if$
1341 set.colon.after
1342 format.btitle "title" output.check
1343 format.edition.or.version output
1344 format.url output
1345 format.online.lastcheck
1346 format.howpublished output
1347 series new.sentence.checka
1348 format.series.number.din output
1349 pages empty$
1350 { skip$ }
1351 { pages set.period.dash.check
1352 pages format.bkpages.collat.check output
1353 }
1354 if$
1355 type set.period.dash.check
1356 format.digital.type output
1357 doi set.period.dash.check
1358 urn set.period.dash.check
1359 format.doi.urn output
1360 note set.period.dash.check
1361 note output
1362 format.isbn.issn output
1363 fin.entry
1364 }
1365
1366
1367 FUNCTION {inbook}
1368 { output.bibitem
1369 chapter format.chapter.inbook output.nonnull
1370 crossref missing$
1371 { author empty$
1372 { format.editors "\,{In:\,}" swap$ * "author and editor" output.check }
1373 { format.authors "\,{In:\,}" swap$ * output.nonnull }
1374 if$
1375 author empty$ editor empty$ AND
1376 { before.all 'output.state := }
1377 { set.colon.after }
1378 if$
1379 format.btitle.vol "title" output.check
1380 format.edition output
1381 format.address.publisher.year "publisher" output.check
1382 new.sentence
1383 format.series.number.din output
1384 isbn set.period.dash.check
1385 format.isbn.issn output
1386 }
1387 { format.book.crossref output.nonnull }
1388 if$
1389 part.of.sentence
1390 format.pages output
1391 note set.period.dash.check
1392 note output
1393 fin.entry
1394 }
1395
1396 FUNCTION {incollection}
1397 { output.bibitem
1398 format.authors "author" output.check
1399 set.colon.after
1400 format.title "title" output.check
1401 format.version.url output
1402 type empty$ NOT
1403 { type #-1 #4 substring$ "mail" =
1404 type #1 #4 substring$ "Mail" =
1405 OR
1406 'skip$
1407 { format.online.lastcheck }
1408 if$
1409 }
1410 { format.online.lastcheck }
1411 if$
1412 crossref missing$
1413 { format.in.ed.booktitle.din "booktitle" output.check
1414 format.edition output
1415 format.address.publisher.year "publisher" output.check
1416 format.maillist.url output
1417 format.maillist.lastcheck
1418 new.sentence
1419 format.series.number.din output
1420 doi set.period.dash.check
1421 urn set.period.dash.check
1422 format.doi.urn output
1423 isbn set.period.dash.check
1424 issn set.period.dash.check
1425 format.isbn.issn output
1426 }
1427 { format.incoll.inproc.crossref output.nonnull }
1428 if$
1429 part.of.sentence
1430 format.chapter.pages "pages" output.check
1431 note set.period.dash.check
1432 note output
1433 fin.entry
1434 }
1435
1436
1437 FUNCTION {inproceedings}
1438 { output.bibitem
1439 format.authors "author" output.check
1440 set.colon.after
1441 format.title "title" output.check
1442 crossref missing$
1443 { format.in.ed.booktitle.din "booktitle" output.check
1444 address empty$
1445 { organization new.sentence.checka
1446 organization output
1447 part.of.sentence
1448 format.address.publisher.year output
1449 }
1450 { format.address.publisher.year "publisher" output.check }
1451 if$
1452 new.sentence
1453 series empty$
1454 'skip$
1455 { format.series.number.din output }
1456 if$
1457 isbn set.period.dash.check
1458 issn set.period.dash.check
1459 format.isbn.issn output
1460 }
1461 { format.incoll.inproc.crossref output.nonnull }
1462 if$
1463 part.of.sentence
1464 format.pages "pages" output.check
1465 note set.period.dash.check
1466 note output
1467 fin.entry
1468 }
1469
1470 FUNCTION {conference} { inproceedings }%% nach Patashnik, wg US-Kompatibilitaet
1471
1472 FUNCTION {manual}
1473 { output.bibitem
1474 author empty$
1475 { organization empty$
1476 { title empty$
1477 'skip$
1478 {format.btitle "title" output.check }
1479 if$
1480 }
1481 'skip$
1482 if$
1483 }
1484 'skip$
1485 if$
1486 format.authors.organization output.nonnull
1487 set.colon.after
1488 format.btitle "title" output.check
1489 format.edition "edition" output.check
1490 author empty$ organization empty$ AND
1491 { address "address" output.check
1492 part.of.sentence
1493 }
1494 { organization empty$
1495 { address "address" output.check
1496 part.of.sentence
1497 }
1498 { address ": " * organization * output
1499 part.of.sentence
1500 }
1501 if$
1502 }
1503 if$
1504 format.date output
1505 number empty$
1506 'skip$
1507 { "(" number * ") " * output }
1508 if$
1509 pages empty$
1510 { skip$ }
1511 { pages set.period.dash.check
1512 pages format.bkpages.collat.check output
1513 }
1514 if$
1515 format.doi output
1516 format.url output
1517 format.online.lastcheck
1518 note set.period.dash.check
1519 note output
1520 fin.entry
1521 }
1522
1523 %% Standard ist "Diplomarbeit", anderes mit TYPE="anderer Typ" erfassen!
1524 %% z.B. TYPE={Hausarbeit}, TYPE={Diss.}, TYPE={Habil.}, TYPE={Magisterarb.}
1525 FUNCTION {mastersthesis}
1526 { output.bibitem
1527 format.authors "author" output.check
1528 set.colon.after
1529 format.btitle "title" output.check
1530 address output
1531 part.of.sentence
1532 school "school" output.check
1533 part.of.sentence
1534 "Diplomarbeit" format.thesis.tr.type output.nonnull
1535 part.of.sentence
1536 format.date "year" output.check
1537 format.url output
1538 format.online.lastcheck
1539 %% format.digital.resource.type
1540 doi set.period.dash.check
1541 urn set.period.dash.check
1542 format.doi.urn output
1543 %% pages set.period.dash.check
1544 %% format.pages.book output
1545 pages empty$
1546 { skip$ }
1547 { pages set.period.dash.check
1548 pages format.bkpages.collat.check output
1549 }
1550 if$
1551 note set.period.dash.check
1552 note output
1553 fin.entry
1554 }
1555
1556 FUNCTION {phdthesis} %% {mastersthesis}% ist identisch bis auf Standardwert, s.o.
1557 { output.bibitem
1558 format.authors "author" output.check
1559 set.colon.after
1560 format.btitle "title" output.check
1561 address output
1562 part.of.sentence
1563 school "school" output.check
1564 part.of.sentence
1565 "Diss." format.thesis.tr.type output.nonnull % koennte auch `Dissertation' sein
1566 part.of.sentence
1567 format.date "year" output.check
1568 format.url output
1569 format.online.lastcheck
1570 %% format.digital.resource.type
1571 doi set.period.dash.check
1572 urn set.period.dash.check
1573 format.doi.urn output
1574 pages empty$
1575 { skip$ }
1576 { pages set.period.dash.check
1577 pages format.bkpages.collat.check output
1578 }
1579 if$
1580 %% pages set.period.dash.check
1581 %% format.pages.book output
1582 note set.period.dash.check
1583 note output
1584 fin.entry
1585 }
1586
1587
1588 %% Normen, Vornormen, Schutzrechte (Patente) werden hiermit erfasst;
1589 %% (z.Zt. auch noch Internetressourcen)
1590 %% das type-Feld uebernimmt eine wichtige Steuerfunktion:
1591 FUNCTION {misc}
1592 { output.bibitem
1593 type missing$ not
1594 { type duplicate$ #1 #4 substring$ "Norm" =
1595 type #1 #4 substring$ "Vorn" = OR
1596 { " " *
1597 format.number * output
1598 new.sentence
1599 format.date output
1600 title empty$
1601 { skip$ }
1602 { add.period$ new.sentence }
1603 if$
1604 format.btitle "title" output.check
1605 note set.period.dash.check
1606 note output
1607 }
1608 { duplicate$ #1 #6 substring$ "Schutz" =
1609 { " " * format.number * output
1610 new.sentence
1611 "(" * format.date ")" * output
1612 add.period$ new.sentence
1613 format.authors.organization add.period$ output
1614 note output
1615 }
1616 %% wenn irgendein anderer Typ eingetragen ist
1617 { pop$ pop$ ""
1618 title empty$
1619 { note empty$
1620 { url empty$
1621 { "there's no relevant field in " cite$ warning$
1622 pop$ ""
1623 }
1624 { format.url output }%%%
1625 if$
1626 }
1627 { note " " * output.nonnull }
1628 if$
1629 }
1630 { author empty$
1631 { editor empty$
1632 { organization empty$
1633 { skip$ }
1634 { format.editors.organization output.nonnull
1635 set.colon.after
1636 }
1637 if$
1638 }
1639 { format.editors format.editors.organization
1640 output.nonnull set.colon.after
1641 }
1642 if$
1643 }
1644 { format.authors format.editors output.nonnull
1645 set.colon.after
1646 }
1647 if$
1648 format.btitle output.nonnull
1649 url empty$
1650 { format.edition output
1651 format.howpublished output}
1652 { format.howpublished output
1653 format.edition.or.date output
1654 format.url output
1655 }
1656 if$
1657 format.online.lastcheck
1658 %% format.lastchecked.or.type
1659 new.sentence
1660 format.misc.series output
1661 %% note set.period.dash.check
1662 note output
1663 }
1664 if$
1665 }
1666 if$
1667 }
1668 if$
1669 }
1670 %% wenn es keinen type gibt
1671 { title empty$
1672 { note empty$
1673 { url empty$
1674 { "there's no relevant field in " cite$ warning$
1675 pop$ ""
1676 }
1677 { format.url output }%%% das waere e. reine URL
1678 if$
1679 }
1680 { note " " * output.nonnull
1681 %% format.url format.date output
1682 }
1683 if$
1684 }
1685 { author empty$
1686 { editor empty$
1687 { organization empty$
1688 { skip$ }
1689 { format.editors.organization output.nonnull
1690 set.colon.after
1691 }
1692 if$
1693 }
1694 { format.editors format.editors.organization
1695 output.nonnull set.colon.after
1696 }
1697 if$
1698 }
1699 { format.authors format.editors output.nonnull
1700 set.colon.after
1701 }
1702 if$
1703 format.btitle output.nonnull
1704 url empty$
1705 { format.edition output
1706 format.howpublished output}
1707 { format.howpublished output
1708 format.url output
1709 format.edition.or.date output
1710 format.online.lastcheck
1711 %% format.lastchecked.or.type
1712 }
1713 if$
1714 new.sentence
1715 format.misc.series output
1716 note set.period.dash.check
1717 note output
1718 }
1719 if$
1720 }
1721 if$
1722 fin.entry
1723 }
1724
1725 FUNCTION {proceedings}
1726 { output.bibitem
1727 editor empty$
1728 { organization empty$
1729 { "empty organization and editor in " cite$ * warning$ }
1730 { organization " (Veranst.)" * output }
1731 if$
1732 }
1733 { format.editors format.editors.organization output.nonnull }
1734 if$
1735 set.colon.after
1736 format.btitle "title" output.check
1737 volume empty$
1738 { skip$ }
1739 { "{\textnormal{Bd.}}" volume tie.or.space.connect emphasize "volume" output.check }
1740 if$
1741 format.address.publisher.year "publisher" output.check
1742 new.sentence
1743 format.series.number.din output.nonnull
1744 pages empty$
1745 { skip$ }
1746 { pages set.period.dash.check
1747 pages format.bkpages.collat.check output
1748 }
1749 if$
1750 isbn set.period.dash.check
1751 issn set.period.dash.check
1752 format.isbn.issn output
1753 note set.period.dash.check
1754 note output
1755 fin.entry
1756 }
1757
1758 FUNCTION {techreport}
1759 { output.bibitem
1760 author empty$
1761 { format.editors "author and editor" output.check
1762 format.tr.institution output.nonnull }
1763 { format.authors format.editors output.nonnull }
1764 if$
1765 set.colon.after
1766 format.title "title" output.check
1767 institution empty$
1768 'skip$
1769 { author empty$ editor empty$ AND
1770 'skip$
1771 { institution new.sentence.checka
1772 "/ " institution * output.nonnull
1773 }
1774 if$
1775 }
1776 if$
1777 format.version.url output
1778 format.online.lastcheck
1779 format.address.publisher.year output
1780 number new.sentence.checka
1781 format.tr.series.or.number "number" output.check
1782 "Forschungsbericht" format.thesis.tr.type set.period.dash.check
1783 "Forschungsbericht" format.thesis.tr.type output
1784 %% format.digital.resource.type
1785 pages empty$
1786 { skip$ }
1787 { pages set.period.dash.check
1788 pages format.bkpages.collat.check output
1789 }
1790 if$
1791 isbn set.period.dash.check
1792 issn set.period.dash.check
1793 format.isbn.issn output
1794 note set.period.dash.check
1795 note "note" output.check
1796 fin.entry
1797 }
1798
1799 FUNCTION {unpublished} {misc}%% AUTHOR, TITLE, NOTE muessen sein!
1800 %% andere Felder sind optional
1801
1802 FUNCTION {default.type} { misc }
1803
1804
1805 MACRO {jan} {"Januar"}
1806
1807 MACRO {feb} {"Februar"}
1808
1809 MACRO {mar} {"M{\^^b a}rz"}
1810
1811 MACRO {apr} {"April"}
1812
1813 MACRO {mai} {"Mai"}
1814
1815 MACRO {may} {"Mai"}
1816
1817 MACRO {jun} {"Juni"}
1818
1819 MACRO {jul} {"Juli"}
1820
1821 MACRO {aug} {"August"}
1822
1823 MACRO {sep} {"September"}
1824
1825 MACRO {okt} {"Oktober"}
1826
1827 MACRO {oct} {"Oktober"}
1828
1829 MACRO {nov} {"November"}
1830
1831 MACRO {dez} {"Dezember"}
1832
1833 MACRO {dec} {"Dezember"}
1834
1835 %%$$$ stillgelegte Beispiele fuer den Gebrauch von Kuerzeln (hier Zs-Titel).
1836
1837 %%MACRO {acmcs} {"ACM Computing Surveys"}
1838
1839 %%MACRO {acta} {"Acta Informatica"}
1840
1841 READ
1842
1843 FUNCTION {sortify}
1844 { purify$
1845 "l" change.case$
1846 }
1847
1848 FUNCTION {chop.word}
1849 { 's :=
1850 'len :=
1851 s #1 len substring$ =
1852 { s len #1 + global.max$ substring$ }
1853 's
1854 if$
1855 }
1856
1857 FUNCTION {initialize.et.al.char.used}
1858 { #0 'et.al.char.used :=
1859 }
1860
1861 EXECUTE {initialize.et.al.char.used}
1862
1863 FUNCTION {format.lab.names}
1864 { 's :=
1865 s num.names$ 'numnames :=
1866 numnames #1 >
1867 { numnames #4 >
1868 { #3 'namesleft := }
1869 { numnames 'namesleft := }
1870 if$
1871 #1 'nameptr :=
1872 ""
1873 { namesleft #0 > }
1874 { nameptr numnames =
1875 { s nameptr "{ff }{vv }{ll}{ jj}" format.name$ "others" =
1876 %% { "\," * %% kein besonderes Zeichen fuer "others" i. label
1877 { "{\etalchar{+}}" * %% ein plus-Zeichen (+) fuer "others"!
1878 #1 'et.al.char.used :=
1879 }
1880 { s nameptr "{l{}}" format.name$ * }
1881 if$
1882 }
1883 { s nameptr "{l{}}" format.name$ * }
1884 if$
1885 nameptr #1 + 'nameptr :=
1886 namesleft #1 - 'namesleft :=
1887 }
1888 while$
1889 numnames #4 >
1890 %% { "\," * %% s. Bemerkung oben
1891 { "{\etalchar{+}}" *
1892 #1 'et.al.char.used :=
1893 }
1894 'skip$
1895 if$
1896 }
1897 { s #1 "{l{}}" format.name$
1898 duplicate$ text.length$ #2 <
1899 { pop$ s #1 "{ll}" format.name$ #3 text.prefix$ } %% vgl. Anmerkung!
1900 'skip$
1901 if$
1902 }
1903 if$
1904 }
1905
1906 FUNCTION {author.key.label}
1907 { author empty$
1908 { key empty$
1909 { cite$ #1 #3 substring$ }
1910 { key #3 text.prefix$ }
1911 if$
1912 }
1913 { author format.lab.names }
1914 if$
1915 }
1916
1917 FUNCTION {author.editor.key.label}
1918 { author empty$
1919 { editor empty$
1920 { key empty$
1921 { cite$ #1 #3 substring$ }
1922 { key #3 text.prefix$ }
1923 if$
1924 }
1925 { editor format.lab.names }
1926 if$
1927 }
1928 { author format.lab.names }
1929 if$
1930 }
1931
1932 FUNCTION {author.key.organization.label}
1933 { author empty$
1934 { key empty$
1935 { organization empty$
1936 { cite$ #1 #3 substring$ }
1937 { "The " #4 organization chop.word #3 text.prefix$ }
1938 if$
1939 }
1940 { key #3 text.prefix$ }
1941 if$
1942 }
1943 { author format.lab.names }
1944 if$
1945 }
1946
1947 FUNCTION {editor.key.organization.label}
1948 { editor empty$
1949 { key empty$
1950 { organization empty$
1951 { cite$ #1 #3 substring$ }
1952 { "The " #4 organization chop.word organization }
1953 if$
1954 }
1955 { key #5 text.prefix$ }%% man kann Laenge des key einstellen
1956 if$
1957 }
1958 { key empty$%% wenn key vh., dann macht er das label! Lo,18/5/99
1959 { editor format.lab.names }
1960 { key #5 text.prefix$ }
1961 if$
1962 }
1963 if$
1964 }
1965
1966 FUNCTION {calc.label}
1967 { type$ "book" =
1968 type$ "booklet" =
1969 type$ "inbook" =
1970 or or
1971 'author.editor.key.label
1972 { type$ "proceedings" =
1973 'editor.key.organization.label
1974 { type$ "manual" =
1975 'author.key.organization.label
1976 'author.key.label
1977 if$
1978 }
1979 if$
1980 }
1981 if$
1982 duplicate$
1983 year field.or.null purify$ #-1 #2 substring$
1984 *
1985 'label :=
1986 year field.or.null purify$ #-1 #4 substring$
1987 *
1988 sortify 'sort.label :=
1989 }
1990
1991 FUNCTION {sort.format.names}
1992 { 's :=
1993 #1 'nameptr :=
1994 ""
1995 s num.names$ 'numnames :=
1996 numnames 'namesleft :=
1997 { namesleft #0 > }
1998 { nameptr #1 >
1999 { " " * }
2000 'skip$
2001 if$
2002 s nameptr "{ll{ }}{ ff{ }}{ vv{ }}{ jj{ }}" format.name$ 't :=
2003 nameptr numnames = t "others" = and
2004 { ua.etal * }
2005 { t sortify * }
2006 if$
2007 nameptr #1 + 'nameptr :=
2008 namesleft #1 - 'namesleft :=
2009 }
2010 while$
2011 }
2012
2013 FUNCTION {sort.format.title}
2014 { 't :=
2015 "A " #2
2016 "An " #3
2017 "Der " #4
2018 "Die " #4
2019 "Das " #4
2020 "Ein " #4
2021 "Eine " #5
2022 "The " #4 t chop.word
2023 chop.word
2024 chop.word
2025 chop.word
2026 chop.word
2027 chop.word
2028 chop.word
2029 chop.word
2030 sortify
2031 #1 global.max$ substring$
2032 }
2033
2034 FUNCTION {author.sort}
2035 { author empty$
2036 { key empty$
2037 { "to sort, need author or key in " cite$ * warning$
2038 ""
2039 }
2040 { key sortify }
2041 if$
2042 }
2043 { author sort.format.names }
2044 if$
2045 }
2046
2047 FUNCTION {author.editor.sort}
2048 { author empty$
2049 { editor empty$
2050 { key empty$
2051 { "to sort, need author, editor, or key in " cite$ * warning$
2052 ""
2053 }
2054 { key sortify }
2055 if$
2056 }
2057 { editor sort.format.names }
2058 if$
2059 }
2060 { author sort.format.names }
2061 if$
2062 }
2063
2064 FUNCTION {author.organization.sort}
2065 { author empty$
2066 { organization empty$
2067 { key empty$
2068 { "to sort, need author, organization, or key in " cite$ * warning$
2069 ""
2070 }
2071 { key sortify }
2072 if$
2073 }
2074 { "The " #4 organization chop.word sortify }
2075 if$
2076 }
2077 { author sort.format.names }
2078 if$
2079 }
2080
2081 FUNCTION {editor.organization.sort}
2082 { editor empty$
2083 { organization empty$
2084 { key empty$
2085 { "to sort, need editor, organization, or key in " cite$ * warning$
2086 ""
2087 }
2088 { key sortify }
2089 if$
2090 }
2091 { "The " #4 organization chop.word sortify }
2092 if$
2093 }
2094 { editor sort.format.names }
2095 if$
2096 }
2097
2098 FUNCTION {presort}
2099 { calc.label
2100 sort.label
2101 " "
2102 *
2103 type$ "book" =
2104 type$ "booklet" =
2105 type$ "inbook" =
2106 or or
2107 'author.editor.sort
2108 { type$ "proceedings" =
2109 'editor.organization.sort
2110 { type$ "manual" =
2111 'author.organization.sort
2112 'author.sort
2113 if$
2114 }
2115 if$
2116 }
2117 if$
2118 *
2119 " "
2120 *
2121 year field.or.null sortify
2122 *
2123 " "
2124 *
2125 title field.or.null
2126 sort.format.title
2127 *
2128 #1 entry.max$ substring$
2129 'sort.key$ :=
2130 }
2131
2132 ITERATE {presort}
2133
2134 SORT
2135
2136 FUNCTION {initialize.longest.label}
2137 { "" 'longest.label :=
2138 #0 int.to.chr$ 'last.sort.label :=
2139 "" 'next.extra :=
2140 #0 'longest.label.width :=
2141 #0 'last.extra.num :=
2142 }
2143
2144 FUNCTION {forward.pass}
2145 { last.sort.label sort.label =
2146 { last.extra.num #1 + 'last.extra.num :=
2147 last.extra.num int.to.chr$ 'extra.label :=
2148 }
2149 { "a" chr.to.int$ 'last.extra.num :=
2150 "" 'extra.label :=
2151 sort.label 'last.sort.label :=
2152 }
2153 if$
2154 }
2155
2156 FUNCTION {reverse.pass}
2157 { next.extra "b" =
2158 { "a" 'extra.label := }
2159 'skip$
2160 if$
2161 label extra.label * 'label :=
2162 label width$ longest.label.width >
2163 { label 'longest.label :=
2164 label width$ 'longest.label.width :=
2165 }
2166 'skip$
2167 if$
2168 extra.label 'next.extra :=
2169 }
2170
2171 EXECUTE {initialize.longest.label}
2172
2173 ITERATE {forward.pass}
2174
2175 REVERSE {reverse.pass}
2176
2177 FUNCTION {begin.bib}
2178 { et.al.char.used
2179 { "\newcommand{\etalchar}[1]{$^{#1}$}" write$ newline$ }
2180 'skip$
2181 if$
2182 preamble$ empty$
2183 'skip$
2184 { preamble$ write$ newline$ }
2185 if$
2186 "\begin{thebibliography}{" longest.label * "}" * write$ newline$
2187 newline$
2188 "% this bibliography is generated by alphadin.bst [8.2] from 2005-12-21"
2189 write$ newline$
2190 newline$
2191 "\providecommand{\url}[1]{\texttt{#1}}"
2192 write$ newline$
2193 "\expandafter\ifx\csname urlstyle\endcsname\relax"
2194 write$ newline$
2195 " \providecommand{\doi}[1]{doi: #1}\else"
2196 write$ newline$
2197 " \providecommand{\doi}{doi: \begingroup \urlstyle{rm}\Url}\fi"
2198 write$ newline$
2199 }
2200
2201 EXECUTE {begin.bib}
2202
2203 EXECUTE {init.state.consts}
2204
2205 ITERATE {call.type$}
2206
2207 FUNCTION {end.bib}
2208 { newline$
2209 "\end{thebibliography}" write$ newline$
2210 }
2211
2212 EXECUTE {end.bib}