Debian Codegraph @

src/interfaces/ecpg/compatlib/meson.build

raw
1 # Copyright (c) 2022-2025, PostgreSQL Global Development Group
2
3 ecpg_compat_sources = files(
4 'informix.c',
5 )
6 ecpg_compat_so_sources = [] # for shared lib, in addition to the above
7
8 ecpg_compat_inc = [include_directories('.'), ecpg_inc, libpq_inc]
9 ecpg_compat_c_args = ['-DSO_MAJOR_VERSION=3']
10 export_file = custom_target('libecpg_compat.exports', kwargs: gen_export_kwargs)
11
12 if host_system == 'windows'
13 ecpg_compat_so_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
14 '--NAME', 'libecpg_compat',
15 '--FILEDESC', 'ECPG compat - compatibility library for ECPG',])
16 endif
17
18 # see src/interfaces/libpq/meson.build
19 ecpg_compat_st = static_library('libecpg_compat',
20 ecpg_compat_sources,
21 include_directories: ecpg_compat_inc,
22 c_args: ecpg_compat_c_args,
23 dependencies: [frontend_stlib_code, thread_dep],
24 link_with: [ecpglib_st, ecpg_pgtypes_st],
25 kwargs: default_lib_args,
26 )
27 ecpg_targets += ecpg_compat_st
28
29 ecpg_compat_so = shared_library('libecpg_compat',
30 ecpg_compat_sources + ecpg_compat_so_sources,
31 include_directories: ecpg_compat_inc,
32 c_args: ecpg_compat_c_args,
33 dependencies: [frontend_shlib_code, thread_dep],
34 link_with: [ecpglib_so, ecpg_pgtypes_so],
35 soversion: host_system != 'windows' ? '3' : '',
36 darwin_versions: ['3', '3.' + pg_version_major.to_string()],
37 version: '3.' + pg_version_major.to_string(),
38 link_args: export_fmt.format(export_file.full_path()),
39 link_depends: export_file,
40 kwargs: default_lib_args,
41 )
42 ecpg_targets += ecpg_compat_so
43
44 pkgconfig.generate(
45 name: 'libecpg_compat',
46 description: 'PostgreSQL libecpg_compat library',
47 url: pg_url,
48 libraries: ecpg_compat_so,
49 libraries_private: [frontend_stlib_code, thread_dep],
50 requires_private: ['libecpg', 'libpgtypes'],
51 )