Debian Codegraph @

data/syntax-highlighting/vim/syntax/meson.vim

raw
1 " Vim syntax file
2 " Language: Meson
3 " License: VIM License
4 " Maintainer: Nirbheek Chauhan <[email protected]>
5 " Liam Beguin <[email protected]>
6 " Last Change: 2023 Aug 27
7 " Credits: Zvezdan Petkovic <[email protected]>
8 " Neil Schemenauer <[email protected]>
9 " Dmitry Vasiliev
10 "
11 " This version is copied and edited from python.vim
12 " It's very basic, and doesn't do many things I'd like it to
13 " For instance, it should show errors for syntax that is valid in
14 " Python but not in Meson.
15 "
16 " Optional highlighting can be controlled using these variables.
17 "
18 " let meson_space_error_highlight = 1
19 "
20
21 if exists("b:current_syntax")
22 finish
23 endif
24
25 " We need nocompatible mode in order to continue lines with backslashes.
26 " Original setting will be restored.
27 let s:cpo_save = &cpo
28 set cpo&vim
29
30 " https://mesonbuild.com/Syntax.html
31 syn keyword mesonConditional elif else if endif
32 syn keyword mesonRepeat foreach endforeach
33 syn keyword mesonOperator and not or in
34 syn keyword mesonStatement continue break
35
36 syn match mesonComment "#.*$" contains=mesonTodo,@Spell
37 syn keyword mesonTodo FIXME NOTE NOTES TODO XXX contained
38
39 " Strings can either be single quoted or triple counted across multiple lines,
40 " but always with a '
41 syn region mesonString
42 \ start="\z('\)" end="\z1" skip="\\\\\|\\\z1"
43 \ contains=mesonEscape,@Spell
44 syn region mesonString
45 \ start="\z('''\)" end="\z1" keepend
46 \ contains=mesonEscape,mesonSpaceError,@Spell
47
48 syn match mesonEscape "\\[abfnrtv'\\]" contained
49 syn match mesonEscape "\\\o\{1,3}" contained
50 syn match mesonEscape "\\x\x\{2}" contained
51 syn match mesonEscape "\%(\\u\x\{4}\|\\U\x\{8}\)" contained
52 " Meson allows case-insensitive Unicode IDs: http://www.unicode.org/charts/
53 syn match mesonEscape "\\N{\a\+\%(\s\a\+\)*}" contained
54 syn match mesonEscape "\\$"
55
56 " Meson only supports integer numbers
57 " https://mesonbuild.com/Syntax.html#numbers
58 syn match mesonNumber "\<\d\+\>"
59 syn match mesonNumber "\<0x\x\+\>"
60 syn match mesonNumber "\<0o\o\+\>"
61
62 " booleans
63 syn keyword mesonBoolean false true
64
65 " Built-in functions
66 syn keyword mesonBuiltin
67 \ build_machine
68 \ host_machine
69 \ meson
70 \ option
71 \ target_machine
72 \ add_global_arguments
73 \ add_global_link_arguments
74 \ add_languages
75 \ add_project_arguments
76 \ add_project_dependencies
77 \ add_project_link_arguments
78 \ add_test_setup
79 \ alias_target
80 \ assert
81 \ benchmark
82 \ both_libraries
83 \ build_target
84 \ configuration_data
85 \ configure_file
86 \ custom_target
87 \ debug
88 \ declare_dependency
89 \ dependency
90 \ disabler
91 \ environment
92 \ error
93 \ executable
94 \ files
95 \ find_program
96 \ generator
97 \ get_option
98 \ get_variable
99 \ import
100 \ include_directories
101 \ install_data
102 \ install_emptydir
103 \ install_headers
104 \ install_man
105 \ install_subdir
106 \ install_symlink
107 \ is_disabler
108 \ is_variable
109 \ jar
110 \ join_paths
111 \ library
112 \ message
113 \ project
114 \ range
115 \ run_command
116 \ run_target
117 \ set_variable
118 \ shared_library
119 \ shared_module
120 \ static_library
121 \ structured_sources
122 \ subdir
123 \ subdir_done
124 \ subproject
125 \ summary
126 \ test
127 \ unset_variable
128 \ vcs_tag
129 \ warning
130
131 if exists("meson_space_error_highlight")
132 " trailing whitespace
133 syn match mesonSpaceError display excludenl "\s\+$"
134 " mixed tabs and spaces
135 syn match mesonSpaceError display " \+\t"
136 syn match mesonSpaceError display "\t\+ "
137 endif
138
139 " The default highlight links. Can be overridden later.
140 hi def link mesonStatement Statement
141 hi def link mesonConditional Conditional
142 hi def link mesonRepeat Repeat
143 hi def link mesonOperator Operator
144 hi def link mesonComment Comment
145 hi def link mesonTodo Todo
146 hi def link mesonString String
147 hi def link mesonEscape Special
148 hi def link mesonNumber Number
149 hi def link mesonBuiltin Function
150 hi def link mesonBoolean Boolean
151 if exists("meson_space_error_highlight")
152 hi def link mesonSpaceError Error
153 endif
154
155 let b:current_syntax = "meson"
156
157 let &cpo = s:cpo_save
158 unlet s:cpo_save
159
160 " vim:set sw=2 sts=2 ts=8 noet: