Debian Codegraph @

src/CMakeLists.txt

raw
1 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS 1)
2
3 # Handle absolute include and lib dirs outside of CMAKE_INSTALL_PREFIX
4 include(JoinPaths.cmake) # can be replaced by cmake_path(APPEND) in CMake 3.20
5 join_paths(PKGCONFIG_INCLUDEDIR "\${prefix}" "${CMAKE_INSTALL_INCLUDEDIR}")
6 join_paths(PKGCONFIG_LIBDIR "\${prefix}" "${CMAKE_INSTALL_LIBDIR}")
7
8 # Build rules for MD4C parser library
9
10 configure_file(md4c.pc.in md4c.pc @ONLY)
11 add_library(md4c md4c.c md4c.h)
12 target_include_directories(md4c PUBLIC
13 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
14 "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
15 )
16 target_compile_definitions(md4c PRIVATE "$<$<CONFIG:Debug>:DEBUG>")
17 set_target_properties(md4c PROPERTIES
18 VERSION ${PROJECT_VERSION}
19 SOVERSION ${PROJECT_VERSION_MAJOR}
20 PUBLIC_HEADER md4c.h
21 )
22
23 # Build rules for HTML renderer library
24
25 configure_file(md4c-html.pc.in md4c-html.pc @ONLY)
26 add_library(md4c-html md4c-html.c md4c-html.h entity.c entity.h)
27 target_include_directories(md4c-html PUBLIC
28 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
29 "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
30 )
31 set_target_properties(md4c-html PROPERTIES
32 VERSION ${PROJECT_VERSION}
33 SOVERSION ${PROJECT_VERSION_MAJOR}
34 PUBLIC_HEADER md4c-html.h
35 )
36 target_link_libraries(md4c-html PUBLIC md4c)
37
38
39 # Install rules
40
41 install(
42 TARGETS md4c
43 EXPORT md4cConfig
44 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
45 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
46 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
47 PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
48 )
49 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/md4c.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
50
51 install(
52 TARGETS md4c-html
53 EXPORT md4cConfig
54 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
55 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
56 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
57 PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
58 )
59 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/md4c-html.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
60
61 install(EXPORT md4cConfig DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/md4c/ NAMESPACE md4c::)