Debian Codegraph @

EXAMPLES/process/proc_snoop.stp

raw
1 #! /usr/bin/env stap
2
3 global start_ts
4
5 probe begin {
6 start_ts = gettimeofday_us()
7 printf("%12s %5s %5s %-16s ACTION\n",
8 "TIMESTAMP", "PID", "TID", "EXECNAME")
9 }
10
11 function report(action:string) {
12 printf("%12d %5d %5d %-16s %s\n", gettimeofday_us() - start_ts,
13 pid(), tid(), execname(), action)
14 }
15
16 function id:string(task:long) {
17 return sprintf("p:%d t:%d n:%s", task_pid(task), task_tid(task),
18 task_execname(task))
19 }
20
21 probe kprocess.create {
22 report(sprintf("create %s", id(task)))
23 }
24
25 probe kprocess.start {
26 report("start")
27 }
28
29 probe kprocess.exec {
30 report(sprintf("exec %s", filename))
31 }
32
33 probe kprocess.exec_complete {
34 if (success)
35 report("exec success")
36 else
37 report(sprintf("exec failed %d (%s)", errno, errno_str(errno)))
38 }
39
40 probe kprocess.exit {
41 report(sprintf("exit %d", code))
42 }
43
44 probe kprocess.release {
45 report(sprintf("remove %s", id(task)))
46 }
47
48 probe signal.send {
49 report(sprintf("sigsend %d (%s) to %s%s", sig, sig_name, id(task),
50 shared? " [SHARED]" : ""))
51 }
52
53 probe signal.handle {
54 report(sprintf("sighandle %d (%s)", sig, sig_name))
55 }