Debian Codegraph @

himbaechel/uarch/gowin/CMakeLists.txt

raw
1 if (NOT IMPORT_BBA_FILES)
2 include(FindApycula)
3 endif()
4
5 set(SOURCES
6 constids.inc
7 cst.cc
8 cst.h
9 globals.cc
10 globals.h
11 gowin.cc
12 gowin.h
13 gowin_utils.cc
14 gowin_utils.h
15 pack.cc
16 pack_bsram.cc
17 pack_dsp.cc
18 pack_luts.cc
19 pack_io.cc
20 pack_iologic.cc
21 pack.h
22 )
23
24 add_nextpnr_himbaechel_microarchitecture(${uarch}
25 CORE_SOURCES ${SOURCES}
26 )
27
28 set(ALL_HIMBAECHEL_GOWIN_DEVICES GW1N-1 GW1NZ-1 GW1N-4 GW1N-9 GW1N-9C GW1NS-4 GW2A-18 GW2A-18C GW5A-25A GW5AST-138C)
29 set(HIMBAECHEL_GOWIN_DEVICES ${ALL_HIMBAECHEL_GOWIN_DEVICES} CACHE STRING
30 "Include support for these Gowin devices (available: ${ALL_HIMBAECHEL_GOWIN_DEVICES})")
31 if (HIMBAECHEL_GOWIN_DEVICES STREQUAL "all")
32 set(HIMBAECHEL_GOWIN_DEVICES ${ALL_HIMBAECHEL_GOWIN_DEVICES})
33 endif()
34 message(STATUS "Enabled Himbaechel-Gowin devices: ${HIMBAECHEL_GOWIN_DEVICES}")
35
36 foreach (device ${HIMBAECHEL_GOWIN_DEVICES})
37 if (NOT device IN_LIST ALL_HIMBAECHEL_GOWIN_DEVICES)
38 message(FATAL_ERROR "Device ${device} is not a supported Gowin device")
39 endif()
40
41 add_bba_produce_command(
42 TARGET nextpnr-himbaechel-gowin-bba
43 COMMAND ${apycula_Python3_EXECUTABLE}
44 ${CMAKE_CURRENT_SOURCE_DIR}/gowin_arch_gen.py
45 -d ${device}
46 -o ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba.new
47 OUTPUT
48 ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
49 INPUTS
50 ${CMAKE_CURRENT_SOURCE_DIR}/gowin_arch_gen.py
51 ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
52 )
53
54 add_bba_compile_command(
55 TARGET nextpnr-himbaechel-gowin-chipdb
56 OUTPUT himbaechel/gowin/chipdb-${device}.bin
57 INPUT ${CMAKE_CURRENT_BINARY_DIR}/chipdb-${device}.bba
58 MODE binary
59 )
60 endforeach()