Debian Codegraph @

vendored-meson/meson/test cases/linuxlike/13 cmake dependency/meson.build

raw
1 # this test can ONLY be run successfully from run_project_test.py
2 # due to use of setup_env.json
3 project('external CMake dependency', ['c', 'cpp'])
4
5 cmake = find_program('cmake')
6
7 # Zlib is probably on all dev machines.
8
9 dep = dependency('ZLIB', version : '>=1.2', method : 'cmake')
10
11 if '#define' in dep.version() and cmake.version().version_compare('< 3.27.4')
12 # ZLIB 1.3 version is broken with those cmake versions
13 error('MESON_SKIP_TEST known bug in cmake (https://gitlab.kitware.com/cmake/cmake/-/issues/25200)')
14 endif
15
16 exe = executable('zlibprog', 'prog-checkver.c',
17 dependencies : dep,
18 c_args : '-DFOUND_ZLIB="' + dep.version() + '"')
19
20 assert(dep.version().version_compare('>=1.2'), 'CMake version numbers exposed incorrectly.')
21
22 # Check that CMake targets are extracted
23 dept = dependency('ZLIB', version : '>=1.2', method : 'cmake', modules : 'ZLIB::ZLIB')
24 exet = executable('zlibprog_target', 'prog-checkver.c',
25 dependencies : dep,
26 c_args : '-DFOUND_ZLIB="' + dep.version() + '"')
27
28 # Check that the version exposed by zlib internally is the same as the one we
29 # retrieve from the pkg-config file. This assumes that the packager didn't mess
30 # up, but we can be reasonably sure of that.
31 test('zlibtest', exe)
32
33 # Test that dependencies of dependencies work.
34 dep2 = declare_dependency(dependencies : dep)
35 exe2 = executable('zlibprog2', 'prog.c', dependencies : dep2)
36 test('zlibtest2', exe2)
37
38 # Try to find a nonexistent library to ensure requires:false works.
39
40 depf1 = dependency('nvakuhrabnsdfasdf', required : false, method : 'cmake')
41 depf2 = dependency('ZLIB', required : false, method : 'cmake', modules : 'dfggh::hgfgag')
42
43 assert(depf2.found() == false, 'Invalid CMake targets should fail')
44
45 # Try to find cmMesonTestDep in a custom prefix
46 # setup_env.json is used by run_project_tests.py:_run_test to point to ./cmake_pref_env/
47 depPrefEnv = dependency('cmMesonTestDep', required : true, method : 'cmake')
48 depPrefEnv1 = dependency('cmMesonTestF1', required : true, method : 'cmake')
49 depPrefEnv2 = dependency('cmMesonTestF2', required : true, method : 'cmake')
50 depPrefEnv3 = dependency('cmMesonTestF3', required : true, method : 'cmake')
51
52 # Try to actually link with depPrefEnv1, since we are doing "fun" stuff there
53 exe3 = executable('zlibprog3', 'prog.c', dependencies : depPrefEnv1)
54 test('zlibtest3', exe3)
55
56 # Try to find a dependency with a custom CMake module
57
58 depm1 = dependency('SomethingLikeZLIB', required : true, components : 'required_comp', method : 'cmake', cmake_module_path : 'cmake')
59 depm2 = dependency('SomethingLikeZLIB', required : true, components : 'required_comp', method : 'cmake', cmake_module_path : ['cmake'])
60 depm3 = dependency('SomethingLikeZLIB', required : true, components : ['required_comp'], cmake_module_path : 'cmake')
61
62
63 # Mix of imported targets and old style variables
64
65 depio1 = dependency('ImportedOldStyle', required : true, cmake_module_path : 'cmake')
66
67 # Try to actually link with depio1, since we are doing even more "fun" stuff there
68 exe4 = executable('zlibprog4', 'prog.c', dependencies : depio1)
69 test('zlibtest4', exe4)
70
71 # Test some edge cases with spaces, etc. (but only for CMake >= 3.15)
72
73 if find_program('cmake', required: false, version: '>=3.15').found()
74 testDep1 = dependency('ImportedTarget', required : true, method : 'cmake', cmake_module_path : 'cmake', modules: 'mesonTestLibDefs')
75 testDep2 = dependency('ImportedTarget', required : true, method : 'cmake', cmake_module_path : 'cmake', modules : ['MesonTest::TestLibDefs'])
76 testFlagSet1 = executable('testFlagSet1', ['testFlagSet.c'], dependencies: [testDep1])
77 testFlagSet2 = executable('testFlagSet2', ['testFlagSet.c'], dependencies: [testDep2])
78 test('testFlagSetTest1', testFlagSet1)
79 test('testFlagSetTest2', testFlagSet2)
80 endif
81
82 # Try to find a dependency with a cmake module which requires a package version
83 # test.json sets CMAKE_PREFIX_PATH to include ./cmake_pref_env/
84 verdep1 = dependency('cmMesonVersionedTestDep', required : true, method : 'cmake', cmake_package_version : '3.0')
85 verdep2 = dependency('cmMesonVersionedTestDep', required : false, method : 'cmake', cmake_package_version : '200.0')
86 assert(not verdep2.found(), 'found a version dep we shouldn\'t have')
87
88 # Try to compile a test that takes a dep and an include_directories
89
90 cc = meson.get_compiler('c')
91 zlibdep = cc.find_library('z')
92 code = '''#include<myinc.h>
93
94 int main(void) {
95 void * something = deflate;
96 if(something != 0)
97 return 0;
98 return 1;
99 }
100 '''
101
102 inc = include_directories('incdir')
103
104 r = cc.run(code, include_directories : inc, dependencies : zlibdep)
105 assert(r.returncode() == 0, 'Running manual zlib test failed.')