Debian Codegraph @

init/tcsh_completion.in

raw
1 #
2 # Tcsh commandline completion
3 #
4
5 alias _module_avail '\\
6 @TCLSH@ "@libexecdir@/modulecmd.tcl" tcsh avail --color=never -s -t -S -o "alias:indesym" |& cat'
7
8 alias _module_spider '\\
9 @TCLSH@ "@libexecdir@/modulecmd.tcl" tcsh spider --color=never -s -t -S -o "alias:indesym" |& cat'
10
11 alias _module_loaded '\\
12 @TCLSH@ "@libexecdir@/modulecmd.tcl" tcsh list --color=never -s -t -o "" |& cat'
13
14 alias _module_savelist '\\
15 @TCLSH@ "@libexecdir@/modulecmd.tcl" tcsh savelist --color=never -s -t |& sed '"'"'\\
16 /No named collection\.$/d; \\
17 /Named collection list$/d; \\
18 /:$/d; '"'"
19
20 alias _module_stashlist '\\
21 @TCLSH@ "@libexecdir@/modulecmd.tcl" tcsh stashlist --color=never -s -t |& sed '"'"'\\
22 /No stash collection\.$/d; \\
23 /Stash collection list$/d; \\
24 /:$/d; '"'"
25
26 alias _module_not_yet_loaded '\\
27 mkfifo /tmp/modules_tcsh_completion.$$.p1 /tmp/modules_tcsh_completion.$$.p2 && \\
28 ( _module_avail | sort >! /tmp/modules_tcsh_completion.$$.p1 & ); \\
29 ( _module_loaded | sort >! /tmp/modules_tcsh_completion.$$.p2 & ); \\
30 comm -23 /tmp/modules_tcsh_completion.$$.p1 /tmp/modules_tcsh_completion.$$.p2; \\
31 \rm /tmp/modules_tcsh_completion.$$.p1 /tmp/modules_tcsh_completion.$$.p2'
32
33 alias _module_modulepath 'echo ${MODULEPATH} | sed '"'"'s/:/\n/g;'"'"' '
34
35 complete module 'C,/*,f,' 'C,.*,f,' 'C,~/*,f,' \
36 'n/help/`_module_avail`/' \
37 'n/add/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
38 'n/load/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
39 'n/add-any/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
40 'n/load-any/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
41 'n/try-add/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
42 'n/try-load/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
43 'n/rm/`_module_loaded; echo "@comp_unload_opts@"`/' \
44 'n/del/`_module_loaded; echo "@comp_unload_opts@"`/' \
45 'n/remove/`_module_loaded; echo "@comp_unload_opts@"`/' \
46 'n/unload/`_module_loaded; echo "@comp_unload_opts@"`/' \
47 'n/swap/`_module_loaded; echo "@comp_load_opts@"`/' \
48 'N/swap/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
49 'n/switch/`_module_loaded; echo "@comp_load_opts@"`/' \
50 'N/switch/`_module_not_yet_loaded; echo "@comp_load_opts@"`/' \
51 'n/show/`_module_avail; echo "@comp_mfile_opts@"`/' \
52 'n/display/`_module_avail; echo "@comp_mfile_opts@"`/' \
53 'n/test/`_module_avail; echo "@comp_mfile_opts@"`/' \
54 "n/list/(@comp_list_opts@)/" \
55 'n/avail/`_module_avail; echo "@comp_avail_opts@"`/' \
56 'n/spider/`_module_spider; echo "@comp_avail_opts@"`/' \
57 'n/is-avail/`_module_avail; echo "@comp_isavail_opts@"`/' \
58 'n/is-loaded/`_module_avail; echo "@comp_mfile_opts@"`/' \
59 'n/info-loaded/`_module_avail; echo "@comp_mfile_opts@"`/' \
60 'n/restore/`_module_savelist`/' \
61 "n/savelist/(@comp_list_opts@)/" \
62 'n/saveshow/`_module_savelist`/' \
63 'n/describe/`_module_savelist`/' \
64 'n/saverm/`_module_savelist`/' \
65 'n/disable/`_module_savelist`/' \
66 'n/save/`_module_savelist`/' \
67 'n/is-saved/`_module_savelist`/' \
68 "n/aliases/(@comp_aliases_opts@)/" \
69 'n/use/d/' \
70 'N/use/d/' \
71 'n/unuse/`_module_modulepath`/' \
72 'n/is-used/`_module_modulepath`/' \
73 'n/purge/n/' \
74 'n/refresh/n/' \
75 'n/reload/n/' \
76 'n/update/n/' \
77 'n/whatis/`_module_avail; echo "@comp_whatis_opts@"`/' \
78 "n/apropos/(@comp_search_opts@)/" \
79 "n/search/(@comp_search_opts@)/" \
80 "n/keyword/(@comp_search_opts@)/" \
81 'n/paths/`_module_avail; echo "@comp_mfile_opts@"`/' \
82 'n/path/`_module_avail; echo "@comp_mfile_opts@"`/' \
83 'n/edit/`_module_avail`/' \
84 'n/sh-to-mod/n/' \
85 'n/source/n/' \
86 'n/initadd/n/' \
87 'n/initprepend/n/' \
88 'n/initrm/n/' \
89 'n/initlist/n/' \
90 'n/initclear/n/' \
91 "n/append-path/(@comp_path_opts@)/" \
92 "n/prepend-path/(@comp_path_opts@)/" \
93 "n/remove-path/(@comp_rm_path_opts@)/" \
94 "n/clear/(@comp_clear_opts@)/" \
95 "n/config/(@comp_config_opts@)/" \
96 "n/state/n/" \
97 'n/lint/`_module_avail; echo "@comp_lint_opts@"`/' \
98 'n/mod-to-sh/`_module_not_yet_loaded; echo "@comp_modtosh_opts@"`/' \
99 "n/reset/n/" \
100 "n/stash/n/" \
101 "n/stashclear/n/" \
102 "n/stashlist/(@comp_stashlist_opts@)/" \
103 'n/stashpop/`_module_stashlist`/' \
104 'n/stashrm/`_module_stashlist`/' \
105 'n/stashshow/`_module_stashlist`/' \
106 'n/cachebuild/d/' \
107 'N/cachebuild/d/' \
108 "n/cacheclear/n/" \
109 "n/--reset/(@comp_config_opts@)/" \
110 'n/-h/n/' \
111 'n/--help/n/' \
112 'n/-V/n/' \
113 'n/--version/n/' \
114 'n/--dumpname/n/' \
115 'C/sw*/(switch)/' \
116 "p/1/(@comp_cmds@ @comp_opts@)/" \
117 "n/-*/(@comp_cmds@)/"
118
119 complete ml \
120 "C/--*/(@comp_long_opts@)/" \
121 'c/-/`_module_loaded`/' \
122 'p/1-/`_module_not_yet_loaded`//'
123