Debian Codegraph @

extra/protobuf/protobuf-24.4/cmake/protobuf-generate.cmake

raw
1 function(protobuf_generate)
2 include(CMakeParseArguments)
3
4 set(_options APPEND_PATH)
5 set(_singleargs LANGUAGE OUT_VAR EXPORT_MACRO PROTOC_OUT_DIR PLUGIN PLUGIN_OPTIONS DEPENDENCIES)
6 if(COMMAND target_sources)
7 list(APPEND _singleargs TARGET)
8 endif()
9 set(_multiargs PROTOS IMPORT_DIRS GENERATE_EXTENSIONS PROTOC_OPTIONS)
10
11 cmake_parse_arguments(protobuf_generate "${_options}" "${_singleargs}" "${_multiargs}" "${ARGN}")
12
13 if(NOT protobuf_generate_PROTOS AND NOT protobuf_generate_TARGET)
14 message(SEND_ERROR "Error: protobuf_generate called without any targets or source files")
15 return()
16 endif()
17
18 if(NOT protobuf_generate_OUT_VAR AND NOT protobuf_generate_TARGET)
19 message(SEND_ERROR "Error: protobuf_generate called without a target or output variable")
20 return()
21 endif()
22
23 if(NOT protobuf_generate_LANGUAGE)
24 set(protobuf_generate_LANGUAGE cpp)
25 endif()
26 string(TOLOWER ${protobuf_generate_LANGUAGE} protobuf_generate_LANGUAGE)
27
28 if(NOT protobuf_generate_PROTOC_OUT_DIR)
29 set(protobuf_generate_PROTOC_OUT_DIR ${CMAKE_CURRENT_BINARY_DIR})
30 endif()
31
32 if(protobuf_generate_EXPORT_MACRO AND protobuf_generate_LANGUAGE STREQUAL cpp)
33 set(_dll_export_decl "dllexport_decl=${protobuf_generate_EXPORT_MACRO}")
34 endif()
35
36 foreach(_option ${_dll_export_decl} ${protobuf_generate_PLUGIN_OPTIONS})
37 # append comma - not using CMake lists and string replacement as users
38 # might have semicolons in options
39 if(_plugin_options)
40 set( _plugin_options "${_plugin_options},")
41 endif()
42 set(_plugin_options "${_plugin_options}${_option}")
43 endforeach()
44
45 if(protobuf_generate_PLUGIN)
46 set(_plugin "--plugin=${protobuf_generate_PLUGIN}")
47 endif()
48
49 if(NOT protobuf_generate_GENERATE_EXTENSIONS)
50 if(protobuf_generate_LANGUAGE STREQUAL cpp)
51 set(protobuf_generate_GENERATE_EXTENSIONS .pb.h .pb.cc)
52 elseif(protobuf_generate_LANGUAGE STREQUAL python)
53 set(protobuf_generate_GENERATE_EXTENSIONS _pb2.py)
54 else()
55 message(SEND_ERROR "Error: protobuf_generate given unknown Language ${LANGUAGE}, please provide a value for GENERATE_EXTENSIONS")
56 return()
57 endif()
58 endif()
59
60 if(protobuf_generate_TARGET)
61 get_target_property(_source_list ${protobuf_generate_TARGET} SOURCES)
62 foreach(_file ${_source_list})
63 if(_file MATCHES "proto$")
64 list(APPEND protobuf_generate_PROTOS ${_file})
65 endif()
66 endforeach()
67 endif()
68
69 if(NOT protobuf_generate_PROTOS)
70 message(SEND_ERROR "Error: protobuf_generate could not find any .proto files")
71 return()
72 endif()
73
74 if(protobuf_generate_APPEND_PATH)
75 # Create an include path for each file specified
76 foreach(_file ${protobuf_generate_PROTOS})
77 get_filename_component(_abs_file ${_file} ABSOLUTE)
78 get_filename_component(_abs_dir ${_abs_file} DIRECTORY)
79 list(FIND _protobuf_include_path ${_abs_dir} _contains_already)
80 if(${_contains_already} EQUAL -1)
81 list(APPEND _protobuf_include_path -I ${_abs_dir})
82 endif()
83 endforeach()
84 endif()
85
86 foreach(DIR ${protobuf_generate_IMPORT_DIRS})
87 get_filename_component(ABS_PATH ${DIR} ABSOLUTE)
88 list(FIND _protobuf_include_path ${ABS_PATH} _contains_already)
89 if(${_contains_already} EQUAL -1)
90 list(APPEND _protobuf_include_path -I ${ABS_PATH})
91 endif()
92 endforeach()
93
94 if(NOT _protobuf_include_path)
95 set(_protobuf_include_path -I ${CMAKE_CURRENT_SOURCE_DIR})
96 endif()
97
98 set(_generated_srcs_all)
99 foreach(_proto ${protobuf_generate_PROTOS})
100 get_filename_component(_abs_file ${_proto} ABSOLUTE)
101 get_filename_component(_abs_dir ${_abs_file} DIRECTORY)
102
103 get_filename_component(_file_full_name ${_proto} NAME)
104 string(FIND "${_file_full_name}" "." _file_last_ext_pos REVERSE)
105 string(SUBSTRING "${_file_full_name}" 0 ${_file_last_ext_pos} _basename)
106
107 set(_suitable_include_found FALSE)
108 foreach(DIR ${_protobuf_include_path})
109 if(NOT DIR STREQUAL "-I")
110 file(RELATIVE_PATH _rel_dir ${DIR} ${_abs_dir})
111 string(FIND "${_rel_dir}" "../" _is_in_parent_folder)
112 if (NOT ${_is_in_parent_folder} EQUAL 0)
113 set(_suitable_include_found TRUE)
114 break()
115 endif()
116 endif()
117 endforeach()
118
119 if(NOT _suitable_include_found)
120 message(SEND_ERROR "Error: protobuf_generate could not find any correct proto include directory.")
121 return()
122 endif()
123
124 set(_generated_srcs)
125 foreach(_ext ${protobuf_generate_GENERATE_EXTENSIONS})
126 list(APPEND _generated_srcs "${protobuf_generate_PROTOC_OUT_DIR}/${_rel_dir}/${_basename}${_ext}")
127 endforeach()
128 list(APPEND _generated_srcs_all ${_generated_srcs})
129
130 set(_comment "Running ${protobuf_generate_LANGUAGE} protocol buffer compiler on ${_proto}")
131 if(protobuf_generate_PROTOC_OPTIONS)
132 set(_comment "${_comment}, protoc-options: ${protobuf_generate_PROTOC_OPTIONS}")
133 endif()
134 if(_plugin_options)
135 set(_comment "${_comment}, plugin-options: ${_plugin_options}")
136 endif()
137
138 add_custom_command(
139 OUTPUT ${_generated_srcs}
140 COMMAND protobuf::protoc
141 ARGS ${protobuf_generate_PROTOC_OPTIONS} --${protobuf_generate_LANGUAGE}_out ${_plugin_options}:${protobuf_generate_PROTOC_OUT_DIR} ${_plugin} ${_protobuf_include_path} ${_abs_file}
142 DEPENDS ${_abs_file} ${protobuf_PROTOC_EXE} ${protobuf_generate_DEPENDENCIES}
143 COMMENT ${_comment}
144 VERBATIM )
145 endforeach()
146
147 set_source_files_properties(${_generated_srcs_all} PROPERTIES GENERATED TRUE)
148 if(protobuf_generate_OUT_VAR)
149 set(${protobuf_generate_OUT_VAR} ${_generated_srcs_all} PARENT_SCOPE)
150 endif()
151 if(protobuf_generate_TARGET)
152 target_sources(${protobuf_generate_TARGET} PRIVATE ${_generated_srcs_all})
153 endif()
154
155 endfunction()