Debian Codegraph @

texmf-dist/bibtex/bst/beilstein/bjnano.bst

raw
1 %%
2 %% This is file `bjnano.bst',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% beilstein.dtx (with options: `bst')
8 %% ----------------------------------------------------------------
9 %% beilstein -- Support for submissions to the ``Beilstein Journal
10 %% of Nanotechnology'' published by the Beilstein-Institut
11 %% zur Foerderung der Chemischen Wissenschaften
12 %% Version: 2.1
13 %% E-mail: [email protected]
14 %% License: Released under the LaTeX Project Public License v1.3c or later
15 %% See http://www.latex-project.org/lppl.txt
16 %% ----------------------------------------------------------------
17 %%
18 %% bjnano.bst is based on achemso.bst which is part of the achemso
19 %% bundle. Some code cleaning and modifications were done and new
20 %% entry types and fields introduced.
21 ENTRY
22 { address
23 author
24 booktitle
25 chapter
26 ctrl-use-title
27 ctrl-etal-number
28 doi
29 edition
30 editor
31 howpublished
32 institution
33 journal
34 key
35 note
36 number
37 organization
38 pages
39 publisher
40 school
41 series
42 title
43 type
44 url
45 urldate
46 venue
47 version
48 volume
49 year
50 }
51 {}
52 { label
53 extra.label
54 short.list
55 }
56
57 INTEGERS { output.state before.all mid.sentence after.sentence }
58 INTEGERS { after.block after.item author.or.editor }
59 INTEGERS { separate.by.semicolon }
60 INTEGERS { is.use.title etal.number }
61
62 FUNCTION {init.state.consts}
63 { #0 'before.all :=
64 #1 'mid.sentence :=
65 #2 'after.sentence :=
66 #3 'after.block :=
67 #4 'after.item :=
68 }
69
70 %% #0 turns off the display of the title for articles
71 %% #1 enables
72 FUNCTION {default.is.use.title} { #0 }
73
74 %% The number of names that force "et al." to be used
75 FUNCTION {default.etal.number} { #100 }
76
77 FUNCTION {add.comma}
78 { ", " * }
79
80 FUNCTION {add.semicolon}
81 { "; " * }
82
83 FUNCTION {add.comma.or.semicolon}
84 { #1 separate.by.semicolon =
85 'add.semicolon
86 'add.comma
87 if$
88 }
89
90 FUNCTION {add.colon}
91 { ": " * }
92
93 STRINGS { s t }
94
95 FUNCTION {output.nonnull}
96 { 's :=
97 output.state mid.sentence =
98 { add.comma write$ }
99 { output.state after.block =
100 { add.semicolon write$
101 newline$
102 "\newblock " write$
103 }
104 { output.state before.all =
105 'write$
106 { output.state after.item =
107 { " " * write$ }
108 { add.period$ " " * write$ }
109 if$
110 }
111 if$
112 }
113 if$
114 mid.sentence 'output.state :=
115 }
116 if$
117 s
118 }
119
120 FUNCTION {output}
121 { duplicate$ empty$
122 'pop$
123 'output.nonnull
124 if$
125 }
126
127 FUNCTION {output.check}
128 { 't :=
129 duplicate$ empty$
130 { pop$ "Empty " t * " in " * cite$ * warning$ }
131 'output.nonnull
132 if$
133 }
134
135 FUNCTION {new.block}
136 { output.state before.all =
137 'skip$
138 { after.block 'output.state := }
139 if$
140 }
141
142 FUNCTION {new.sentence}
143 { output.state after.block =
144 'skip$
145 { output.state before.all =
146 'skip$
147 { after.sentence 'output.state := }
148 if$
149 }
150 if$
151 }
152
153 FUNCTION {fin.entry}
154 { add.period$
155 write$
156 ""
157 newline$
158 note missing$
159 'skip$
160 {" " write$ note write$ }
161 if$
162 write$ newline$
163 }
164
165 FUNCTION {not}
166 { { #0 }
167 { #1 }
168 if$
169 }
170
171 FUNCTION {and}
172 { 'skip$
173 { pop$ #0 }
174 if$
175 }
176
177 FUNCTION {or}
178 { { pop$ #1 }
179 'skip$
180 if$
181 }
182
183 FUNCTION {field.or.null}
184 { duplicate$ empty$
185 { pop$ "" }
186 'skip$
187 if$
188 }
189
190 FUNCTION {emphasize}
191 { duplicate$ empty$
192 { pop$ "" }
193 { "\emph{" swap$ * "}" * }
194 if$
195 }
196
197 FUNCTION {boldface}
198 { duplicate$ empty$
199 { pop$ "" }
200 { "\textbf{" swap$ * "}" * }
201 if$
202 }
203
204 FUNCTION {paren}
205 { duplicate$ empty$
206 { pop$ "" }
207 { "(" swap$ * ")" * }
208 if$
209 }
210
211 FUNCTION {bbl.and}
212 { "and" }
213
214 FUNCTION {bbl.chapter}
215 { "Chapter" }
216
217 FUNCTION {bbl.editor}
218 { "Ed." }
219
220 FUNCTION {bbl.editors}
221 { "Eds." }
222
223 FUNCTION {bbl.edition}
224 { "ed." }
225
226 FUNCTION {bbl.etal}
227 { "et~al." }
228
229 FUNCTION {bbl.in}
230 { "In" }
231
232 FUNCTION {bbl.inpress}
233 { "in press" }
234
235 FUNCTION {bbl.page}
236 { "p" }
237
238 FUNCTION {bbl.pages}
239 { "pp" }
240
241 FUNCTION {bbl.phd}
242 { "Ph.\,D.\ Thesis" }
243
244 FUNCTION {bbl.submitted}
245 { "submitted for publication" }
246
247 FUNCTION {bbl.volume}
248 { "Vol." }
249
250 FUNCTION {bbl.first}
251 { "1st" }
252
253 FUNCTION {bbl.second}
254 { "2nd" }
255
256 FUNCTION {bbl.third}
257 { "3rd" }
258
259 FUNCTION {bbl.fourth}
260 { "4th" }
261
262 FUNCTION {bbl.fifth}
263 { "5th" }
264
265 FUNCTION {bbl.st}
266 { "st" }
267
268 FUNCTION {bbl.nd}
269 { "nd" }
270
271 FUNCTION {bbl.rd}
272 { "rd" }
273
274 FUNCTION {bbl.th}
275 { "th" }
276
277 FUNCTION {eng.ord}
278 { duplicate$ "1" swap$ *
279 #-2 #1 substring$ "1" =
280 { bbl.th * }
281 { duplicate$ #-1 #1 substring$
282 duplicate$ "1" =
283 { pop$ bbl.st * }
284 { duplicate$ "2" =
285 { pop$ bbl.nd * }
286 { "3" =
287 { bbl.rd * }
288 { bbl.th * }
289 if$
290 }
291 if$
292 }
293 if$
294 }
295 if$
296 }
297
298 FUNCTION {is.a.digit}
299 { duplicate$ "" =
300 {pop$ #0}
301 {chr.to.int$ #48 - duplicate$
302 #0 < swap$ #9 > or not}
303 if$
304 }
305
306 FUNCTION {is.a.number}
307 {
308 { duplicate$ #1 #1 substring$ is.a.digit }
309 {#2 global.max$ substring$}
310 while$
311 "" =
312 }
313
314 FUNCTION {extract.num}
315 { duplicate$ 't :=
316 "" 's :=
317 { t empty$ not }
318 { t #1 #1 substring$
319 t #2 global.max$ substring$ 't :=
320 duplicate$ is.a.number
321 { s swap$ * 's := }
322 { pop$ "" 't := }
323 if$
324 }
325 while$
326 s empty$
327 'skip$
328 { pop$ s }
329 if$
330 }
331
332 FUNCTION {chr.to.value}
333 { chr.to.int$ #48 -
334 duplicate$ duplicate$
335 #0 < swap$ #9 > or
336 { #48 + int.to.chr$
337 " is not a number..." *
338 warning$
339 pop$ #0
340 }
341 {}
342 if$
343 }
344
345 %% Some tricks from "Tame the BeaST" to convert a string
346 %% to a number
347 INTEGERS { a b }
348
349 FUNCTION {mult}
350 { 'a :=
351 'b :=
352 b #0 <
353 {#-1 #0 b - 'b :=}
354 {#1}
355 if$
356 #0
357 {b #0 >}
358 { a +
359 b #1 - 'b :=
360 }
361 while$
362 swap$
363 'skip$
364 {#0 swap$ -}
365 if$
366 }
367
368 FUNCTION {str.to.int.aux}
369 { {duplicate$ empty$ not}
370 { swap$ #10 mult 'a :=
371 duplicate$ #1 #1 substring$
372 chr.to.value a +
373 swap$
374 #2 global.max$ substring$
375 }
376 while$
377 pop$
378 }
379
380 FUNCTION {str.to.int}
381 { duplicate$ #1 #1 substring$ "-" =
382 {#1 swap$ #2 global.max$ substring$}
383 {#0 swap$}
384 if$
385 #0 swap$ str.to.int.aux
386 swap$
387 {#0 swap$ -}
388 {}
389 if$
390 }
391
392 FUNCTION {bibinfo.check}
393 { swap$
394 duplicate$ missing$
395 { pop$ pop$
396 ""
397 }
398 { duplicate$ empty$
399 {
400 swap$ pop$
401 }
402 { swap$
403 pop$
404 }
405 if$
406 }
407 if$
408 }
409
410 FUNCTION {convert.edition}
411 { extract.num "l" change.case$ 's :=
412 s "first" = s "1" = or
413 { bbl.first 't := }
414 { s "second" = s "2" = or
415 { bbl.second 't := }
416 { s "third" = s "3" = or
417 { bbl.third 't := }
418 { s "fourth" = s "4" = or
419 { bbl.fourth 't := }
420 { s "fifth" = s "5" = or
421 { bbl.fifth 't := }
422 { s #1 #1 substring$ is.a.number
423 { s eng.ord 't := }
424 { edition 't := }
425 if$
426 }
427 if$
428 }
429 if$
430 }
431 if$
432 }
433 if$
434 }
435 if$
436 t
437 }
438
439 FUNCTION {tie.or.space.connect}
440 { duplicate$ text.length$ #3 <
441 { "~" }
442 { " " }
443 if$
444 swap$ * *
445 }
446
447 FUNCTION {space.connect}
448 { " " swap$ * * }
449
450 INTEGERS { nameptr namesleft numnames }
451
452 FUNCTION {format.names}
453 { 's :=
454 #1 'nameptr :=
455 s num.names$ 'numnames :=
456 numnames 'namesleft :=
457 numnames etal.number > etal.number #0 > and
458 { s #1 "{vv~}{ll,}{~f.}{,~jj}" format.name$ 't :=
459 t bbl.etal space.connect
460 }
461 {
462 { namesleft #0 > }
463 { s nameptr "{vv~}{ll,}{~f.}{,~jj}" format.name$ 't :=
464 nameptr #1 >
465 { namesleft #1 >
466 { add.comma.or.semicolon t * }
467 { numnames #2 >
468 { "" * }
469 'skip$
470 if$
471 t "others," =
472 { bbl.etal space.connect }
473 { add.comma.or.semicolon t * }
474 if$
475 }
476 if$
477 }
478 't
479 if$
480 nameptr #1 + 'nameptr :=
481 namesleft #1 - 'namesleft :=
482 }
483 while$
484 }
485 if$
486 }
487
488 FUNCTION {format.authors}
489 { author empty$
490 { "" }
491 { #1 'author.or.editor :=
492 #1 'separate.by.semicolon :=
493 author format.names
494 }
495 if$
496 }
497
498 FUNCTION {format.editors}
499 { editor empty$
500 { "" }
501 { #2 'author.or.editor :=
502 #0 'separate.by.semicolon :=
503 editor format.names
504 add.comma
505 editor num.names$ #1 >
506 { bbl.editors }
507 { bbl.editor }
508 if$
509 *
510 }
511 if$
512 }
513
514 FUNCTION {n.separate.multi}
515 { 't :=
516 ""
517 #0 'numnames :=
518 t text.length$ #4 > t is.a.number and
519 {
520 { t empty$ not }
521 { t #-1 #1 substring$ is.a.number
522 { numnames #1 + 'numnames := }
523 { #0 'numnames := }
524 if$
525 t #-1 #1 substring$ swap$ *
526 t #-2 global.max$ substring$ 't :=
527 numnames #4 =
528 { duplicate$ #1 #1 substring$ swap$
529 #2 global.max$ substring$
530 "," swap$ * *
531 #1 'numnames :=
532 }
533 'skip$
534 if$
535 }
536 while$
537 }
538 { t swap$ * }
539 if$
540 }
541
542 FUNCTION {format.bvolume}
543 { volume empty$
544 { "" }
545 { bbl.volume volume tie.or.space.connect }
546 if$
547 }
548
549 FUNCTION {format.title.noemph}
550 { 't :=
551 t empty$
552 { "" }
553 { t }
554 if$
555 }
556
557 FUNCTION {format.title}
558 { 't :=
559 t empty$
560 { "" }
561 { t emphasize }
562 if$
563 }
564
565 %% The add.title function only does anything if the appropriate
566 %% flag is set.
567 FUNCTION {add.title}
568 { is.use.title
569 { title format.title.noemph "title" output.check
570 new.sentence }
571 'skip$
572 if$
573 }
574
575 FUNCTION {format.number.series}
576 { volume empty$
577 { number empty$
578 { series field.or.null }
579 { series empty$
580 { "There is a number but no series in " cite$ * warning$ }
581 { series number space.connect }
582 if$
583 }
584 if$
585 }
586 { "" }
587 if$
588 }
589
590 FUNCTION {format.url}
591 { url empty$
592 { "There is no url in " cite$ * warning$ }
593 { new.sentence "\url{" url * "}" * }
594 if$
595 }
596
597 FUNCTION {format.urldate}
598 { urldate empty$
599 { "There is no urldate in " cite$ * warning$ }
600 { "accessed " urldate * paren space.connect }
601 if$
602 }
603
604 FUNCTION {format.full.names}
605 {'s :=
606 #1 'nameptr :=
607 s num.names$ 'numnames :=
608 numnames 'namesleft :=
609 { namesleft #0 > }
610 { s nameptr
611 "{vv~}{ll}" format.name$ 't :=
612 nameptr #1 >
613 {
614 namesleft #1 >
615 { ", " * t * }
616 {
617 numnames #2 >
618 { "," * }
619 'skip$
620 if$
621 t "others" =
622 { bbl.etal * }
623 { bbl.and space.connect t space.connect }
624 if$
625 }
626 if$
627 }
628 't
629 if$
630 nameptr #1 + 'nameptr :=
631 namesleft #1 - 'namesleft :=
632 }
633 while$
634 }
635
636 FUNCTION {author.editor.full}
637 { author empty$
638 { editor empty$
639 { "" }
640 { editor format.full.names }
641 if$
642 }
643 { author format.full.names }
644 if$
645 }
646
647 FUNCTION {author.full}
648 { author empty$
649 { "" }
650 { author format.full.names }
651 if$
652 }
653
654 FUNCTION {editor.full}
655 { editor empty$
656 { "" }
657 { editor format.full.names }
658 if$
659 }
660
661 FUNCTION {make.full.names}
662 { type$ "book" =
663 type$ "inbook" =
664 or
665 'author.editor.full
666 { type$ "proceedings" =
667 'editor.full
668 'author.full
669 if$
670 }
671 if$
672 }
673
674 FUNCTION {output.bibitem}
675 { newline$
676 "\setboolean{nobreakdashused}{false}" write$
677 "\bibitem[" write$
678 label write$
679 ")" make.full.names duplicate$ short.list =
680 { pop$ }
681 { * }
682 if$
683 "]{" * write$
684 cite$ write$
685 "}" write$
686 newline$
687 ""
688 before.all 'output.state :=
689 }
690
691 FUNCTION {n.dashify}
692 { 't :=
693 ""
694 { t empty$ not }
695 { t #1 #1 substring$ "-" =
696 { t #1 #2 substring$ "--" = not
697 { "\mynobreakdash " *
698 t #2 global.max$ substring$ 't :=
699 }
700 { { t #1 #1 substring$ "-" = }
701 { "\mynobreakdash " *
702 t #2 global.max$ substring$ 't :=
703 }
704 while$
705 }
706 if$
707 }
708 { t #1 #1 substring$ *
709 t #2 global.max$ substring$ 't :=
710 }
711 if$
712 }
713 while$
714 }
715
716 FUNCTION {format.date}
717 { year empty$
718 { "" }
719 { year boldface }
720 if$
721 }
722
723 FUNCTION {format.bdate}
724 { year empty$
725 { "There's no year in " cite$ * warning$ }
726 'year
727 if$
728 }
729
730 FUNCTION {either.or.check}
731 { empty$
732 'pop$
733 { "Can't use both " swap$ * " fields in " * cite$ * warning$ }
734 if$
735 }
736
737 FUNCTION {format.edition}
738 { edition duplicate$ empty$
739 'skip$
740 { convert.edition
741 bbl.edition bibinfo.check
742 " " * bbl.edition *
743 }
744 if$
745 }
746
747 INTEGERS { multiresult }
748
749 FUNCTION {multi.page.check}
750 { 't :=
751 #0 'multiresult :=
752 { multiresult not
753 t empty$ not
754 and
755 }
756 { t #1 #1 substring$
757 duplicate$ "-" =
758 swap$ duplicate$ "," =
759 swap$ "+" =
760 or or
761 { #1 'multiresult := }
762 { t #2 global.max$ substring$ 't := }
763 if$
764 }
765 while$
766 multiresult
767 }
768
769 FUNCTION {format.pages}
770 { pages empty$
771 { "" }
772 { pages multi.page.check
773 { bbl.pages pages n.dashify tie.or.space.connect }
774 { bbl.page pages tie.or.space.connect }
775 if$
776 }
777 if$
778 }
779
780 FUNCTION {format.pages.required}
781 { pages empty$
782 { ""
783 "There are no page numbers for " cite$ * warning$
784 output
785 }
786 { pages multi.page.check
787 { bbl.pages pages n.dashify tie.or.space.connect }
788 { bbl.page pages tie.or.space.connect }
789 if$
790 }
791 if$
792 }
793
794 FUNCTION {format.pages.nopp}
795 { pages empty$
796 { ""
797 "There are no page numbers for " cite$ * warning$
798 output
799 }
800 { pages multi.page.check
801 { pages n.dashify space.connect }
802 { pages space.connect }
803 if$
804 }
805 if$
806 }
807
808 FUNCTION {format.pages.patent}
809 { pages empty$
810 { "There is no patent number for " cite$ * warning$ }
811 { pages multi.page.check
812 { pages n.dashify }
813 { pages n.separate.multi }
814 if$
815 }
816 if$
817 }
818
819 FUNCTION {format.vol.pages}
820 { volume emphasize field.or.null
821 number empty$
822 'skip$
823 { number paren tie.or.space.connect }
824 if$
825 duplicate$ empty$
826 { pop$ format.pages.required }
827 { add.comma pages n.dashify * }
828 if$
829 }
830
831 FUNCTION {format.chapter.pages}
832 { chapter empty$
833 'format.pages
834 { type empty$
835 { bbl.chapter }
836 { type "l" change.case$ }
837 if$
838 chapter tie.or.space.connect
839 pages empty$
840 'skip$
841 { add.comma format.pages * }
842 if$
843 }
844 if$
845 }
846
847 FUNCTION {format.title.in}
848 { 's :=
849 s empty$
850 { "" }
851 { editor empty$
852 { bbl.in s format.title space.connect }
853 { bbl.in s format.title space.connect
854 add.semicolon format.editors *
855 }
856 if$
857 }
858 if$
859 }
860
861 FUNCTION {format.proc.title.in}
862 { 's :=
863 s empty$
864 { "" }
865 { editor empty$
866 { bbl.in s format.title space.connect }
867 { venue empty$
868 { bbl.in s format.title space.connect
869 add.semicolon format.editors * }
870 { bbl.in s format.title space.connect
871 add.comma venue *
872 add.semicolon format.editors * }
873 if$
874 }
875 if$
876 }
877 if$
878 }
879
880 FUNCTION {format.pub.address}
881 { publisher empty$
882 { "" }
883 { address empty$
884 { publisher }
885 { publisher add.colon address *}
886 if$
887 }
888 if$
889 }
890
891 FUNCTION {format.school.address}
892 { school empty$
893 { "" }
894 { address empty$
895 { school }
896 { school add.colon address *}
897 if$
898 }
899 if$
900 }
901
902 FUNCTION {format.organization.address}
903 { organization empty$
904 { "" }
905 { address empty$
906 { organization }
907 { organization add.colon address *}
908 if$
909 }
910 if$
911 }
912
913 FUNCTION {format.venue}
914 { venue empty$
915 { "" }
916 { venue add.semicolon}
917 if$
918 }
919
920 FUNCTION {empty.misc.check}
921 { note empty$
922 { "note field is empty in " cite$ * warning$ }
923 'skip$
924 if$
925 }
926
927 FUNCTION {empty.doi.note}
928 { doi empty$ note empty$ and
929 { "Need either a note or DOI for " cite$ * warning$ }
930 'skip$
931 if$
932 }
933
934 FUNCTION {format.thesis.type}
935 { type empty$
936 'skip$
937 { pop$
938 type
939 }
940 if$
941 }
942
943 FUNCTION {format.doi}
944 { doi empty$
945 { " "} % 'skip$
946 { new.sentence "\url{doi:" doi tie.or.space.connect "}" * }
947 if$
948 }
949
950 FUNCTION {article}
951 { output.bibitem
952 author empty$
953 { format.editors "editor" output.check
954 after.item 'output.state :=
955 title empty$
956 'skip$
957 { title format.title.noemph output
958 after.sentence 'output.state :=
959 }
960 if$
961 journal emphasize "journal" output.check
962 }
963 { format.authors "author" output.check
964 after.item 'output.state :=
965 add.title
966 journal emphasize "journal" output.check
967 }
968 if$
969 after.item 'output.state :=
970 format.date "year" output.check
971 volume empty$
972 { number empty$
973 { "There is neither volume nor number given for " cite$ * warning$ }
974 { "No. " number * output}
975 if$
976 ""
977 format.pages.nopp output
978 }
979 { format.vol.pages output }
980 if$
981 format.doi output
982 fin.entry
983 }
984
985 FUNCTION {book}
986 { output.bibitem
987 author empty$
988 { booktitle empty$
989 { title format.title "title" output.check }
990 { booktitle format.title "booktitle" output.check }
991 if$
992 format.edition output
993 new.block
994 editor empty$
995 { "Need either an author or editor for " cite$ * warning$ }
996 { "" format.editors * "editor" output.check }
997 if$
998 }
999 { format.authors output
1000 after.item 'output.state :=
1001 "author and editor" editor either.or.check
1002 booktitle empty$
1003 { title format.title "title" output.check }
1004 { booktitle format.title "booktitle" output.check }
1005 if$
1006 format.edition output
1007 }
1008 if$
1009 new.block
1010 format.number.series output
1011 new.block
1012 format.pub.address "publisher" output.check
1013 format.bdate "year" output.check
1014 new.block
1015 format.bvolume output
1016 pages empty$
1017 'skip$
1018 { format.pages output }
1019 if$
1020 format.doi output
1021 fin.entry
1022 }
1023
1024 FUNCTION {booklet}
1025 { "Entrytype booklet of " cite$ " is not supported." * * warning$ }
1026
1027 FUNCTION {inbook}
1028 { output.bibitem
1029 author empty$
1030 { booktitle format.title "booktitle" output.check
1031 format.edition output
1032 new.block
1033 editor empty$
1034 { "Need at least an author or an editor for " cite$ * warning$ }
1035 { "" format.editors * "editor" output.check }
1036 if$
1037 }
1038 { format.authors output
1039 after.item 'output.state :=
1040 title empty$
1041 'skip$
1042 { title format.title.noemph output }
1043 if$
1044 after.sentence 'output.state :=
1045 booktitle format.title.in "booktitle" output.check
1046 format.edition output
1047 }
1048 if$
1049 new.block
1050 format.number.series output
1051 new.block
1052 format.pub.address "publisher" output.check
1053 format.bdate "year" output.check
1054 new.block
1055 format.bvolume output
1056 format.chapter.pages "chapter and pages" output.check
1057 fin.entry
1058 }
1059
1060 FUNCTION {incollection}
1061 { output.bibitem
1062 author empty$
1063 { booktitle format.title "booktitle" output.check
1064 format.edition output
1065 new.block
1066 editor empty$
1067 { "Need at least an author or an editor for " cite$ * warning$ }
1068 { "" format.editors * "editor" output.check }
1069 if$
1070 }
1071 { format.authors output
1072 after.item 'output.state :=
1073 title empty$
1074 'skip$
1075 { title format.title.noemph output }
1076 if$
1077 after.sentence 'output.state :=
1078 booktitle format.title.in "booktitle" output.check
1079 format.edition output
1080 }
1081 if$
1082 new.block
1083 format.number.series output
1084 new.block
1085 format.pub.address "publisher" output.check
1086 format.bdate "year" output.check
1087 new.block
1088 format.bvolume output
1089 format.chapter.pages "chapter and pages" output.check
1090 format.doi output
1091 fin.entry
1092 }
1093
1094 FUNCTION {inpress}
1095 { output.bibitem
1096 format.authors "author" output.check
1097 after.item 'output.state :=
1098 journal emphasize "journal" output.check
1099 doi empty$
1100 { bbl.inpress output }
1101 { after.item 'output.state :=
1102 format.date output
1103 "doi:" doi tie.or.space.connect output
1104 }
1105 if$
1106 format.doi output
1107 fin.entry
1108 }
1109
1110 FUNCTION {inproceedings}
1111 { output.bibitem
1112 format.authors "author" output.check
1113 after.item 'output.state :=
1114 title empty$
1115 'skip$
1116 { title format.title.noemph output
1117 after.sentence 'output.state :=
1118 }
1119 if$
1120 booktitle format.proc.title.in "booktitle" output.check
1121 new.block
1122 format.pub.address "publisher" output.check
1123 format.bdate "year" output.check
1124 pages empty$
1125 'skip$
1126 { new.block
1127 format.pages output }
1128 if$
1129 format.doi output
1130 fin.entry
1131 }
1132
1133 FUNCTION {manual}
1134 { "Entrytype manual of " cite$ " is not supported." * * warning$ }
1135
1136 FUNCTION {mastersthesis}
1137 { "Entrytype masterthesis of " cite$ " is not supported." * * warning$ }
1138
1139 FUNCTION {misc}
1140 { output.bibitem
1141 fin.entry
1142 }
1143
1144 FUNCTION {online}
1145 { output.bibitem
1146 format.authors output
1147 after.item 'output.state :=
1148 title empty$
1149 'skip$
1150 { title output }
1151 if$
1152 format.url output
1153 after.item 'output.state :=
1154 format.urldate output
1155 format.doi output
1156 fin.entry
1157 }
1158
1159 FUNCTION {patent}
1160 { output.bibitem
1161 format.authors "author" output.check
1162 after.item 'output.state :=
1163 title empty$
1164 'skip$
1165 { title format.title.noemph output
1166 after.sentence 'output.state :=
1167 }
1168 if$
1169 journal "journal" output.check
1170 after.item 'output.state :=
1171 format.pages.patent "pages" output.check
1172 format.bdate "year" output.check
1173 format.doi output
1174 fin.entry
1175 }
1176
1177 FUNCTION {phdthesis}
1178 { output.bibitem
1179 format.authors "author" output.check
1180 after.item 'output.state :=
1181 title empty$
1182 'skip$
1183 { title format.title.noemph output
1184 after.sentence 'output.state :=
1185 }
1186 if$
1187 bbl.phd format.thesis.type output
1188 format.school.address "school" output.check
1189 format.bdate "year" output.check
1190 format.doi output
1191 fin.entry
1192 }
1193
1194 FUNCTION {proceedings}
1195 { output.bibitem
1196 format.editors "editor" output.check
1197 after.item 'output.state :=
1198 title format.title "title" output.check
1199 venue empty$
1200 { }
1201 { venue output
1202 add.semicolon write$ }
1203 if$
1204 format.pub.address "publisher" output.check
1205 format.bdate "year" output.check
1206 pages empty$
1207 'skip$
1208 { new.block
1209 format.pages output }
1210 if$
1211 format.doi output
1212 fin.entry
1213 }
1214
1215 FUNCTION {software}
1216 { output.bibitem
1217 title format.title "title" output.check
1218 version empty$
1219 'skip$
1220 { version output }
1221 if$
1222 after.block 'output.state :=
1223 format.pub.address "publisher" output.check
1224 format.bdate "year" output.check
1225 format.doi output
1226 fin.entry
1227 }
1228
1229 FUNCTION {techreport}
1230 { "Entrytype techreport of " cite$ " is not supported." * * warning$ }
1231
1232 FUNCTION {unpublished}
1233 { "Entrytype unpublished of " cite$ " is not supported." * * warning$ }
1234
1235 FUNCTION {www}
1236 { output.bibitem
1237 format.authors output
1238 after.item 'output.state :=
1239 title empty$
1240 'skip$
1241 { title output }
1242 if$
1243 format.url output
1244 after.item 'output.state :=
1245 format.urldate output
1246 format.doi output
1247 fin.entry
1248 }
1249
1250 %% Convert the strings "yes" or "no" to #1 or #0 respectively
1251 FUNCTION {yes.no.to.int}
1252 { "l" change.case$ duplicate$
1253 "yes" =
1254 { pop$ #1 }
1255 { duplicate$ "no" =
1256 { pop$ #0 }
1257 { "unknown Boolean " quote$ * swap$ * quote$ *
1258 " in " * cite$ * warning$
1259 #0
1260 }
1261 if$
1262 }
1263 if$
1264 }
1265
1266 %% Using the same mechanism as in IEEEtrans, control of
1267 %% output can be achieved using a special entry type.
1268 FUNCTION {Control}
1269 { ctrl-use-title
1270 empty$
1271 { }
1272 { ctrl-use-title
1273 yes.no.to.int
1274 'is.use.title := }
1275 if$
1276 ctrl-etal-number
1277 empty$
1278 { }
1279 { ctrl-etal-number
1280 str.to.int
1281 'etal.number := }
1282 if$
1283 }
1284
1285 FUNCTION {conference} {inproceedings}
1286
1287 FUNCTION {other} {patent}
1288
1289 FUNCTION {default.type} {misc}
1290
1291 READ
1292
1293 FUNCTION {initialize.controls}
1294 { default.is.use.title 'is.use.title :=
1295 default.etal.number 'etal.number :=
1296 }
1297
1298 EXECUTE {initialize.controls}
1299
1300 INTEGERS { len }
1301
1302 FUNCTION {chop.word}
1303 { 's :=
1304 'len :=
1305 s #1 len substring$ =
1306 { s len #1 + global.max$ substring$ }
1307 's
1308 if$
1309 }
1310
1311 FUNCTION {format.lab.names}
1312 { 's :=
1313 s #1 "{vv~}{ll}" format.name$
1314 s num.names$ duplicate$
1315 #2 >
1316 { pop$ bbl.etal space.connect }
1317 { #2 <
1318 'skip$
1319 { s #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
1320 { bbl.etal space.connect }
1321 { bbl.and space.connect s #2 "{vv~}{ll}" format.name$ space.connect
1322 }
1323 if$
1324 }
1325 if$
1326 }
1327 if$
1328 }
1329
1330 FUNCTION {author.key.label}
1331 { author empty$
1332 { key empty$
1333 { cite$ #1 #3 substring$ }
1334 'key
1335 if$
1336 }
1337 { author format.lab.names }
1338 if$
1339 }
1340
1341 FUNCTION {author.editor.key.label}
1342 { author empty$
1343 { editor empty$
1344 { key empty$
1345 { cite$ #1 #3 substring$ }
1346 'key
1347 if$
1348 }
1349 { editor format.lab.names }
1350 if$
1351 }
1352 { author format.lab.names }
1353 if$
1354 }
1355
1356 FUNCTION {author.key.organization.label}
1357 { author empty$
1358 { key empty$
1359 { organization empty$
1360 { cite$ #1 #3 substring$ }
1361 { "The " #4 organization chop.word #3 text.prefix$ }
1362 if$
1363 }
1364 'key
1365 if$
1366 }
1367 { author format.lab.names }
1368 if$
1369 }
1370
1371 FUNCTION {editor.key.organization.label}
1372 { editor empty$
1373 { key empty$
1374 { organization empty$
1375 { cite$ #1 #3 substring$ }
1376 { "The " #4 organization chop.word #3 text.prefix$ }
1377 if$
1378 }
1379 'key
1380 if$
1381 }
1382 { editor format.lab.names }
1383 if$
1384 }
1385
1386 FUNCTION {calc.short.authors}
1387 { type$ "book" =
1388 type$ "inbook" =
1389 or
1390 'author.editor.key.label
1391 { type$ "proceedings" =
1392 'editor.key.organization.label
1393 { type$ "manual" =
1394 'author.key.organization.label
1395 'author.key.label
1396 if$
1397 }
1398 if$
1399 }
1400 if$
1401 'short.list :=
1402 }
1403
1404 FUNCTION {calc.label}
1405 { calc.short.authors
1406 short.list
1407 "("
1408 *
1409 year duplicate$ empty$
1410 short.list key field.or.null = or
1411 { pop$ "" }
1412 'skip$
1413 if$
1414 *
1415 'label :=
1416 }
1417
1418 ITERATE {calc.label}
1419
1420 STRINGS { longest.label last.label next.extra }
1421
1422 INTEGERS { longest.label.width last.extra.num number.label }
1423
1424 FUNCTION {initialize.longest.label}
1425 { "" 'longest.label :=
1426 #0 int.to.chr$ 'last.label :=
1427 "" 'next.extra :=
1428 #0 'longest.label.width :=
1429 #0 'last.extra.num :=
1430 #0 'number.label :=
1431 }
1432
1433 FUNCTION {forward.pass}
1434 { last.label label =
1435 { last.extra.num #1 + 'last.extra.num :=
1436 last.extra.num int.to.chr$ 'extra.label :=
1437 }
1438 { "a" chr.to.int$ 'last.extra.num :=
1439 "" 'extra.label :=
1440 label 'last.label :=
1441 }
1442 if$
1443 number.label #1 + 'number.label :=
1444 }
1445
1446 EXECUTE {initialize.longest.label}
1447
1448 ITERATE {forward.pass}
1449
1450 FUNCTION {begin.bib}
1451 { preamble$ empty$
1452 'skip$
1453 { preamble$ write$ newline$ }
1454 if$
1455 "\begin{thebibliography}{" number.label int.to.str$ * "}" *
1456 write$ newline$
1457 }
1458
1459 EXECUTE {begin.bib}
1460
1461 EXECUTE {init.state.consts}
1462
1463 ITERATE {call.type$}
1464
1465 FUNCTION {end.bib}
1466 { newline$
1467 "\end{thebibliography}" write$ newline$
1468 }
1469
1470 EXECUTE {end.bib}
1471 %%
1472 %% Originally developed by Martin Sievers ([email protected])
1473 %% Copyright (C) 2009-2020 by Beilstein-Institut zur Foerderung der Chemischen Wissenschaften (Beilstein)
1474 %%
1475 %% Part of this bundle is derived from cite.sty, to which the
1476 %% following license applies:
1477 %% Copyright (C) 1989-2003 by Donald Arseneau
1478 %% These macros may be freely transmitted, reproduced, or
1479 %% modified provided that this notice is left intact.
1480 %%
1481 %% It may be distributed and/or modified under the conditions of
1482 %% the LaTeX Project Public License (LPPL), either version 1.3c of
1483 %% this license or (at your option) any later version. The latest
1484 %% version of this license is in the file:
1485 %%
1486 %% http://www.latex-project.org/lppl.txt
1487 %%
1488 %% This work has the LPPL maintenancce status "author-maintained".
1489 %%
1490 %% This work consists of the files beilstein.dtx,
1491 %% CHANGELOG.md,
1492 %% README.md
1493 %% and the derived files beilstein.pdf,
1494 %% beilstein.cls,
1495 %% beilstein.ins,
1496 %% bjnano.bst,
1497 %% beilstein-template.tex,
1498 %% beilstein-template.bib.
1499 %% Some graphic files for the documentation and template are also added:
1500 %% bjnano_logo.pdf
1501 %% scheme1.pdf
1502 %% scheme2.pdf
1503 %% figure1.pdf
1504 %%
1505 %% End of file `bjnano.bst'.