Debian Codegraph @

src/machine/meson.build

raw
1 # SPDX-License-Identifier: LGPL-2.1-or-later
2
3 if conf.get('ENABLE_MACHINED') != 1
4 subdir_done()
5 endif
6
7 systemd_machined_sources = files(
8 'machined.c'
9 )
10 systemd_machined_extract_sources = files(
11 'image.c',
12 'image-dbus.c',
13 'image-varlink.c',
14 'machine-dbus.c',
15 'machine-varlink.c',
16 'machine.c',
17 'machined-core.c',
18 'machined-dbus.c',
19 'machined-resolve-hook.c',
20 'machined-varlink.c',
21 'operation.c',
22 )
23
24 executables += [
25 libexec_template + {
26 'name' : 'systemd-machined',
27 'dbus' : true,
28 'sources' : systemd_machined_sources,
29 'extract' : systemd_machined_extract_sources,
30 },
31 executable_template + {
32 'name' : 'machinectl',
33 'public' : true,
34 'sources' : files('machinectl.c'),
35 'dependencies' : [
36 liblz4_cflags,
37 libxz_cflags,
38 libzstd_cflags,
39 ],
40 },
41 test_template + {
42 'sources' : files('test-machine-tables.c'),
43 'objects' : ['systemd-machined'],
44 },
45 ]
46
47 install_data('org.freedesktop.machine1.conf',
48 install_dir : dbuspolicydir)
49 install_data('org.freedesktop.machine1.service',
50 install_dir : dbussystemservicedir)
51 install_data('org.freedesktop.machine1.service-for-session',
52 install_dir : dbussessionservicedir,
53 rename : 'org.freedesktop.machine1.service')
54 install_data('org.freedesktop.machine1.policy',
55 install_dir : polkitpolicydir)