Debian Codegraph @

cmake/modules/FindCPlex.cmake

raw
1 # - Try to find CPLEX
2 # Once done this will define
3 # CPLEX_FOUND - System has CPLEX
4 # CPLEX_INCLUDE_DIRS - The CPLEX include directories
5 # CPLEX_LIBRARIES - The libraries needed to use CPLEX
6 # CPLEX_COMPILE_FLAGS - The definitions required to compile with CPLEX
7 # User can set CPlex_ROOT to the preferred installation prefix
8
9 set(CPLEX_COMPILE_FLAGS "-fPIC -fno-strict-aliasing -fexceptions")
10
11 set(CPLEX_VERSIONS 1210 129 128 1271 127 1263 1262 1261 126 201)
12
13 foreach(VERSION ${CPLEX_VERSIONS})
14 list(APPEND CPLEX_DEFAULT_LOC "/opt/ibm/ILOG/CPLEX_Studio${VERSION}")
15 list(APPEND CPLEX_DEFAULT_LOC "/opt/IBM/ILOG/CPLEX_Studio${VERSION}")
16 list(APPEND CPLEX_DEFAULT_LOC "C:\\Program Files\\IBM\\ILOG\\CPLEX_Studio${VERSION}")
17 list(APPEND CPLEX_DEFAULT_LOC "C:\\Program Files (x86)\\IBM\\ILOG\\CPLEX_Studio${VERSION}")
18 list(APPEND CPLEX_DEFAULT_LOC "$ENV{HOME}/Applications/IBM/ILOG/CPLEX_Studio${VERSION}")
19 list(APPEND CPLEX_DEFAULT_LOC "/Applications/IBM/ILOG/CPLEX_Studio${VERSION}")
20 list(APPEND CPLEX_DEFAULT_LOC "/Applications/CPLEX_Studio${VERSION}")
21
22 list(APPEND CPLEX_LIB_NAMES cplex${VERSION})
23 endforeach(VERSION)
24
25 find_path(CPLEX_INCLUDE ilcplex/cplex.h
26 HINTS ${CPLEX_DEFAULT_LOC}
27 PATH_SUFFIXES include cplex/include)
28
29 if(NOT "${CPLEX_INCLUDE}" STREQUAL "CPLEX_INCLUDE-NOTFOUND")
30 file(READ "${CPLEX_INCLUDE}/ilcplex/cplex.h" CPLEX_CONFIG)
31 string(REGEX MATCH " +\\* +Version +([0-9]+\\.[0-9]+\\.[0-9]+)" _ "${CPLEX_CONFIG}")
32 set(CPLEX_VERSION "${CMAKE_MATCH_1}")
33 unset(CPLEX_CONFIG)
34 endif()
35
36 foreach(CPLEX_LIB ${CPLEX_LIB_NAMES})
37 find_library(CPLEX_LIBRARY NAMES cplex ${CPLEX_LIB}
38 HINTS ${CPLEX_DEFAULT_LOC}
39 PATH_SUFFIXES lib/x86-64_linux/static_pic lib/x86-64_osx/static_pic lib/x64_windows_vs2013/stat_mda cplex/lib/x86-64_linux/static_pic cplex/lib/x86-64_osx/static_pic cplex/lib/x64_windows_vs2013/stat_mda)
40 if(NOT "${CPLEX_LIBRARY}" STREQUAL "CPLEX_LIBRARY-NOTFOUND")
41 break()
42 endif()
43 endforeach(CPLEX_LIB)
44
45 include(FindPackageHandleStandardArgs)
46 # handle the QUIETLY and REQUIRED arguments and set CBC_FOUND to TRUE
47 # if all listed variables are TRUE
48 find_package_handle_standard_args(CPlex
49 FOUND_VAR CPLEX_FOUND
50 REQUIRED_VARS CPLEX_INCLUDE CPLEX_LIBRARY
51 VERSION_VAR CPLEX_VERSION
52 FAIL_MESSAGE "Could NOT find CPlex, use CPlex_ROOT to hint its location"
53 )
54
55 mark_as_advanced(CPLEX_INCLUDE CPLEX_LIBRARY)
56
57 set(CPLEX_LIBRARIES ${CPLEX_LIBRARY})
58 set(CPLEX_INCLUDE_DIRS ${CPLEX_INCLUDE})