Debian Codegraph @

texmf-dist/doc/metapost/featpost/example/keplernewtonfeynman.mp

raw
1 % keplernewtonfeynman.mp
2 % L. Nobre G.
3 % 2014
4
5 %input featpost3Dplus2D;
6
7 prologues := 0;
8
9 %verbatimtex \documentclass{article}\usepackage{mathpazo}\begin{document} etex
10
11 ahangle := 30;
12
13 beginfig(1);
14 numeric u, abratio, foc, pang, auxang, refdist, stepang, factor, thang;
15 pair secofod, ocirpoi, midpoi, tpoi, dirplu, dirmin;
16 pen poipen;
17 color mygrey;
18 path thecircle;
19 thang = -45;
20 stepang = 4;
21 poipen = pencircle scaled 1mm;
22 mygrey = 0.5*(red+green);
23 u = 1cm;
24 %abratio = 0.5*(1+sqrt(5));
25 abratio = 1.2;
26 foc = u*(abratio +-+ 1);
27 refdist = 2*u*abratio;
28 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
29 factor = 1.02;
30 secofod := 2*foc*dir(thang);
31 thecircle = fullcircle scaled 2refdist;
32 pickup pencircle scaled 0;
33 %draw fullcircle scaled 2u xscaled abratio shifted (foc,0);
34 %draw thecircle;
35 draw secofod withpen poipen withcolor blue;
36 for pang = stepang step stepang until 360:
37 ocirpoi := refdist*dir(pang);
38 midpoi := 0.5[secofod,ocirpoi];
39 auxang := angle(ocirpoi-secofod);
40 dirplu := dir(auxang+90);
41 dirmin := dir(auxang-90);
42 pair tpoi;
43 tpoi = whatever*dir(pang);
44 tpoi = whatever[midpoi,midpoi+dirplu];
45 %draw ocirpoi--secofod withcolor mygrey;
46 %draw tpoi withpen poipen withcolor red;
47 drawarrow tpoi--(tpoi+abs(midpoi-secofod)*dirplu/factor);
48 endfor;
49 clip currentpicture to (thecircle scaled (factor**2));
50 draw origin withpen poipen withcolor green;
51 endfig;
52
53 verbatimtex \end{document} etex
54
55 end.
56
57 Newton showed this construction in Book 1, Section 4, Lemma 15, of
58 Principia. On March 13, 1964, Feynman resurrected the construction and
59 used it in a lecture, "The Motion of Planets Around the Sun". The
60 lecture is detailed in a book with audio CD, Feynman's Lost Lecture,
61 by David and Judith Goodstein. In the lecture, Feynman used the
62 diagram and differential geometry to prove the planetary laws of
63 motion.
64 In the construction, the green dot is the primary focus of the ellipse
65 about which the planet orbits; the blue dot is the secondary
66 focus. The black dot is on a circle at a distance in radius equal in
67 length to the major axis of an ellipse. A line is drawn from the blue
68 dot to the black dot and its perpendicular bisector is
69 constructed. The point where this perpendicular bisector intersects
70 the line from the green dot (primary focus) to the black dot (circle)
71 is a point on the ellipse. The perpendicular bisector is tangent to
72 the ellipse at this point. A further interesting point of the
73 construction is that the length of the line from the blue dot
74 (secondary focus) to the black dot (circle) is proportional to the
75 velocity of the orbiting planet at this point. In the Demonstration,
76 half this length is represented by the black vector traveling in the
77 direction of the planet.
78 All of the possible ellipses with the given major axis are contained
79 in the circle. You can adjust the eccentricity and rotation of the
80 ellipse.