Debian Codegraph @

mkspecs/devices/integrity-armv8-drive-cx/qmake.conf

raw
1 #
2 # qmake configuration for 64-bit Tegra X1 boards, like the DRIVE CX, using Vibrante Integrity
3 #
4 # A typical configure line might look like:
5 # configure \
6 # -device integrity-armv8-drive-cx \
7 # -device-option VIBRANTE_INTEGRITY_PDK_TOPDIR=/opt/nvidia/vibrante-t186ref-integrity
8 # -static \
9 # -opengl es2
10
11 load(device_config)
12
13 include(../../common/ghs-integrity-armv8.conf)
14
15 DEFINES += WIN_INTERFACE_CUSTOM
16
17 QT_QPA_DEFAULT_PLATFORM = eglfs
18
19 QMAKE_LIBS_EGL += -lEGL -lGLESv2 -lnvidia-glsi -lnvidia-eglcore -lnvidia-rmapi-tegra -lposix -livfs -ldrm-nvdc -lnvll -lnvdc -lnvrm -lnvrm_gpu -lnvrm_graphics -lnvos -lsocket -lnet -lnvtegrahv
20 QMAKE_LIBS_OPENGL_ES2 += $${QMAKE_LIBS_EGL}
21
22 EGLFS_DEVICE_INTEGRATION = eglfs_kms_egldevice
23
24 # Vibrante Integrity PDK headers & libraries
25 QMAKE_INCDIR += $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/include
26 QMAKE_LIBDIR += $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/libs
27
28 # OpenGL libraries have a dependency on libEGL
29 QMAKE_INCDIR_EGL = $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/include
30 QMAKE_LIBDIR_EGL = $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/libs
31 QMAKE_INCDIR_OPENGL_ES2 = $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/include
32 QMAKE_LIBDIR_OPENGL_ES2 = $${VIBRANTE_INTEGRITY_PDK_TOPDIR}/libs
33
34 defineTest(qtConfSanitizeMkspec) {
35 isEmpty(VIBRANTE_INTEGRITY_PDK_TOPDIR): \
36 error("You must pass -device-option VIBRANTE_INTEGRITY_PDK_TOPDIR=/path/to/pdk")
37 }
38
39 load(qt_config)