Debian Codegraph @

src/tools/mod_neko_config.neko

raw
1 begin = "<html>
2 <head><title>Mod_Neko Configuration</title></head>
3 <h1>Mod_neko Configuration</h1>
4 ";
5 end = "
6 <p>
7 <a href='?'>Home</a>
8 </p>
9 </body>
10 </html>
11 ";
12
13 var params = $loader.loadprim("mod_neko@get_params",0)();
14 var get_config = $loader.loadprim("mod_neko@cgi_get_config",0);
15 var memory = $loader.loadprim("std@mem_size",1);
16 var execCommand = $loader.loadprim("mod_neko@cgi_command",1);
17 var setHeader = $loader.loadprim("mod_neko@set_header",2);
18
19 getParam = function(name) {
20 var p = params;
21 while( p != null ) {
22 if( p[0] == name )
23 return p[1];
24 p = p[2];
25 }
26 return null;
27 }
28
29 error = function(e) {
30 $throw(e);
31 }
32
33 message = function(msg) {
34 $print(begin);
35 $print("<p>",msg,"</p>");
36 $print(end);
37 }
38
39
40 displayObject = function(obj,edit) {
41 var fl = $objfields(obj);
42 var i = 0;
43 $print("<ul>");
44 while( i < $asize(fl) ) {
45 var name = $field(fl[i]);
46 var data = $objget(obj,fl[i]);
47 $print("<li><b>",name,"</b> ");
48 if( edit && $typeof(data) == $tbool )
49 $print("<input type='checkbox' name='",name,"'",if( data ) "checked='1'" else "","/>");
50 else
51 $print(": ",data);
52 $print("</li>");
53 i += 1;
54 }
55 $print("</ul>");
56 }
57
58 displayVars = function() {
59 var gc = $loader.loadprim("std@gc_stats",0)();
60 var now = $loader.loadprim("std@date_now",0)();
61 displayObject({
62 date => $loader.loadprim("std@date_format",2)(now,null),
63 pid => $loader.loadprim("std@sys_get_pid",0)(),
64 gc_heap => gc.heap,
65 gc_free => gc.free,
66 gc_free_size => $int(gc.free * 100.0 / gc.heap) + "%",
67 },false);
68 }
69
70 displayConfig = function(cfg) {
71 $print("<form action='?command=setconfig' method='POST'>");
72 displayObject(cfg,true);
73 $print("<input type='submit' value='Update Config'/>");
74 $print("</form>");
75 }
76
77 displayCache = function(cache) {
78 $print("<table>");
79 $print("<tr><th>File</th><th>Mem</th><th>Hits</th></tr>");
80 while( cache != null ) {
81 $print("<tr><td>",cache[0],"</td><td>",memory(cache[1]),"</td><td>",cache[2],"</td></tr>");
82 cache = cache[3];
83 }
84 $print("</table>");
85 }
86
87 displayMenu = function() {
88 $print(begin);
89 $print("<h2>Vars</h2>");
90 displayVars();
91 $print("<h2>Config</h2>");
92 displayConfig(get_config());
93 $print("<h2>Cache</h2>");
94 displayCache(execCommand("cache"));
95 $print("<h2>Command</h2>");
96 $print("<ul>");
97 $print("<li><a href='?command=stats'>Statistics</a></li>");
98 $print("</ul>");
99 $print(end);
100 }
101
102 displayStatistics = function(stats) {
103 $print(begin);
104 $print("<h2>Statistics</h2>");
105 $print("<table>");
106 $print("<tr><th>Name</th><th>Total Time</th><th>Inner Time</th><th>Hits</th><th>Errors</th></tr>");
107 while( stats != null ) {
108 $print("<tr><td>",stats[0],"</td><td>",stats[1],"</td><td>",stats[2],"</td><td>",stats[3],"</td><td>",stats[4],"</td></tr>");
109 stats = stats[5];
110 }
111 $print("</table>");
112 $print(end);
113 }
114
115 setConfig = function() {
116 var cfg = get_config();
117 var fl = $objfields(cfg);
118 var i = 0;
119 while( i < $asize(fl) ) {
120 var name = $field(fl[i]);
121 var data = $objget(cfg,fl[i]);
122 var value = getParam(name);
123 if( $typeof(data) == $tbool )
124 $objset(cfg,fl[i],value != null);
125 i += 1;
126 }
127 $loader.loadprim("mod_neko@cgi_set_config",1)(cfg);
128 message("Configuration Updated");
129 }
130
131 var cmd = getParam("command");
132 switch( cmd ) {
133 "stats" => displayStatistics(execCommand("stats"))
134 "setconfig" => setConfig()
135 default => {
136 if( cmd != null && cmd != "" ) error("Unknown command "+cmd);
137 displayMenu()
138 }
139 }