Debian Codegraph @

himbaechel/uarch/xilinx/CMakeLists.txt

raw
1 set(SOURCES
2 cells.cc
3 constids.inc
4 extra_data.h
5 fasm.cc
6 mmcm_tables.cc
7 pack_carry.cc
8 pack.cc
9 pack_clocking.cc
10 pack_dram.cc
11 pack_dsp_xc7.cc
12 pack.h
13 pack_io.cc
14 pins.cc
15 pins.h
16 xdc.cc
17 xilinx.cc
18 xilinx.h
19 xilinx_place.cc
20 )
21
22 add_nextpnr_himbaechel_microarchitecture(${uarch}
23 CORE_SOURCES ${SOURCES}
24 )
25
26 set(HIMBAECHEL_PRJXRAY_DB "" CACHE STRING
27 "Path to a project x-ray database")
28 if (NOT HIMBAECHEL_PRJXRAY_DB AND NOT IMPORT_BBA_FILES)
29 message(FATAL_ERROR "HIMBAECHEL_PRJXRAY_DB must be set to a prjxray database checkout")
30 endif()
31
32 set(ALL_HIMBAECHEL_XILINX_DEVICES xc7a100t xc7a200t xc7a50t xc7s50 xc7z010 xc7z020)
33 set(HIMBAECHEL_XILINX_DEVICES ${ALL_HIMBAECHEL_XILINX_DEVICES} CACHE STRING
34 "Include support for these Xilinx devices (available: ${ALL_HIMBAECHEL_XILINX_DEVICES})")
35 if (HIMBAECHEL_XILINX_DEVICES STREQUAL "all")
36 set(HIMBAECHEL_XILINX_DEVICES ${ALL_HIMBAECHEL_XILINX_DEVICES})
37 endif()
38 message(STATUS "Enabled Himbaechel-Xilinx devices: ${HIMBAECHEL_XILINX_DEVICES}")
39
40 if (NOT XilinxChipdb_Python3_EXECUTABLE)
41 find_program(XilinxChipdb_Python3_EXECUTABLE NAMES pypy3 python3)
42 endif()
43
44 foreach (device ${HIMBAECHEL_XILINX_DEVICES})
45 add_bba_produce_command(
46 TARGET nextpnr-himbaechel-xilinx-bba
47 COMMAND ${XilinxChipdb_Python3_EXECUTABLE}
48 ${CMAKE_CURRENT_SOURCE_DIR}/gen/xilinx_gen.py
49 --xray ${HIMBAECHEL_PRJXRAY_DB}/artix7
50 --device ${device}
51 --bba ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba.new
52 OUTPUT
53 ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
54 INPUTS
55 ${CMAKE_CURRENT_SOURCE_DIR}/gen/xilinx_gen.py
56 ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
57 )
58
59 add_bba_compile_command(
60 TARGET nextpnr-himbaechel-xilinx-chipdb
61 OUTPUT himbaechel/xilinx/chipdb-${device}.bin
62 INPUT ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
63 MODE binary
64 )
65 endforeach()