Debian Codegraph @

himbaechel/uarch/ng-ultra/CMakeLists.txt

raw
1 set(SOURCES
2 bitstream.cc
3 cells.cc
4 constids.inc
5 csv.cc
6 extra_data.h
7 location_map.cc
8 location_map.h
9 ng_ultra.cc
10 ng_ultra.h
11 pack.cc
12 pack.h
13 )
14
15 set(TEST_SOURCES
16 tests/lut_dff.cc
17 tests/main.cc
18 )
19
20 add_nextpnr_himbaechel_microarchitecture(${uarch}
21 CORE_SOURCES ${SOURCES}
22 TEST_SOURCES ${TEST_SOURCES}
23 )
24
25 set(HIMBAECHEL_PRJBEYOND_DB "" CACHE STRING
26 "Path to a Project Beyond database")
27 if (NOT HIMBAECHEL_PRJBEYOND_DB)
28 message(FATAL_ERROR "HIMBAECHEL_PRJBEYOND_DB must be set to a prjbeyond database checkout")
29 endif()
30
31 set(ALL_HIMBAECHEL_NGULTRA_DEVICES ng-ultra)
32 set(HIMBAECHEL_NGULTRA_DEVICES ${ALL_HIMBAECHEL_NGULTRA_DEVICES} CACHE STRING
33 "Include support for these NG-Ultra devices (available: ${ALL_HIMBAECHEL_NGULTRA_DEVICES})")
34 message(STATUS "Enabled Himbaechel-NG-Ultra devices: ${HIMBAECHEL_NGULTRA_DEVICES}")
35
36 foreach (device ${HIMBAECHEL_NGULTRA_DEVICES})
37 if (NOT device IN_LIST ALL_HIMBAECHEL_NGULTRA_DEVICES)
38 message(FATAL_ERROR "Device ${device} is not a supported NG-Ultra device")
39 endif()
40
41 string(TOUPPER ${device} device_upper)
42
43 add_bba_produce_command(
44 TARGET nextpnr-himbaechel-ng-ultra-bba
45 COMMAND ${Python3_EXECUTABLE}
46 ${CMAKE_CURRENT_SOURCE_DIR}/gen/arch_gen.py
47 --db ${HIMBAECHEL_PRJBEYOND_DB}
48 --device ${device_upper}
49 --bba ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba.new
50 OUTPUT
51 ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
52 INPUTS
53 ${CMAKE_CURRENT_SOURCE_DIR}/gen/arch_gen.py
54 ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
55 )
56
57 add_bba_compile_command(
58 TARGET nextpnr-himbaechel-ng-ultra-chipdb
59 OUTPUT himbaechel/ng-ultra/chipdb-${device}.bin
60 INPUT ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
61 MODE binary
62 )
63 endforeach()