Debian Codegraph @

testsuite/systemtap.examples/general/socket-events.stp

raw
1 #! /usr/bin/env stap
2
3 global socketstart, lastevent, sendtofd
4 global eventnumber, eventname, eventstart, eventend, eventbytes, eventlength
5 global writestart, readstart, sendstart, recvstart
6
7 probe begin {
8 if (target() == 0) {
9 println("No PID specified. Use -c or -x. See man stap for more information.")
10 exit()
11 }
12 }
13
14 function printshorthistory (fd:long) {
15 if (eventnumber[fd] < 1 || eventnumber[fd] % 2 && eventnumber[fd] != 1)
16 return
17 wait1 = eventstart[fd, eventnumber[fd] - 1] - eventend[fd, eventnumber[fd] - 2]
18 wait2 = eventstart[fd, eventnumber[fd]] - eventend[fd, eventnumber[fd] - 1]
19 name1 = eventname[fd, eventnumber[fd] - 1]
20 name2 = eventname[fd, eventnumber[fd]]
21 length1 = eventlength[fd, eventnumber[fd] - 1]
22 length2 = eventlength[fd, eventnumber[fd]]
23 bytes1 = eventbytes[fd, eventnumber[fd] -1]
24 bytes2 = eventbytes[fd, eventnumber[fd]]
25 if (eventnumber[fd] == 1)
26 printf("Socket %d connect, wait %d us, %s %d bytes in %d us\n", fd, wait2, name2, bytes2, length2)
27 else {
28 printf("Socket %d wait %d us, ", fd, wait1)
29 printf("%s %d bytes in %d us, wait %d us, ", name1, bytes1, length1, wait2)
30 printf("%s %d bytes in %d us\n", name2, bytes2, length2)
31 }
32 }
33
34 probe syscall.socket.return {
35 if (!target_set_pid(pid()))
36 next
37 eventnumber[retval] = 0
38 socketstart[retval] = gettimeofday_us()
39 eventname[retval, eventnumber[retval]] = "connect"
40 eventend[retval, eventnumber[retval]] = gettimeofday_us()
41 lastevent[retval] = "connect"
42 }
43
44 probe syscall.close {
45 @this1 = fd
46 }
47
48 probe syscall.close.return {
49 if (!target_set_pid(pid()))
50 next
51 fd = @this1
52 if (socketstart[fd] != 0 && eventnumber[fd] >= 1)
53 printf("Socket %d close\n", fd)
54 delete socketstart[fd]
55 }
56
57 probe syscall.send, syscall.sendmsg {
58 if (!target_set_pid(pid()))
59 next
60 if (socketstart[s] != 0 && sendstart[s] == 0) {
61 sendstart[s] = gettimeofday_us()
62 if (lastevent[s] == "send")
63 next
64 printshorthistory(s)
65 eventname[s, ++eventnumber[s]] = "send"
66 eventstart[s, eventnumber[s]] = sendstart[s]
67 }
68 @this2 = s
69 }
70
71 probe syscall.sendto {
72 if (!target_set_pid(pid()))
73 next
74 if (socketstart[s] !=0 && sendstart[s] == 0) {
75 sendstart[s] = gettimeofday_us()
76 sendtofd[tid()] = s
77 if (lastevent[s] == "send")
78 next
79 printshorthistory(s)
80 eventname[s, ++eventnumber[s]] = "send"
81 eventstart[s, eventnumber[s]] = sendstart[s]
82 }
83 }
84
85 probe syscall.send.return, syscall.sendmsg.return {
86 if (!target_set_pid(pid()))
87 next
88 fd = @this2
89 if (socketstart[fd] != 0 && retval > 0) {
90 eventbytes[fd, eventnumber[fd]] += retval
91 eventlength[fd, eventnumber[fd]] += gettimeofday_us() - sendstart[fd]
92 eventend[fd, eventnumber[fd]] = gettimeofday_us()
93 }
94 sendstart[fd] = 0
95 lastevent[fd] = "send"
96 }
97
98 probe syscall.sendto.return {
99 if (!target_set_pid(pid()))
100 next
101 fd = sendtofd[tid()]
102 if (socketstart[fd] != 0 && retval > 0) {
103 eventbytes[fd, eventnumber[fd]] += retval
104 eventlength[fd, eventnumber[fd]] += gettimeofday_us() - sendstart[fd]
105 eventend[fd, eventnumber[fd]] = gettimeofday_us()
106 }
107 sendstart[fd] = 0
108 lastevent[fd] = "send"
109 }
110
111 probe syscall.recv, syscall.recvfrom, syscall.recvmsg {
112 if (!target_set_pid(pid()))
113 next
114 if (socketstart[s] != 0 && recvstart[s] == 0) {
115 recvstart[s] = gettimeofday_us()
116 if (lastevent[s] == "recv")
117 next
118 printshorthistory(s)
119 eventname[s, ++eventnumber[s]] = "recv"
120 eventstart[s, eventnumber[s]] = recvstart[s]
121 }
122 @this3 = s
123 }
124
125 probe syscall.recv.return, syscall.recvfrom.return, syscall.recvmsg.return {
126 if (!target_set_pid(pid()))
127 next
128 fd = @this3
129 if (socketstart[fd] != 0 && retval > 0) {
130 eventbytes[fd, eventnumber[fd]] += retval
131 eventlength[fd, eventnumber[fd]] += gettimeofday_us() - recvstart[fd]
132 eventend[fd, eventnumber[fd]] = gettimeofday_us()
133 }
134 recvstart[fd] = 0
135 lastevent[fd] = "recv"
136 }
137
138 probe syscall.write, syscall.writev {
139 if (!target_set_pid(pid()))
140 next
141 if (socketstart[fd] != 0 && writestart[fd] == 0) {
142 writestart[fd] = gettimeofday_us()
143 if (lastevent[fd] == "write")
144 next
145 printshorthistory(fd)
146 eventname[fd, ++eventnumber[fd]] = "write"
147 eventstart[fd, eventnumber[fd]] = writestart[fd]
148 }
149 @this4 = fd
150 }
151
152 probe syscall.write.return, syscall.writev.return {
153 if (!target_set_pid(pid()))
154 next
155 fd = @this4
156 if (socketstart[fd] != 0 && retval > 0) {
157 eventbytes[fd, eventnumber[fd]] += retval
158 eventlength[fd, eventnumber[fd]] += gettimeofday_us() - writestart[fd]
159 eventend[fd, eventnumber[fd]] = gettimeofday_us()
160 }
161 writestart[fd] = 0
162 lastevent[fd] = "write"
163 }
164
165 probe syscall.read, syscall.readv {
166 if (!target_set_pid(pid()))
167 next
168 if (socketstart[fd] != 0 && readstart[fd] == 0) {
169 readstart[fd] = gettimeofday_us()
170 if (lastevent[fd] == "read")
171 next
172 printshorthistory(fd)
173 eventname[fd, ++eventnumber[fd]] = "read"
174 eventstart[fd, eventnumber[fd]] = readstart[fd]
175 }
176 @this5 = fd
177 }
178
179 probe syscall.read.return, syscall.readv.return {
180 if (!target_set_pid(pid()))
181 next
182 fd = @this5
183 if (socketstart[fd] != 0 && retval > 0) {
184 eventbytes[fd, eventnumber[fd]] += retval
185 eventlength[fd, eventnumber[fd]] += gettimeofday_us() - readstart[fd]
186 eventend[fd, eventnumber[fd]] = gettimeofday_us()
187 }
188 readstart[fd] = 0
189 lastevent[fd] = "read"
190 }