Debian Codegraph @

vendor/ls-qpack/test/CMakeLists.txt

raw
1 add_compile_definitions("TEST_DATA=\"${CMAKE_CURRENT_SOURCE_DIR}/testdata\"")
2
3 function(lsqpack_add_test TARGET)
4 add_executable(test_${TARGET} "")
5 target_sources(test_${TARGET} PRIVATE test_${TARGET}.c)
6 target_link_libraries(test_${TARGET} ls-qpack)
7
8 if(WIN32)
9 target_include_directories(test_${TARGET} PRIVATE ../wincompat)
10 target_link_libraries(test_${TARGET} ${GETOPT_LIB})
11 else()
12 target_link_libraries(test_${TARGET} m)
13 endif()
14
15 add_test(${TARGET} test_${TARGET})
16 endfunction()
17
18 lsqpack_add_test(int)
19 lsqpack_add_test(enc_str)
20 lsqpack_add_test(huff_dec)
21 lsqpack_add_test(read_enc_stream)
22 lsqpack_add_test(qpack)
23 lsqpack_add_test(circ_list)
24 lsqpack_add_test(dec_crash_case)
25 lsqpack_add_test(dyn_table_cap_mismatch)
26
27 if(WIN32)
28 message(WARNING "Scenario tests are disabled on Windows (TODO)")
29 else()
30 file(GLOB SCENARIOS scenarios/*.sce)
31 foreach(SCENARIO ${SCENARIOS})
32 get_filename_component(TEST_NAME ${SCENARIO} NAME)
33 add_test(
34 NAME scenario-${TEST_NAME}
35 COMMAND bash run-scenario.sh ${SCENARIO}
36 WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/test
37 )
38 set_tests_properties(scenario-${TEST_NAME} PROPERTIES
39 ENVIRONMENT "PATH=$ENV{PATH}:${PROJECT_BINARY_DIR}/bin:${PROJECT_SOURCE_DIR}/tools"
40 )
41 endforeach()
42 endif()
43
44 find_package(Perl)
45
46 if(PERL_FOUND)
47 message(STATUS "Found Perl interpreter: ${PERL_EXECUTABLE}")
48 file(GLOB QIFS qifs/*.qif)
49
50 foreach(QIF ${QIFS})
51 get_filename_component(FILE_NAME ${QIF} NAME)
52
53 foreach(TABLE_SIZE 0 256 512 1024 4096)
54 foreach(RISKED_STREAMS 0 100)
55 foreach(IMMEDIATE_ACK 0 1)
56 foreach(AGGRESSIVE 0 1)
57 set(TEST_NAME qif-${FILE_NAME}-t${TABLE_SIZE}-s${RISKED_STREAMS}-a${IMMEDIATE_ACK}-A${AGGRESSIVE})
58
59 add_test(
60 NAME ${TEST_NAME}
61 COMMAND ${PERL_EXECUTABLE} run-qif.pl --table-size ${TABLE_SIZE} --risked-streams ${RISKED_STREAMS} --immed-ack ${IMMEDIATE_ACK} --aggressive ${AGGRESSIVE} ${QIF}
62 WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/test
63 )
64
65 if(NOT WIN32)
66 set_tests_properties(${TEST_NAME} PROPERTIES
67 ENVIRONMENT "PATH=$ENV{PATH}:${PROJECT_BINARY_DIR}/bin:${PROJECT_SOURCE_DIR}/tools"
68 )
69 endif()
70 endforeach()
71 endforeach()
72 endforeach()
73 endforeach()
74 endforeach()
75 else()
76 message(WARNING "Perl not found: QIF tests won't be run")
77 endif()