Debian Codegraph @

tests/auto/qml-qtquicktest/data/tst_xyseries.qml

raw
1 // Copyright (C) 2016 The Qt Company Ltd.
2 // SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only
3
4 import QtQuick 2.0
5 import QtTest 1.0
6 import QtCharts 2.1
7
8 Rectangle {
9 width: 400
10 height: 300
11
12 TestCase {
13 id: tc1
14 name: "tst_qml-qtquicktest XY Series"
15 when: windowShown
16
17 function test_properties() {
18 verify(lineSeries.color != undefined);
19 compare(lineSeries.pointsVisible, false);
20 compare(lineSeries.capStyle, Qt.SquareCap);
21 compare(lineSeries.style, Qt.SolidLine);
22 compare(lineSeries.width, 2.0);
23
24 verify(splineSeries.color != undefined);
25 compare(splineSeries.pointsVisible, false);
26 compare(splineSeries.capStyle, Qt.SquareCap);
27 compare(splineSeries.style, Qt.SolidLine);
28 compare(splineSeries.width, 2.0);
29
30 verify(scatterSeries.color != undefined);
31 verify(scatterSeries.borderColor != undefined);
32 compare(scatterSeries.borderWidth, 2.0);
33 compare(scatterSeries.markerShape, ScatterSeries.MarkerShapeCircle);
34 compare(scatterSeries.markerSize, 15.0);
35 compare(scatterSeries.brushFilename, "");
36
37 verify(areaSeries.color != undefined);
38 verify(areaSeries.borderColor != undefined);
39 compare(areaSeries.borderWidth, 2.0);
40 compare(areaSeries.brushFilename, "");
41 }
42
43 function test_axes() {
44 // Axis initialization
45 compare(chartView.axisX(), lineSeries.axisX);
46 compare(chartView.axisY(), lineSeries.axisY);
47 compare(lineSeries.axisX, splineSeries.axisX);
48 compare(lineSeries.axisY, splineSeries.axisY);
49 compare(lineSeries.axisX, areaSeries.axisX);
50 compare(lineSeries.axisY, areaSeries.axisY);
51 }
52
53 function test_append() {
54 lineSeriesPointAddedSpy.clear();
55 splineSeriesPointAddedSpy.clear();
56 scatterSeriesPointAddedSpy.clear();
57 var count = append();
58 compare(lineSeries.count, count);
59 compare(splineSeries.count, count);
60 compare(scatterSeries.count, count);
61 compare(lineSeriesPointAddedSpy.count, count);
62 compare(splineSeriesPointAddedSpy.count, count);
63 compare(scatterSeriesPointAddedSpy.count, count);
64 clear();
65 compare(lineSeries.count, 0);
66 compare(splineSeries.count, 0);
67 compare(scatterSeries.count, 0);
68 }
69
70 function test_replace() {
71 var count = append();
72 for (var i = 0; i < count; i++) {
73 lineSeries.replace(lineSeries.at(i).x, lineSeries.at(i).y, i, Math.random());
74 splineSeries.replace(splineSeries.at(i).x, splineSeries.at(i).y, i, Math.random());
75 scatterSeries.replace(scatterSeries.at(i).x, scatterSeries.at(i).y, i, Math.random());
76 }
77 compare(lineSeries.count, count);
78 compare(splineSeries.count, count);
79 compare(scatterSeries.count, count);
80 compare(lineSeriesPointReplacedSpy.count, count);
81 compare(splineSeriesPointReplacedSpy.count, count);
82 compare(scatterSeriesPointReplacedSpy.count, count);
83 clear();
84 }
85
86 function test_insert() {
87 var count = append();
88 lineSeriesPointAddedSpy.clear();
89 splineSeriesPointAddedSpy.clear();
90 scatterSeriesPointAddedSpy.clear();
91 for (var i = 0; i < count; i++) {
92 lineSeries.insert(i * 2, i, Math.random());
93 splineSeries.insert(i * 2, i, Math.random());
94 scatterSeries.insert(i * 2, i, Math.random());
95 }
96 compare(lineSeries.count, count * 2);
97 compare(splineSeries.count, count * 2);
98 compare(scatterSeries.count, count * 2);
99 compare(lineSeriesPointAddedSpy.count, count);
100 compare(splineSeriesPointAddedSpy.count, count);
101 compare(scatterSeriesPointAddedSpy.count, count);
102 clear();
103 }
104
105 function test_remove() {
106 lineSeriesPointRemovedSpy.clear();
107 splineSeriesPointRemovedSpy.clear();
108 scatterSeriesPointRemovedSpy.clear();
109 var count = append();
110 for (var i = 0; i < count; i++) {
111 lineSeries.remove(lineSeries.at(0).x, lineSeries.at(0).y);
112 splineSeries.remove(splineSeries.at(0).x, splineSeries.at(0).y);
113 scatterSeries.remove(scatterSeries.at(0).x, scatterSeries.at(0).y);
114 }
115 compare(lineSeries.count, 0);
116 compare(splineSeries.count, 0);
117 compare(scatterSeries.count, 0);
118 compare(lineSeriesPointRemovedSpy.count, count);
119 compare(splineSeriesPointRemovedSpy.count, count);
120 compare(scatterSeriesPointRemovedSpy.count, count);
121
122 lineSeriesPointRemovedSpy.clear();
123 splineSeriesPointRemovedSpy.clear();
124 scatterSeriesPointRemovedSpy.clear();
125 lineSeriesPointsRemovedSpy.clear();
126 splineSeriesPointsRemovedSpy.clear();
127 scatterSeriesPointsRemovedSpy.clear();
128
129 count = append();
130 lineSeries.removePoints(2, count - 2);
131 splineSeries.removePoints(2, count - 2);
132 scatterSeries.removePoints(2, count - 2);
133
134 compare(lineSeries.count, 2);
135 compare(splineSeries.count, 2);
136 compare(scatterSeries.count, 2);
137
138 lineSeries.removePoints(0, 2);
139 splineSeries.removePoints(0, 2);
140 scatterSeries.removePoints(0, 2);
141
142 compare(lineSeries.count, 0);
143 compare(splineSeries.count, 0);
144 compare(scatterSeries.count, 0);
145 compare(lineSeriesPointRemovedSpy.count, 0);
146 compare(splineSeriesPointRemovedSpy.count, 0);
147 compare(scatterSeriesPointRemovedSpy.count, 0);
148 compare(lineSeriesPointsRemovedSpy.count, 2);
149 compare(splineSeriesPointsRemovedSpy.count, 2);
150 compare(scatterSeriesPointsRemovedSpy.count, 2);
151 }
152
153 // Not a test function, called from test functions
154 function append() {
155 var count = 100;
156 chartView.axisX().min = 0;
157 chartView.axisX().max = 100;
158 chartView.axisY().min = 0;
159 chartView.axisY().max = 1;
160
161 for (var i = 0; i < count; i++) {
162 lineSeries.append(i, Math.random());
163 splineSeries.append(i, Math.random());
164 scatterSeries.append(i, Math.random());
165 }
166
167 return count;
168 }
169
170 // Not a test function, called from test functions
171 function clear() {
172 lineSeries.clear();
173 splineSeries.clear();
174 scatterSeries.clear();
175 }
176 }
177
178 ChartView {
179 id: chartView
180 anchors.fill: parent
181
182 LineSeries {
183 id: lineSeries
184 name: "line"
185
186 SignalSpy {
187 id: lineSeriesPointAddedSpy
188 target: lineSeries
189 signalName: "pointAdded"
190 }
191
192 SignalSpy {
193 id: lineSeriesPointReplacedSpy
194 target: lineSeries
195 signalName: "pointReplaced"
196 }
197
198 SignalSpy {
199 id: lineSeriesPointsReplacedSpy
200 target: lineSeries
201 signalName: "pointsReplaced"
202 }
203
204 SignalSpy {
205 id: lineSeriesPointRemovedSpy
206 target: lineSeries
207 signalName: "pointRemoved"
208 }
209
210 SignalSpy {
211 id: lineSeriesPointsRemovedSpy
212 target: lineSeries
213 signalName: "pointsRemoved"
214 }
215 }
216
217 AreaSeries {
218 id: areaSeries
219 name: "area"
220 upperSeries: lineSeries
221 }
222
223 SplineSeries {
224 id: splineSeries
225 name: "spline"
226
227 SignalSpy {
228 id: splineSeriesPointAddedSpy
229 target: splineSeries
230 signalName: "pointAdded"
231 }
232
233 SignalSpy {
234 id: splineSeriesPointReplacedSpy
235 target: splineSeries
236 signalName: "pointReplaced"
237 }
238
239 SignalSpy {
240 id: splineSeriesPointsReplacedSpy
241 target: splineSeries
242 signalName: "pointsReplaced"
243 }
244
245 SignalSpy {
246 id: splineSeriesPointRemovedSpy
247 target: splineSeries
248 signalName: "pointRemoved"
249 }
250
251 SignalSpy {
252 id: splineSeriesPointsRemovedSpy
253 target: splineSeries
254 signalName: "pointsRemoved"
255 }
256 }
257
258 ScatterSeries {
259 id: scatterSeries
260 name: "scatter"
261
262 SignalSpy {
263 id: scatterSeriesPointAddedSpy
264 target: scatterSeries
265 signalName: "pointAdded"
266 }
267
268 SignalSpy {
269 id: scatterSeriesPointReplacedSpy
270 target: scatterSeries
271 signalName: "pointReplaced"
272 }
273
274 SignalSpy {
275 id: scatterSeriesPointsReplacedSpy
276 target: scatterSeries
277 signalName: "pointsReplaced"
278 }
279
280 SignalSpy {
281 id: scatterSeriesPointRemovedSpy
282 target: scatterSeries
283 signalName: "pointRemoved"
284 }
285
286 SignalSpy {
287 id: scatterSeriesPointsRemovedSpy
288 target: scatterSeries
289 signalName: "pointsRemoved"
290 }
291 }
292 }
293 }