Debian Codegraph @

texmf-dist/bibtex/bst/bgteubner/bgteuabbr.bst

raw
1 %%
2 %% This is file `bgteuabbr.bst',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% bgteucls.dtx (with options: `bibstyle,short,names1')
8 %%
9 %% bgteubner class bundle
10 %%
11 %% Copyright 2003--2015 Harald Harders
12 %%
13 %% This program may be distributed and/or modified under the
14 %% conditions of the LaTeX Project Public License, either version 1.3
15 %% of this license or (at your opinion) any later version.
16 %% The latest version of this license is in
17 %% http://www.latex-project.org/lppl.txt
18 %% and version 1.3 or later is part of all distributions of LaTeX
19 %% version 1999/12/01 or later.
20 %%
21 %% This program consists of all files listed in manifest.txt.
22 %%
23 %% This BibTeX style is intended to be used with the bgteubner
24 %% document class and the babelbib package. It may work together with
25 %% other document classes but is unlikely to work without the
26 %% babelbib package.
27 %%
28 %% [email protected]
29 %%
30 ENTRY
31 { address
32 author
33 booktitle
34 chapter
35 edition
36 editor
37 howpublished
38 institution
39 isbn
40 issn
41 journal
42 key
43 language
44 month
45 note
46 number
47 organization
48 pages
49 publisher
50 school
51 series
52 title
53 type
54 url
55 volume
56 year
57 }
58 {}
59 { label }
60
61 INTEGERS
62 { output.state
63 before.all
64 mid.sentence
65 after.sentence
66 after.block
67 before.title
68 }
69 STRINGS
70 { s
71 t
72 language.state
73 change.temp
74 }
75 FUNCTION {init.state.consts}
76 { #0 'before.all :=
77 #1 'mid.sentence :=
78 #2 'after.sentence :=
79 #3 'after.block :=
80 #4 'before.title :=
81 "nostate" 'language.state :=
82 }
83 FUNCTION {not}
84 { { #0 }
85 { #1 }
86 if$
87 }
88 FUNCTION {and}
89 { 'skip$
90 { pop$ #0 }
91 if$
92 }
93 FUNCTION {or}
94 { { pop$ #1 }
95 'skip$
96 if$
97 }
98 FUNCTION {language.change.case}
99 {
100 'change.temp :=
101 't :=
102 "\btxifchangecase {"
103 t change.temp change.case$ *
104 "}{" *
105 t *
106 "}" *
107 }
108 FUNCTION {output.nonnull}
109 { 's :=
110 output.state mid.sentence =
111 { ", " * write$ }
112 { output.state after.block =
113 { add.period$ write$
114 newline$
115 "\newblock " write$
116 }
117 { output.state before.all =
118 'write$
119 {
120 output.state before.title =
121 { "\btxauthorcolon\ " * write$ }
122 { add.period$ " " * write$ }
123 if$
124 }
125 if$
126 }
127 if$
128 mid.sentence 'output.state :=
129 }
130 if$
131 s
132 }
133 FUNCTION {output}
134 { duplicate$ empty$
135 'pop$
136 'output.nonnull
137 if$
138 }
139 FUNCTION {output.check}
140 { 't :=
141 duplicate$ empty$
142 { pop$ "empty " t * " in " * cite$ * warning$ }
143 'output.nonnull
144 if$
145 }
146 FUNCTION {output.bibitem}
147 { newline$
148 language empty$
149 { "empty language in " cite$ * warning$ }
150 { language.state language =
151 'skip$
152 { "\btxselectlanguage {" language * "}" * write$
153 newline$
154 }
155 if$
156 language 'language.state :=
157 }
158 if$
159 "\bibitem{" write$
160 cite$ write$
161 "}" write$
162 newline$
163 ""
164 before.all 'output.state :=
165 }
166 FUNCTION {fin.entry}
167 { add.period$
168 write$
169 newline$
170 }
171 FUNCTION {new.block}
172 { output.state before.all =
173 'skip$
174 { after.block 'output.state := }
175 if$
176 }
177 FUNCTION {new.sentence}
178 { output.state after.block =
179 'skip$
180 { output.state before.all =
181 'skip$
182 { after.sentence 'output.state := }
183 if$
184 }
185 if$
186 }
187 FUNCTION {after.authors}
188 { output.state before.all =
189 'skip$
190 { before.title 'output.state := }
191 if$
192 }
193 FUNCTION {new.block.checka}
194 { empty$
195 'skip$
196 'new.block
197 if$
198 }
199 FUNCTION {new.block.checkb}
200 { empty$
201 swap$ empty$
202 and
203 'skip$
204 'new.block
205 if$
206 }
207 FUNCTION {new.block.checkc}
208 { empty$
209 swap$ empty$
210 and
211 'skip$
212 'after.authors
213 if$
214 }
215 FUNCTION {new.sentence.checka}
216 { empty$
217 'skip$
218 'new.sentence
219 if$
220 }
221 FUNCTION {new.sentence.checkb}
222 { empty$
223 swap$ empty$
224 and
225 'skip$
226 'new.sentence
227 if$
228 }
229 FUNCTION {field.or.null}
230 { duplicate$ empty$
231 { pop$ "" }
232 'skip$
233 if$
234 }
235 FUNCTION {namefont}
236 { duplicate$ empty$
237 { pop$ "" }
238 { "\btxnamefont {" swap$ * "}" * }
239 if$
240 }
241 FUNCTION {lastnamefont}
242 { duplicate$ empty$
243 { pop$ "" }
244 { "\btxlastnamefont {" swap$ * "}" * }
245 if$
246 }
247 FUNCTION {titlefont}
248 { duplicate$ empty$
249 { pop$ "" }
250 { "\btxtitlefont {" swap$ * "}" * }
251 if$
252 }
253 FUNCTION {journalfont}
254 { duplicate$ empty$
255 { pop$ "" }
256 { "\btxjournalfont {" swap$ * "}" * }
257 if$
258 }
259 FUNCTION {volumefont}
260 { duplicate$ empty$
261 { pop$ "" }
262 { "\btxvolumefont {" swap$ * "}" * }
263 if$
264 }
265 FUNCTION {etalfont}
266 { duplicate$ empty$
267 { pop$ "" }
268 { "\btxetalfont {" swap$ * "}" * }
269 if$
270 }
271 INTEGERS { nameptr namesleft numnames }
272 FUNCTION {format.names}
273 { 's :=
274 #1 'nameptr :=
275 s num.names$ 'numnames :=
276 numnames 'namesleft :=
277 { namesleft #0 > }
278 { nameptr #1 >
279 {
280 s nameptr "{f{.\,}.~}{vv~}" format.name$
281 s nameptr "{ll}" format.name$ lastnamefont *
282 s nameptr "{, jj}" format.name$ * 't :=
283 namesleft #1 >
284 { ", " * t namefont * }
285 { numnames #2 >
286 { "\btxandcomma {}" * }
287 'skip$
288 if$
289 s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ "others" =
290 { " " "\btxetalshort {.}" etalfont * * }
291 { " \btxandlong {}\ " * t namefont * }
292 if$
293 }
294 if$
295 }
296 {
297 s nameptr "{ll}" format.name$ lastnamefont
298 s nameptr "{,~jj}{,~f{.\,}.}{~vv}" format.name$ * namefont
299 }
300 if$
301 nameptr #1 + 'nameptr :=
302 namesleft #1 - 'namesleft :=
303 }
304 while$
305 }
306 FUNCTION {format.authors}
307 { author empty$
308 { "" }
309 { author format.names }
310 if$
311 }
312 FUNCTION {format.editors}
313 { editor empty$
314 { "" }
315 { editor format.names
316 editor num.names$ #1 >
317 { "\ (\btxeditorsshort {.})" * }
318 { "\ (\btxeditorshort {.})" * }
319 if$
320 }
321 if$
322 }
323 FUNCTION {format.title}
324 { title empty$
325 { "" }
326 { title "t" language.change.case titlefont }
327 if$
328 }
329 FUNCTION {n.dashify}
330 { 't :=
331 ""
332 { t empty$ not }
333 { t #1 #1 substring$ "-" =
334 { t #1 #2 substring$ "--" = not
335 { "--" *
336 t #2 global.max$ substring$ 't :=
337 }
338 { { t #1 #1 substring$ "-" = }
339 { "-" *
340 t #2 global.max$ substring$ 't :=
341 }
342 while$
343 }
344 if$
345 }
346 { t #1 #1 substring$ *
347 t #2 global.max$ substring$ 't :=
348 }
349 if$
350 }
351 while$
352 }
353 FUNCTION {format.date}
354 { year empty$
355 { month empty$
356 { "" }
357 { "there's a month but no year in " cite$ * warning$
358 month
359 }
360 if$
361 }
362 { month empty$
363 'year
364 { month "\ " * year * }
365 if$
366 }
367 if$
368 }
369 FUNCTION {format.btitle}
370 { title titlefont
371 }
372 FUNCTION {tie.or.space.connect}
373 { duplicate$ text.length$ #3 <
374 { "~" }
375 { "\ " }
376 if$
377 swap$ * *
378 }
379 FUNCTION {volume.tie.or.space.connect}
380 { duplicate$ text.length$ #3 <
381 { "~" }
382 { "\ " }
383 if$
384 swap$ volumefont * *
385 }
386 FUNCTION {either.or.check}
387 { empty$
388 'pop$
389 { "can't use both " swap$ * " fields in " * cite$ * warning$ }
390 if$
391 }
392 FUNCTION {format.bvolume}
393 { volume empty$
394 { "" }
395 { output.state after.block =
396 { "\Btxvolumeshort {.}" }
397 { "\btxvolumeshort {.}" }
398 if$
399 volume volume.tie.or.space.connect
400 series empty$
401 'skip$
402 { " \btxofseriesshort {.}\ " * series titlefont * }
403 if$
404 "volume and number" number either.or.check
405 }
406 if$
407 }
408 FUNCTION {format.number.series}
409 { volume empty$
410 { number empty$
411 { series field.or.null }
412 { output.state mid.sentence =
413 { "\btxnumbershort {.}" }
414 { "\Btxnumbershort {.}" }
415 if$
416 number tie.or.space.connect
417 series empty$
418 { "there's a number but no series in " cite$ * warning$ }
419 { " \btxinseriesshort {.}\ " * series titlefont * }
420 if$
421 }
422 if$
423 }
424 { "" }
425 if$
426 }
427 FUNCTION {format.edition}
428 { edition empty$
429 { "" }
430 {
431 output.state mid.sentence =
432 { edition "l" language.change.case "~\btxeditionshort {.}" * }
433 { edition "t" language.change.case "~\btxeditionshort {.}" * }
434 if$
435 }
436 if$
437 }
438 FUNCTION {format.isbn}
439 { isbn empty$
440 { "" }
441 { "\btxISBN~\btxISBNfont {" isbn * "}" * }
442 if$
443 }
444 FUNCTION {format.issn}
445 { issn empty$
446 { "" }
447 { "\btxISSN~\btxISSNfont {" issn * "}" * }
448 if$
449 }
450 FUNCTION {format.url}
451 { url empty$
452 { "" }
453 { "\btxurlfont {" url * "}" * }
454 if$
455 }
456 INTEGERS { multiresult }
457 FUNCTION {multi.page.check}
458 { 't :=
459 #0 'multiresult :=
460 { multiresult not
461 t empty$ not
462 and
463 }
464 { t #1 #1 substring$
465 duplicate$ "-" =
466 swap$ duplicate$ "," =
467 swap$ "+" =
468 or or
469 { #1 'multiresult := }
470 { t #2 global.max$ substring$ 't := }
471 if$
472 }
473 while$
474 multiresult
475 }
476 FUNCTION {format.pages}
477 { pages empty$
478 { "" }
479 { pages multi.page.check
480 { "\btxpagesshort {.}" pages n.dashify tie.or.space.connect }
481 { "\btxpageshort {.}" pages tie.or.space.connect }
482 if$
483 }
484 if$
485 }
486
487 FUNCTION {format.vol.num.pages}
488 { volume field.or.null
489 number empty$
490 'skip$
491 { "(" number * ")" * *
492 volume empty$
493 { "there's a number but no volume in " cite$ * warning$ }
494 'skip$
495 if$
496 }
497 if$
498 pages empty$
499 'skip$
500 { duplicate$ empty$
501 { pop$ format.pages }
502 { ":" * pages n.dashify * }
503 if$
504 }
505 if$
506 }
507
508 FUNCTION {format.chapter.pages}
509 { chapter empty$
510 'format.pages
511 { type empty$
512 { "\btxchaptershort {.}" }
513 { type "l" language.change.case }
514 if$
515 chapter tie.or.space.connect
516 pages empty$
517 'skip$
518 { ", " * format.pages * }
519 if$
520 }
521 if$
522 }
523
524 FUNCTION {format.in.ed.booktitle}
525 { booktitle empty$
526 { "" }
527 { editor empty$
528 { "\Btxinshort {.}\ " booktitle titlefont * }
529 { "\Btxinshort {.}\ " format.editors * ": " * booktitle titlefont * }
530 if$
531 }
532 if$
533 }
534
535 FUNCTION {empty.misc.check}
536 { author empty$ title empty$ howpublished empty$
537 month empty$ year empty$ note empty$
538 and and and and and
539 key empty$ not and
540 { "all relevant fields are empty in " cite$ * warning$ }
541 'skip$
542 if$
543 }
544
545 FUNCTION {format.thesis.type}
546 { type empty$
547 'skip$
548 { pop$
549 type "t" language.change.case
550 }
551 if$
552 }
553
554 FUNCTION {format.tr.number}
555 {
556 number empty$
557 {
558 type empty$
559 { "\btxtechrepshort {.}" }
560 { type "t" language.change.case }
561 if$
562 }
563 {
564 type empty$
565 { "\Btxtechrepshort {.}" }
566 { type "t" language.change.case }
567 if$
568 number tie.or.space.connect
569 }
570 if$
571 }
572
573 FUNCTION {format.article.crossref}
574 { key empty$
575 { journal empty$
576 { "need key or journal for " cite$ * " to crossref " * crossref *
577 warning$
578 ""
579 }
580 { "\Btxinshort {.}\ " journal titlefont * }
581 if$
582 }
583 { "\Btxinshort {.}\ " key titlefont * }
584 if$
585 " \cite{" * crossref * "}" *
586 }
587
588 FUNCTION {format.crossref.editor}
589 { editor #1 "{f.~}{vv~}{ll}{, jj}" format.name$ namefont
590 editor num.names$ duplicate$
591 #2 >
592 { pop$ " " "\btxetalshort {.}" etalfont * * }
593 { #2 <
594 'skip$
595 { editor #2 "{ff }{vv~}{ll}{ jj}" format.name$ "others" =
596 { " " "\btxetalshort {.}" etalfont * * }
597 { " \btxandlong {}\ " * editor #2
598 "{f.~}{vv~}{ll}{, jj}" format.name$
599 namefont * }
600 if$
601 }
602 if$
603 }
604 if$
605 }
606
607 FUNCTION {format.book.crossref}
608 { volume empty$
609 { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
610 "\Btxinshort {.}\ "
611 }
612 { "\Btxvolumeshort {.}" volume volume.tie.or.space.connect
613 " \btxofseriesshort {.}\ " *
614 }
615 if$
616 editor empty$
617 editor field.or.null author field.or.null =
618 or
619 { key empty$
620 { series empty$
621 { "need editor, key, or series for " cite$ * " to crossref " *
622 crossref * warning$
623 "" *
624 }
625 { series titlefont * }
626 if$
627 }
628 { key titlefont * }
629 if$
630 }
631 { format.crossref.editor * }
632 if$
633 " \cite{" * crossref * "}" *
634 }
635
636 FUNCTION {format.incoll.inproc.crossref}
637 { editor empty$
638 editor field.or.null author field.or.null =
639 or
640 { key empty$
641 { booktitle empty$
642 { "need editor, key, or booktitle for " cite$ * " to crossref " *
643 crossref * warning$
644 ""
645 }
646 { "\Btxinshort {.}\ " booktitle titlefont * }
647 if$
648 }
649 { "\Btxinshort {.}\ " key titlefont * }
650 if$
651 }
652 { "\Btxinshort {.}\ " format.crossref.editor * }
653 if$
654 " \cite{" * crossref * "}" *
655 }
656
657 FUNCTION {article}
658 { output.bibitem
659 format.authors "author" output.check
660 after.authors
661 format.title "title" output.check
662 new.block
663 crossref missing$
664 { journal
665 title missing$
666 { titlefont }
667 { journalfont }
668 if$
669 "journal" output.check
670 format.vol.num.pages output
671 format.date "year" output.check
672 }
673 { format.article.crossref output.nonnull
674 format.pages output
675 }
676 if$
677 format.issn output
678 new.block
679 format.url output
680 note output
681 fin.entry
682 }
683
684 FUNCTION {book}
685 { output.bibitem
686 author empty$
687 { format.editors "author and editor" output.check }
688 { format.authors output.nonnull
689 crossref missing$
690 { "author and editor" editor either.or.check }
691 'skip$
692 if$
693 }
694 if$
695 after.authors
696 format.btitle "title" output.check
697 crossref missing$
698 { format.bvolume output
699 new.block
700 format.number.series output
701 new.sentence
702 publisher "publisher" output.check
703 address output
704 }
705 { new.block
706 format.book.crossref output.nonnull
707 }
708 if$
709 format.edition output
710 format.date "year" output.check
711 format.isbn output
712 new.block
713 format.url output
714 note output
715 fin.entry
716 }
717
718 FUNCTION {booklet}
719 { output.bibitem
720 format.authors output
721 after.authors
722 format.title "title" output.check
723 howpublished address new.block.checkb
724 howpublished output
725 address output
726 format.date output
727 new.block
728 format.url output
729 note output
730 fin.entry
731 }
732
733 FUNCTION {inbook}
734 { output.bibitem
735 author empty$
736 { format.editors "author and editor" output.check }
737 { format.authors output.nonnull
738 crossref missing$
739 { "author and editor" editor either.or.check }
740 'skip$
741 if$
742 }
743 if$
744 after.authors
745 format.btitle "title" output.check
746 crossref missing$
747 { format.bvolume output
748 format.chapter.pages "chapter and pages" output.check
749 new.block
750 format.number.series output
751 new.sentence
752 publisher "publisher" output.check
753 address output
754 }
755 { format.chapter.pages "chapter and pages" output.check
756 new.block
757 format.book.crossref output.nonnull
758 }
759 if$
760 format.edition output
761 format.date "year" output.check
762 format.isbn output
763 new.block
764 format.url output
765 note output
766 fin.entry
767 }
768
769 FUNCTION {incollection}
770 { output.bibitem
771 format.authors "author" output.check
772 after.authors
773 format.title "title" output.check
774 new.block
775 crossref missing$
776 { format.in.ed.booktitle "booktitle" output.check
777 format.bvolume output
778 format.number.series output
779 format.chapter.pages output
780 new.sentence
781 publisher "publisher" output.check
782 address output
783 format.edition output
784 format.date "year" output.check
785 }
786 { format.incoll.inproc.crossref output.nonnull
787 format.chapter.pages output
788 }
789 if$
790 format.isbn output
791 new.block
792 format.url output
793 note output
794 fin.entry
795 }
796
797 FUNCTION {inproceedings}
798 { output.bibitem
799 format.authors "author" output.check
800 after.authors
801 format.title "title" output.check
802 new.block
803 crossref missing$
804 { format.in.ed.booktitle "booktitle" output.check
805 format.bvolume output
806 format.number.series output
807 format.pages output
808 address empty$
809 { organization publisher new.sentence.checkb
810 organization output
811 publisher output
812 format.date "year" output.check
813 }
814 { address output.nonnull
815 format.date "year" output.check
816 new.sentence
817 organization output
818 publisher output
819 }
820 if$
821 }
822 { format.incoll.inproc.crossref output.nonnull
823 format.pages output
824 }
825 if$
826 format.isbn output
827 new.block
828 format.url output
829 note output
830 fin.entry
831 }
832
833 FUNCTION {conference} { inproceedings }
834
835 FUNCTION {manual}
836 { output.bibitem
837 author empty$
838 { organization empty$
839 'skip$
840 { organization output.nonnull
841 address output
842 }
843 if$
844 }
845 { format.authors output.nonnull }
846 if$
847 after.authors
848 format.btitle "title" output.check
849 author empty$
850 { organization empty$
851 { address new.block.checka
852 address output
853 }
854 'skip$
855 if$
856 }
857 { organization address new.block.checkb
858 organization output
859 address output
860 }
861 if$
862 format.edition output
863 format.date output
864 format.isbn output
865 new.block
866 format.url output
867 note output
868 fin.entry
869 }
870
871 FUNCTION {mastersthesis}
872 { output.bibitem
873 format.authors "author" output.check
874 after.authors
875 format.title "title" output.check
876 new.block
877 "\btxmastthesis {}" format.thesis.type output.nonnull
878 school "school" output.check
879 address output
880 format.date "year" output.check
881 new.block
882 format.url output
883 note output
884 fin.entry
885 }
886
887 FUNCTION {misc}
888 { output.bibitem
889 format.authors output
890 title howpublished new.block.checkc
891 format.title output
892 howpublished new.block.checka
893 howpublished output
894 format.date output
895 format.isbn output
896 format.issn output
897 new.block
898 format.url output
899 note output
900 fin.entry
901 empty.misc.check
902 }
903
904 FUNCTION {phdthesis}
905 { output.bibitem
906 format.authors "author" output.check
907 after.authors
908 format.btitle "title" output.check
909 new.block
910 "\btxphdthesis {}" format.thesis.type output.nonnull
911 school "school" output.check
912 address output
913 format.date "year" output.check
914 format.isbn output
915 new.block
916 format.url output
917 note output
918 fin.entry
919 }
920
921 FUNCTION {proceedings}
922 { output.bibitem
923 editor empty$
924 { organization output }
925 { format.editors output.nonnull }
926 if$
927 after.authors
928 format.btitle "title" output.check
929 format.bvolume output
930 format.number.series output
931 address empty$
932 { editor empty$
933 { publisher new.sentence.checka }
934 { organization publisher new.sentence.checkb
935 organization output
936 }
937 if$
938 publisher output
939 format.date "year" output.check
940 }
941 { address output.nonnull
942 format.date "year" output.check
943 new.sentence
944 editor empty$
945 'skip$
946 { organization output }
947 if$
948 publisher output
949 }
950 if$
951 format.isbn output
952 new.block
953 format.url output
954 note output
955 fin.entry
956 }
957
958 FUNCTION {techreport}
959 { output.bibitem
960 format.authors "author" output.check
961 after.authors
962 format.title "title" output.check
963 new.block
964 format.tr.number output.nonnull
965 institution "institution" output.check
966 address output
967 format.date "year" output.check
968 format.isbn output
969 new.block
970 format.url output
971 note output
972 fin.entry
973 }
974
975 FUNCTION {unpublished}
976 { output.bibitem
977 format.authors "author" output.check
978 after.authors
979 format.title "title" output.check
980 new.block
981 format.url output
982 note "note" output.check
983 format.date output
984 fin.entry
985 }
986
987 FUNCTION {default.type} { misc }
988
989 MACRO {jan} {"\btxmonjanshort {.}"}
990 MACRO {feb} {"\btxmonfebshort {.}"}
991 MACRO {mar} {"\btxmonmarshort {.}"}
992 MACRO {apr} {"\btxmonaprshort {.}"}
993 MACRO {may} {"\btxmonmayshort {.}"}
994 MACRO {jun} {"\btxmonjunshort {.}"}
995 MACRO {jul} {"\btxmonjulshort {.}"}
996 MACRO {aug} {"\btxmonaugshort {.}"}
997 MACRO {sep} {"\btxmonsepshort {.}"}
998 MACRO {oct} {"\btxmonoctshort {.}"}
999 MACRO {nov} {"\btxmonnovshort {.}"}
1000 MACRO {dec} {"\btxmondecshort {.}"}
1001 MACRO {acmcs} {"ACM Computing Surveys"}
1002 MACRO {acta} {"Acta Informatica"}
1003 MACRO {cacm} {"Communications of the ACM"}
1004 MACRO {ibmjrd} {"IBM Journal of Research and Development"}
1005 MACRO {ibmsj} {"IBM Systems Journal"}
1006 MACRO {ieeese} {"IEEE Transactions on Software Engineering"}
1007 MACRO {ieeetc} {"IEEE Transactions on Computers"}
1008 MACRO {ieeetcad}
1009 {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
1010 MACRO {ipl} {"Information Processing Letters"}
1011 MACRO {jacm} {"Journal of the ACM"}
1012 MACRO {jcss} {"Journal of Computer and System Sciences"}
1013 MACRO {scp} {"Science of Computer Programming"}
1014 MACRO {sicomp} {"SIAM Journal on Computing"}
1015 MACRO {tocs} {"ACM Transactions on Computer Systems"}
1016 MACRO {tods} {"ACM Transactions on Database Systems"}
1017 MACRO {tog} {"ACM Transactions on Graphics"}
1018 MACRO {toms} {"ACM Transactions on Mathematical Software"}
1019 MACRO {toois} {"ACM Transactions on Office Information Systems"}
1020 MACRO {toplas} {"ACM Transactions on Programming Languages and Systems"}
1021 MACRO {tcs} {"Theoretical Computer Science"}
1022
1023 READ
1024
1025 FUNCTION {sortify}
1026 { purify$
1027 "l" change.case$
1028 }
1029
1030 INTEGERS { len }
1031
1032 FUNCTION {chop.word}
1033 { 's :=
1034 'len :=
1035 s #1 len substring$ =
1036 { s len #1 + global.max$ substring$ }
1037 's
1038 if$
1039 }
1040
1041 FUNCTION {sort.format.names}
1042 { 's :=
1043 #1 'nameptr :=
1044 ""
1045 s num.names$ 'numnames :=
1046 numnames 'namesleft :=
1047 { namesleft #0 > }
1048 { nameptr #1 >
1049 { " " * }
1050 'skip$
1051 if$
1052 s nameptr "{ll{ }}{ f{ }}{vv{ } }{ jj{ }}" format.name$ 't :=
1053 nameptr numnames = t "others" = and
1054 { "et al" * }
1055 { t sortify * }
1056 if$
1057 nameptr #1 + 'nameptr :=
1058 namesleft #1 - 'namesleft :=
1059 }
1060 while$
1061 }
1062
1063 FUNCTION {sort.format.title}
1064 { 't :=
1065 "A " #2
1066 "An " #3
1067 "The " #4 t chop.word
1068 chop.word
1069 chop.word
1070 sortify
1071 #1 global.max$ substring$
1072 }
1073
1074 FUNCTION {author.sort}
1075 { author empty$
1076 { key empty$
1077 { "to sort, need author or key in " cite$ * warning$
1078 ""
1079 }
1080 { key sortify }
1081 if$
1082 }
1083 { author sort.format.names }
1084 if$
1085 }
1086
1087 FUNCTION {author.editor.sort}
1088 { author empty$
1089 { editor empty$
1090 { key empty$
1091 { "to sort, need author, editor, or key in " cite$ * warning$
1092 ""
1093 }
1094 { key sortify }
1095 if$
1096 }
1097 { editor sort.format.names }
1098 if$
1099 }
1100 { author sort.format.names }
1101 if$
1102 }
1103
1104 FUNCTION {author.organization.sort}
1105 { author empty$
1106 { organization empty$
1107 { key empty$
1108 { "to sort, need author, organization, or key in " cite$ * warning$
1109 ""
1110 }
1111 { key sortify }
1112 if$
1113 }
1114 { "The " #4 organization chop.word sortify }
1115 if$
1116 }
1117 { author sort.format.names }
1118 if$
1119 }
1120
1121 FUNCTION {editor.organization.sort}
1122 { editor empty$
1123 { organization empty$
1124 { key empty$
1125 { "to sort, need editor, organization, or key in " cite$ * warning$
1126 ""
1127 }
1128 { key sortify }
1129 if$
1130 }
1131 { "The " #4 organization chop.word sortify }
1132 if$
1133 }
1134 { editor sort.format.names }
1135 if$
1136 }
1137
1138 FUNCTION {presort}
1139 { type$ "book" =
1140 type$ "inbook" =
1141 or
1142 'author.editor.sort
1143 { type$ "proceedings" =
1144 'editor.organization.sort
1145 { type$ "manual" =
1146 'author.organization.sort
1147 'author.sort
1148 if$
1149 }
1150 if$
1151 }
1152 if$
1153 " "
1154 *
1155 year field.or.null sortify
1156 *
1157 " "
1158 *
1159 title field.or.null
1160 sort.format.title
1161 *
1162 #1 entry.max$ substring$
1163 'sort.key$ :=
1164 }
1165
1166 ITERATE {presort}
1167
1168 SORT
1169
1170 STRINGS { longest.label }
1171
1172 INTEGERS { number.label longest.label.width }
1173
1174 FUNCTION {initialize.longest.label}
1175 { "" 'longest.label :=
1176 #1 'number.label :=
1177 #0 'longest.label.width :=
1178 }
1179
1180 FUNCTION {longest.label.pass}
1181 { number.label int.to.str$ 'label :=
1182 number.label #1 + 'number.label :=
1183 label width$ longest.label.width >
1184 { label 'longest.label :=
1185 label width$ 'longest.label.width :=
1186 }
1187 'skip$
1188 if$
1189 }
1190
1191 EXECUTE {initialize.longest.label}
1192
1193 ITERATE {longest.label.pass}
1194
1195 FUNCTION {begin.bib}
1196 { preamble$ empty$
1197 'skip$
1198 { preamble$ write$ newline$ }
1199 if$
1200 "\begin{thebibliography}{" longest.label * "}" * write$ newline$
1201 " \providebibliographyfont{name}{}%" write$ newline$
1202 " \providebibliographyfont{lastname}{}%" write$ newline$
1203 " \providebibliographyfont{title}{\emph}%" write$ newline$
1204 " \providebibliographyfont{etal}{\emph}%" write$ newline$
1205 " \providebibliographyfont{journal}{}%" write$ newline$
1206 " \providebibliographyfont{volume}{}%" write$ newline$
1207 " \providebibliographyfont{ISBN}{\MakeUppercase}%" write$ newline$
1208 " \providebibliographyfont{ISSN}{\MakeUppercase}%" write$ newline$
1209 " \providebibliographyfont{url}{\url}%" write$ newline$
1210 }
1211
1212 EXECUTE {begin.bib}
1213
1214 EXECUTE {init.state.consts}
1215
1216 ITERATE {call.type$}
1217
1218 FUNCTION {end.bib}
1219 { newline$
1220 "\end{thebibliography}" write$ newline$
1221 }
1222
1223 EXECUTE {end.bib}