Debian Codegraph @

mkspecs/devices/linux-drive-cx-g++/qmake.conf

raw
1 #
2 # qmake configuration for 64-bit Tegra X1 boards, like the DRIVE CX, using Vibrante Linux
3 #
4 # A typical configure line might look like:
5 # configure \
6 # -device drive-cx \
7 # -device-option VIBRANTE_SDK_TOPDIR=/opt/nvidia/vibrante-t186ref-linux
8 # -device-option CROSS_COMPILE=/opt/nvidia/toolchains/tegra-4.9-nv/usr/bin/aarch64-gnu-linux/aarch64-gnu-linux- \
9 # -sysroot /opt/nvidia/vibrante-t186ref-linux/targetfs \
10 # -no-gcc-sysroot \
11 # -opengl es2
12
13 # Note: This enables eglfs and wayland only. To enable xcb (with EGL
14 # support) as well, add -qt-xcb and fix the SDK's X11 headers. See
15 # QTBUG-55140.
16
17 include(../common/linux_device_pre.conf)
18
19 QMAKE_INCDIR_POST += \
20 $${VIBRANTE_SDK_TOPDIR}/include \
21 $$[QT_SYSROOT]/usr/include
22
23 QMAKE_LIBDIR_POST += \
24 $${VIBRANTE_SDK_TOPDIR}/lib-target \
25 $$[QT_SYSROOT]/usr/lib \
26 $$[QT_SYSROOT]/lib/aarch64-linux-gnu \
27 $$[QT_SYSROOT]/usr/lib/aarch64-linux-gnu
28
29 QMAKE_RPATHLINKDIR_POST += \
30 $${VIBRANTE_SDK_TOPDIR}/lib-target \
31 $$[QT_SYSROOT]/usr/lib \
32 $$[QT_SYSROOT]/usr/lib/aarch64-linux-gnu \
33 $$[QT_SYSROOT]/lib/aarch64-linux-gnu
34
35 DISTRO_OPTS += aarch64
36
37 # Do not define WIN_INTERFACE_CUSTOM here. It is suitable for drm and
38 # wayland, but not X11. Leave it to qt_egl_p.h instead.
39 COMPILER_FLAGS += -mtune=cortex-a57.cortex-a53 -march=armv8-a
40
41 EGLFS_DEVICE_INTEGRATION = eglfs_kms_egldevice
42
43 include(../common/linux_arm_device_post.conf)
44
45 # override the default from linux_arm_device_post.conf
46 defineTest(qtConfSanitizeMkspec) {
47 isEmpty(VIBRANTE_SDK_TOPDIR): \
48 error("You must pass -device-option VIBRANTE_SDK_TOPDIR=/path/to/sdk")
49 deviceSanityCheckCompiler()
50 }
51
52 load(qt_config)