Debian Codegraph @

mkspecs/devices/linux-sh4-stmicro-ST7540-g++/qmake.conf

raw
1 #
2 # qmake configuration for linux-g++ using the sh4-linux-g++ crosscompiler
3 #
4 # http://wiki.qt.io/ST7540
5 #
6
7 MAKEFILE_GENERATOR = UNIX
8 CONFIG += incremental
9 QMAKE_INCREMENTAL_STYLE = sublib
10
11 include(../../common/linux.conf)
12 include(../../common/gcc-base-unix.conf)
13 include(../../common/g++-unix.conf)
14
15 load(device_config)
16
17 defineTest(qtConfSanitizeMkspec) {
18 deviceSanityCheckCompiler()
19 }
20
21 QMAKE_CC = $${CROSS_COMPILE}gcc
22 QMAKE_CXX = $${CROSS_COMPILE}g++
23 QMAKE_LINK = $${QMAKE_CXX}
24 QMAKE_LINK_SHLIB = $${QMAKE_CXX}
25
26 QMAKE_AR = $${CROSS_COMPILE}ar cqs
27 QMAKE_OBJCOPY = $${CROSS_COMPILE}objcopy
28 QMAKE_NM = $${CROSS_COMPILE}nm -P
29 QMAKE_STRIP = $${CROSS_COMPILE}strip
30
31 QMAKE_INCDIR_EGL += $$[QT_SYSROOT]/root/modules/include/
32 QMAKE_LIBDIR_EGL += $$[QT_SYSROOT]/root/modules/
33
34 #
35 # The EGL library used for ST7540 is based on DirectFB so it has to be linked with
36 # 1. libdirectfb.so 2. libfusion.so 3. libdirect.so
37 #
38 QMAKE_LIBS_EGL += -lMali -ldirectfb -lfusion -ldirect
39
40 QMAKE_INCDIR_OPENGL_ES2 += $$QMAKE_INCDIR_EGL
41 QMAKE_LIBDIR_OPENGL_ES2 += $$QMAKE_LIBDIR_EGL
42 QMAKE_LIBS_OPENGL_ES2 += $$QMAKE_LIBS_EGL
43
44 QT_QPA_DEFAULT_PLATFORM = eglfs
45
46 load(qt_config)
47