Debian Codegraph @

cmake/3rdparty/extra-cmake-modules/find-modules/FindGLIB2.cmake

raw
1 #.rst:
2 # FindGLIB2
3 # ---------
4 #
5 # Try to locate the GLib2 library.
6 # If found, this will define the following variables:
7 #
8 # ``GLIB2_FOUND``
9 # True if the GLib2 library is available
10 # ``GLIB2_INCLUDE_DIRS``
11 # The GLib2 include directories
12 # ``GLIB2_LIBRARIES``
13 # The GLib2 libraries for linking
14 # ``GLIB2_INCLUDE_DIR``
15 # Deprecated, use ``GLIB2_INCLUDE_DIRS``
16 # ``GLIB2_LIBRARY``
17 # Deprecated, use ``GLIB2_LIBRARIES``
18 #
19 # If ``GLIB2_FOUND`` is TRUE, it will also define the following
20 # imported target:
21 #
22 # ``GLIB2::GLIB2``
23 # The GLIB2 library
24 #
25 # Since 5.41.0.
26
27 #=============================================================================
28 # Copyright (c) 2008 Laurent Montel, <[email protected]>
29 #
30 # Redistribution and use in source and binary forms, with or without
31 # modification, are permitted provided that the following conditions
32 # are met:
33 #
34 # 1. Redistributions of source code must retain the copyright
35 # notice, this list of conditions and the following disclaimer.
36 # 2. Redistributions in binary form must reproduce the copyright
37 # notice, this list of conditions and the following disclaimer in the
38 # documentation and/or other materials provided with the distribution.
39 # 3. The name of the author may not be used to endorse or promote products
40 # derived from this software without specific prior written permission.
41 #
42 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
43 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
44 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
45 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
46 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
47 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
48 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
49 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
50 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
51 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
52 #=============================================================================
53
54 find_package(PkgConfig QUIET)
55 pkg_check_modules(PC_GLIB2 QUIET glib-2.0)
56
57 find_path(GLIB2_INCLUDE_DIRS
58 NAMES glib.h
59 HINTS ${PC_GLIB2_INCLUDEDIR}
60 PATH_SUFFIXES glib-2.0)
61
62 find_library(GLIB2_LIBRARIES
63 NAMES glib-2.0
64 HINTS ${PC_GLIB2_LIBDIR}
65 )
66
67 pkg_check_modules(PC_GTHREAD2 QUIET gthread-2.0)
68
69 find_library(GTHREAD2_LIBRARIES
70 NAMES gthread-2.0
71 HINTS ${PC_GTHREAD2_LIBDIR}
72 )
73
74 pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
75
76 find_path(GLIB2_GOBJECT_INCLUDE_DIRS
77 NAMES glib-object.h
78 HINTS ${PC_GOBJECT_INCLUDEDIR}
79 PATH_SUFFIXES glib-2.0)
80
81 find_library(GLIB2_GOBJECT_LIBRARIES
82 NAMES gobject-2.0
83 HINTS ${PC_GOBJECT_LIBDIR}
84 )
85
86 pkg_check_modules(PC_GIO QUIET gio-2.0)
87
88 find_path(GLIB2_GIO_INCLUDE_DIRS
89 NAMES gio/gio.h
90 HINTS ${PC_GIO_INCLUDEDIR}
91 PATH_SUFFIXES glib-2.0)
92
93 find_library(GLIB2_GIO_LIBRARIES
94 NAMES gio-2.0
95 HINTS ${PC_GIO_LIBDIR}
96 )
97
98 # search the glibconfig.h include dir under the same root where the library is found
99 get_filename_component(glib2LibDir "${GLIB2_LIBRARIES}" PATH)
100
101 find_path(GLIB2_INTERNAL_INCLUDE_DIR glibconfig.h
102 PATH_SUFFIXES glib-2.0/include
103 HINTS ${PC_GLIB2_INCLUDEDIR} "${glib2LibDir}" ${CMAKE_SYSTEM_LIBRARY_PATH})
104
105 # not sure if this include dir is optional or required
106 # for now it is optional
107 if(GLIB2_INTERNAL_INCLUDE_DIR)
108 list(APPEND GLIB2_INCLUDE_DIRS "${GLIB2_INTERNAL_INCLUDE_DIR}")
109 list(APPEND GLIB2_GOBJECT_INCLUDE_DIRS "${GLIB2_INTERNAL_INCLUDE_DIR}")
110 list(APPEND GLIB2_GIO_INCLUDE_DIRS "${GLIB2_INTERNAL_INCLUDE_DIR}")
111 endif()
112
113 # Deprecated synonyms
114 set(GLIB2_INCLUDE_DIR "${GLIB2_INCLUDE_DIRS}")
115 set(GLIB2_LIBRARY "${GLIB2_LIBRARIES}")
116 set(GLIB2_GOBJECT_INCLUDE_DIR "${GLIB2_GOBJECT_INCLUDE_DIRS}")
117 set(GLIB2_GOBJECT_LIBRARY "${GLIB2_GOBJECT_LIBRARIES}")
118 set(GLIB2_GIO_INCLUDE_DIR "${GLIB2_GIO_INCLUDE_DIRS}")
119 set(GLIB2_GIO_LIBRARY "${GLIB2_GIO_LIBRARIES}")
120
121 if(GLIB2_GOBJECT_LIBRARIES AND GLIB2_GOBJECT_INCLUDE_DIRS)
122 set(GLIB2_GOBJECT_FOUND TRUE)
123 endif()
124
125 if(GLIB2_GIO_LIBRARIES AND GLIB2_GIO_INCLUDE_DIRS)
126 set(GLIB2_GIO_FOUND TRUE)
127 endif()
128
129 include(FindPackageHandleStandardArgs)
130 find_package_handle_standard_args(GLIB2
131 REQUIRED_VARS GLIB2_LIBRARIES GTHREAD2_LIBRARIES GLIB2_INCLUDE_DIRS
132 HANDLE_COMPONENTS)
133
134 if(GLIB2_FOUND AND NOT TARGET GLIB2::GLIB2)
135 add_library(GLIB2::GLIB2 UNKNOWN IMPORTED)
136 set_target_properties(GLIB2::GLIB2 PROPERTIES
137 IMPORTED_LOCATION "${GLIB2_LIBRARIES}"
138 INTERFACE_LINK_LIBRARIES "${GTHREAD2_LIBRARIES}"
139 INTERFACE_INCLUDE_DIRECTORIES "${GLIB2_INCLUDE_DIRS}")
140 endif()
141
142 if(GLIB2_GOBJECT_FOUND AND NOT TARGET GLIB2::GOBJECT)
143 add_library(GLIB2::GOBJECT UNKNOWN IMPORTED)
144 set_target_properties(GLIB2::GOBJECT PROPERTIES
145 IMPORTED_LOCATION "${GLIB2_GOBJECT_LIBRARIES}"
146 INTERFACE_INCLUDE_DIRECTORIES "${GLIB2_GOBJECT_INCLUDE_DIRS}")
147 endif()
148
149 if(GLIB2_GIO_FOUND AND NOT TARGET GLIB2::GIO)
150 add_library(GLIB2::GIO UNKNOWN IMPORTED)
151 set_target_properties(GLIB2::GIO PROPERTIES
152 IMPORTED_LOCATION "${GLIB2_GIO_LIBRARIES}"
153 INTERFACE_INCLUDE_DIRECTORIES "${GLIB2_GIO_INCLUDE_DIRS}")
154 endif()
155
156 mark_as_advanced(GLIB2_INCLUDE_DIRS GLIB2_INCLUDE_DIR
157 GLIB2_LIBRARIES GLIB2_LIBRARY
158 GLIB2_GOBJECT_INCLUDE_DIRS GLIB2_GOBJECT_INCLUDE_DIR
159 GLIB2_GOBJECT_LIBRARIES GLIB2_GOBJECT_LIBRARY
160 GLIB2_GIO_INCLUDE_DIRS GLIB2_GIO_INCLUDE_DIR
161 GLIB2_GIO_LIBRARIES GLIB2_GIO_LIBRARY)
162
163 include(FeatureSummary)
164 set_package_properties(GLIB2 PROPERTIES
165 URL "https://wiki.gnome.org/Projects/GLib"
166 DESCRIPTION "Event loop and utility library")
167