Debian Codegraph @

ports/stm32/boards/common_isr_ram/common_isr.ld

raw
1 /* This linker script fragment is intended to be included in SECTIONS. */
2
3 /* The startup code goes first into FLASH */
4 .isr_vector :
5 {
6 . = ALIGN(4);
7 __isr_vector_ram_start = .;
8
9 KEEP(*(.isr_vector)) /* Startup code */
10
11 /* These functions need to run from ram to enable uart
12 reception during flash erase/write operations.
13 Defining them here ensures they're copied from
14 flash (in main.c) along with the isr_vector above.
15 */
16 . = ALIGN(4);
17 *(.text.mp_sched_keyboard_interrupt)
18 *(.text.pendsv_schedule_dispatch)
19 *(.text.storage_systick_callback)
20 *(.text.SysTick_Handler)
21 *(.text.uart_irq_handler)
22 *(.text.UART*_IRQHandler)
23 *(.text.USART*_IRQHandler)
24 *(.text.FLASH_PageErase)
25 *(.text.FLASH_SectorErase)
26 *(.text.FLASH_WaitForLastOperation)
27 *(.text.HAL_FLASHEx_Erase)
28 *(.text.HAL_GetTick)
29
30 __isr_vector_ram_end = .;
31 . = ALIGN(4);
32
33 } >RAM AT >FLASH_ISR
34
35 /* Used by the start-up code to initialise data */
36 __isr_vector_flash_addr = LOADADDR(.isr_vector);