Debian Codegraph @

ports/stm32/boards/ARDUINO_NICLA_VISION/stm32h747.ld

raw
1 /*
2 GNU linker script for STM32H747
3 */
4
5 /* Specify the memory areas */
6 MEMORY
7 {
8 ITCM (xrw) : ORIGIN = 0x00000000, LENGTH = 64K
9 DTCM (xrw) : ORIGIN = 0x20000000, LENGTH = 128K
10 RAM (xrw) : ORIGIN = 0x24000000, LENGTH = 512K /* AXI SRAM D1 */
11 SRAM1 (xrw) : ORIGIN = 0x30000000, LENGTH = 128K /* SRAM1 D2 */
12 SRAM2 (xrw) : ORIGIN = 0x30020000, LENGTH = 128K /* SRAM2 D2 */
13 SRAM3 (xrw) : ORIGIN = 0x30040000, LENGTH = 32K /* SRAM3 D2 */
14 SRAM4 (xrw) : ORIGIN = 0x38000000, LENGTH = 64K /* SRAM4 D3 */
15 FLASH (rx) : ORIGIN = 0x08000000, LENGTH = 2048K /* Total available flash */
16 FLASH_BL (rx) : ORIGIN = 0x08000000, LENGTH = 128K /* Arduino bootloader */
17 FLASH_FS (r) : ORIGIN = 0x08020000, LENGTH = 128K /* filesystem */
18 FLASH_TEXT (rx) : ORIGIN = 0x08040000, LENGTH = 1280K /* CM7 firmware */
19 FLASH_CM4 (rx) : ORIGIN = 0x08180000, LENGTH = 512K /* CM4 firmware */
20 FLASH_ROMFS (rx) : ORIGIN = 0x90B00000, LENGTH = 4096K /* romfs partition in QSPI flash */
21 }
22
23 _cm4_ram_start = ORIGIN(SRAM4);
24
25 /* produce a link error if there is not this amount of RAM for these sections */
26 _minimum_stack_size = 2K;
27 _minimum_heap_size = 16K;
28
29 /* Define the stack. The stack is full descending so begins just above last byte
30 of RAM. Note that EABI requires the stack to be 8-byte aligned for a call. */
31 _estack = ORIGIN(RAM) + LENGTH(RAM) - _estack_reserve;
32 _sstack = _estack - 16K; /* tunable */
33
34 /* RAM extents for the garbage collector */
35 _ram_start = ORIGIN(RAM);
36 _ram_end = ORIGIN(RAM) + LENGTH(RAM);
37 _heap_start = _ebss; /* heap starts just after statically allocated memory */
38 _heap_end = _sstack;
39
40 /* Note the following varilables are only used if the filesystem flash storage is enabled */
41 /* Location of filesystem RAM cache */
42 _micropy_hw_internal_flash_storage_ram_cache_start = ORIGIN(DTCM);
43 _micropy_hw_internal_flash_storage_ram_cache_end = ORIGIN(DTCM) + LENGTH(DTCM);
44
45 /* Location of filesystem flash storage */
46 _micropy_hw_internal_flash_storage_start = ORIGIN(FLASH_FS);
47 _micropy_hw_internal_flash_storage_end = ORIGIN(FLASH_FS) + LENGTH(FLASH_FS);
48
49 /* Location of romfs filesystem */
50 _micropy_hw_romfs_part0_start = ORIGIN(FLASH_ROMFS);
51 _micropy_hw_romfs_part0_size = LENGTH(FLASH_ROMFS);
52
53 /* OpenAMP shared memory region */
54 _openamp_shm_region_start = ORIGIN(SRAM4);
55 _openamp_shm_region_end = ORIGIN(SRAM4) + LENGTH(SRAM4);
56
57 INCLUDE common_blifs.ld