Debian Codegraph @

modules/Lomiri/Components/Extras/qml5/Example/Printers.qml

raw
1 /*
2 * Copyright 2017 Canonical Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU Lesser General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU Lesser General Public License for more details.
12 *
13 * You should have received a copy of the GNU Lesser General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 *
16 * Authored by Jonas G. Drange <[email protected]>
17 */
18
19 import QtQuick 2.4
20 import QtQuick.Layouts 1.1
21 import Lomiri.Components 1.3
22 import Lomiri.Components.Popups 1.3
23 import Lomiri.Components.ListItems 1.3 as ListItems
24 import Lomiri.Components.Extras.Printers 0.1
25
26 MainView {
27 width: units.gu(50)
28 height: units.gu(90)
29
30 Component {
31 id: printerPage
32
33 Page {
34 visible: false
35 property var printer
36 header: PageHeader {
37 id: printerPageHeader
38 title: printer.name
39 flickable: printerFlickable
40 }
41
42 Component {
43 id: printerPageNotYetLoaded
44
45 Item {
46 anchors.fill: parent
47 ActivityIndicator {
48 anchors.centerIn: parent
49 running: true
50 }
51 }
52 }
53
54 Flickable {
55 id: printerFlickable
56 anchors.fill: parent
57 contentHeight: contentItem.childrenRect.height
58 Loader {
59 id: printerPageBitsLoader
60 anchors {
61 left: parent.left
62 right: parent.right
63 }
64
65 sourceComponent: printer.isLoaded ? printerPageLoaded : printerPageNotYetLoaded
66 }
67 }
68
69 Component {
70 id: printerPageLoaded
71
72 Column {
73 height: childrenRect.height + anchors.topMargin
74 anchors {
75 top: parent.top
76 topMargin: units.gu(2)
77 left: parent.left
78 right: parent.right
79 }
80
81 ListItems.Standard {
82 anchors {
83 left: parent.left
84 right: parent.right
85 }
86 text: "Enabled"
87
88 control: Switch {
89 checked: printer.printerEnabled
90 onCheckedChanged: printer.printerEnabled = checked
91 }
92 }
93
94 ListItems.SingleValue {
95 anchors {
96 left: parent.left
97 right: parent.right
98 }
99 text: "Status"
100
101 value: {
102 var state;
103 if (printer.state == PrinterEnum.IdleState) {
104 state = i18n.tr("Idle");
105 } else if (printer.state == PrinterEnum.AbortedState) {
106 state = i18n.tr("Aborted");
107 } else if (printer.state == PrinterEnum.ActiveState) {
108 state = i18n.tr("Active");
109 } else if (printer.state == PrinterEnum.ErrorState) {
110 state = i18n.tr("Stopped");
111 }
112 return "%1 — %2"
113 .arg(state)
114 .arg(printer.lastMessage ?
115 printer.lastMessage : i18n.tr("No messages"));
116 }
117 }
118
119 ListItems.Standard {
120 anchors {
121 left: parent.left
122 right: parent.right
123 }
124 text: "Accepting jobs"
125
126 control: Switch {
127 checked: printer.acceptJobs
128 onCheckedChanged: printer.acceptJobs = checked
129 }
130 }
131
132 ListItems.Standard {
133 anchors {
134 left: parent.left
135 right: parent.right
136 }
137 text: "Shared"
138
139 control: Switch {
140 checked: printer.shared
141 onCheckedChanged: printer.shared = checked
142 }
143 }
144
145 ListItems.Standard {
146 anchors {
147 left: parent.left
148 right: parent.right
149 }
150 text: "Jobs"
151 progression: true
152 onClicked: pageStack.push(jobPage, { printer: printer })
153 }
154
155 ListItems.Standard {
156 anchors {
157 left: parent.left
158 right: parent.right
159 }
160 text: "Description"
161
162 control: TextField {
163 anchors {
164 margins: units.gu(1)
165 left: parent.left
166 right: parent.right
167
168 }
169 text: printer.description
170 onTextChanged: printer.description = text
171 }
172 }
173
174 ListItems.Standard {
175 anchors {
176 left: parent.left
177 right: parent.right
178 }
179 text: "Copies"
180
181 control: TextField {
182 id: copiesField
183 inputMethodHints: Qt.ImhDigitsOnly
184 text: printer.copies
185 validator: IntValidator {
186 bottom: 1
187 top: 999
188 }
189 width: units.gu(10)
190 onTextChanged: printer.copies = text
191 }
192
193 }
194
195
196 ListItems.ValueSelector {
197 anchors {
198 left: parent.left
199 right: parent.right
200 }
201 enabled: values.length > 1
202 text: "Duplex"
203 values: printer.supportedDuplexModes
204 onSelectedIndexChanged: printer.duplexMode = selectedIndex
205 Component.onCompleted: {
206 if (enabled) {
207 selectedIndex = printer.duplexMode
208 }
209 }
210 }
211
212 ListItems.ValueSelector {
213 anchors {
214 left: parent.left
215 right: parent.right
216 }
217 text: "Page size"
218 values: printer.supportedPageSizes
219 onSelectedIndexChanged: printer.pageSize = selectedIndex
220 Component.onCompleted: selectedIndex = printer.supportedPageSizes.indexOf(printer.pageSize)
221 }
222
223 ListItems.ValueSelector {
224 anchors {
225 left: parent.left
226 right: parent.right
227 }
228 visible: printer.supportedColorModels.length
229 text: "Color model"
230 values: printer.supportedColorModels
231 enabled: values.length > 1
232 onSelectedIndexChanged: printer.colorModel = selectedIndex
233 Component.onCompleted: {
234 if (enabled)
235 selectedIndex = printer.colorModel
236 }
237 }
238
239 ListItems.ValueSelector {
240 anchors {
241 left: parent.left
242 right: parent.right
243 }
244 visible: printer.supportedPrintQualities.length
245 text: "Quality"
246 values: printer.supportedPrintQualities
247 enabled: values.length > 1
248 onSelectedIndexChanged: printer.printQuality = selectedIndex
249 Component.onCompleted: {
250 if (enabled)
251 selectedIndex = printer.printQuality
252 }
253 }
254
255 ListItems.SingleControl {
256 anchors {
257 left: parent.left
258 right: parent.right
259 }
260 control: Button {
261 text: "Print test page"
262 onClicked: Printers.printTestPage(printer.name)
263 }
264 }
265
266 ListItems.SingleValue {
267 anchors {
268 left: parent.left
269 right: parent.right
270 }
271 text: "Device URI"
272 value: printer.deviceUri
273 }
274 }
275 }
276 }
277 }
278
279 Component {
280 id: jobDelegate
281
282 ListItem {
283 height: modelLayout.height + (divider.visible ? divider.height : 0)
284 trailingActions: ListItemActions {
285 actions: [
286 Action {
287 iconName: model.held ? "media-playback-start" : "media-playback-pause"
288 text: model.held ? "Release" : "Hold"
289
290 onTriggered: {
291 if (model.held) {
292 Printers.releaseJob(model.printerName, model.id);
293 } else {
294 Printers.holdJob(model.printerName, model.id);
295 }
296 }
297 },
298 Action {
299 iconName: "cancel"
300 text: "Cancel"
301
302 onTriggered: Printers.cancelJob(model.printerName, model.id);
303 }
304 ]
305 }
306
307 ListItemLayout {
308 id: modelLayout
309 title.text: displayName
310 subtitle.text: "Printing " + model.impressionsCompleted + " pages" + "\n" + model.printerName
311 subtitle.wrapMode: Text.WrapAtWordBoundaryOrAnywhere
312 subtitle.maximumLineCount: 3
313 }
314 }
315 }
316
317 Component {
318 id: jobPage
319 Page {
320 property var printer
321 header: PageHeader {
322 id: jobPageHeader
323 title: "%1 (%2 jobs)".arg(printer.name).arg(jobList.count)
324 flickable: jobList
325 }
326
327 ListView {
328 id: jobList
329 anchors.fill: parent
330 model: printer.jobs
331 delegate: jobDelegate
332 }
333 }
334 }
335
336 Component {
337 id: allJobsPage
338 Page {
339 header: PageHeader {
340 id: allJobsHeader
341 title: "Printer jobs"
342 flickable: jobsList
343 }
344
345 ListView {
346 id: jobsList
347 anchors.fill: parent
348 model: Printers.printJobs
349 delegate: jobDelegate
350 }
351 }
352 }
353
354
355 PageStack {
356 id: pageStack
357
358 Component.onCompleted: push(printersPage)
359
360 Page {
361 id: printersPage
362 header: PageHeader {
363 title: "Printers"
364 flickable: printerList
365 trailingActionBar {
366 actions: [
367 Action {
368 iconName: "add"
369 text: "Add printer"
370 onTriggered: pageStack.push(addPrinterPageComponent)
371 },
372 Action {
373 iconName: "document-print"
374 text: "Printer jobs"
375 onTriggered: pageStack.push(allJobsPage)
376 }
377 ]
378 }
379 }
380 visible: false
381
382 ListView {
383 id: printerList
384 anchors { fill: parent }
385 model: Printers.allPrintersWithPdf
386 delegate: ListItem {
387 height: modelLayout.height + (divider.visible ? divider.height : 0)
388 trailingActions: ListItemActions {
389 actions: [
390 Action {
391 iconName: "delete"
392 onTriggered: {
393 if (!Printers.removePrinter(model.name)) {
394 console.error('failed to remove printer', Printers.lastMessage);
395 }
396 }
397 },
398 Action {
399 iconName: model.default ? "starred" : "non-starred"
400 enabled: !model.default
401 onTriggered: Printers.defaultPrinterName = model.name
402 }
403
404 ]
405 }
406 ListItemLayout {
407 id: modelLayout
408 title.text: displayName
409 title.font.bold: model.default
410
411 Icon {
412 id: icon
413 width: height
414 height: units.gu(2.5)
415 name: "printer-symbolic"
416 SlotsLayout.position: SlotsLayout.First
417 }
418
419 ProgressionSlot {}
420 }
421 onClicked: {
422 Printers.loadPrinter(model.name);
423 pageStack.push(printerPage, { printer: model });
424 }
425 }
426 }
427
428 Label {
429 anchors.centerIn: parent
430 visible: printerList.count === 0
431 text: "No printers found"
432 }
433 }
434 }
435
436 Component {
437 id: addPrinterPageComponent
438 Page {
439 id: addPrinterPage
440 states: [
441 State {
442 name: "success"
443 PropertyChanges {
444 target: okAction
445 enabled: false
446 }
447 PropertyChanges {
448 target: closeAction
449 enabled: false
450 }
451 PropertyChanges {
452 target: addPrinterCol
453 enabled: false
454 }
455 StateChangeScript {
456 script: okTimer.start()
457 }
458 },
459 State {
460 name: "failure"
461 PropertyChanges {
462 target: errorMessageContainer
463 visible: true
464 }
465 }
466 ]
467 header: PageHeader {
468 title: "Add printer"
469 flickable: addPrinterFlickable
470 leadingActionBar.actions: [
471 Action {
472 id: closeAction
473 iconName: "close"
474 text: "Abort"
475 onTriggered: pageStack.pop()
476 }
477 ]
478 trailingActionBar {
479 actions: [
480 Action {
481 id: okAction
482 iconName: "ok"
483 text: "Complete"
484 onTriggered: {
485 var ret;
486 if (driverSelector.selectedIndex == 0) {
487 ret = Printers.addPrinter(
488 printerName.text,
489 driversView.selectedDriver,
490 printerUri.text,
491 printerDescription.text,
492 printerLocation.text
493 );
494 } else {
495 ret = Printers.addPrinterWithPpdFile(
496 printerName.text,
497 printerPpd.text,
498 printerUri.text,
499 printerDescription.text,
500 printerLocation.text
501 );
502 }
503 if (ret) {
504 addPrinterPage.state = "success"
505 } else {
506 errorMessage.text = Printers.lastMessage;
507 addPrinterPage.state = "failure"
508 }
509 }
510 }
511 ]
512 }
513 }
514
515 Component.onCompleted: Printers.prepareToAddPrinter()
516
517 Timer {
518 id: okTimer
519 interval: 2000
520 onTriggered: pageStack.pop();
521 }
522
523 Flickable {
524 id: addPrinterFlickable
525 anchors.fill: parent
526 contentHeight: contentItem.childrenRect.height
527
528 Column {
529 id: addPrinterCol
530 property bool enabled: true
531 anchors { left: parent.left; right: parent.right }
532
533 Item {
534 id: errorMessageContainer
535 visible: false
536 anchors {
537 left: parent.left
538 right: parent.right
539 margins: units.gu(2)
540 }
541 height: units.gu(6)
542 Label {
543 id: errorMessage
544 anchors {
545 top: parent.top
546 topMargin: units.gu(2)
547 horizontalCenter: parent.horizontalCenter
548 }
549 }
550
551 }
552
553 ListItems.Standard {
554 text: "Device URI"
555 control: TextField {
556 id: printerUri
557 placeholderText: "ipp://server.local/my-queue"
558 }
559 enabled: parent.enabled
560 }
561
562 ListItems.ValueSelector {
563 id: driverSelector
564 anchors { left: parent.left; right: parent.right }
565 text: "Choose driver"
566 values: [
567 "Select printer from database",
568 "Provide PPD file"
569 ]
570 enabled: parent.enabled
571 }
572
573 ListItems.Standard {
574 anchors { left: parent.left; right: parent.right }
575 text: "Filter drivers"
576 control: TextField {
577 id: driverFilter
578 onTextChanged: Printers.driverFilter = text
579 }
580 visible: driverSelector.selectedIndex == 0
581 enabled: parent.enabled
582 }
583
584 ListView {
585 id: driversView
586 property string selectedDriver
587 property bool loading: true
588 visible: driverSelector.selectedIndex == 0
589 model: Printers.drivers
590 anchors { left: parent.left; right: parent.right }
591 height: units.gu(30)
592 clip: true
593 enabled: parent.enabled
594 highlightFollowsCurrentItem: false
595 highlight: Rectangle {
596 z: 0
597 y: driversView.currentItem.y
598 width: driversView.currentItem.width
599 height: driversView.currentItem.height
600 color: theme.palette.selected.background
601 }
602 delegate: ListItem {
603 height: driverLayout.height + (divider.visible ? divider.height : 0)
604 ListItemLayout {
605 id: driverLayout
606 title.text: displayName
607 subtitle.text: name
608 summary.text: deviceId
609 }
610 onClicked: {
611 driversView.selectedDriver = name
612 driversView.currentIndex = index
613 }
614 }
615
616 ActivityIndicator {
617 anchors.centerIn: parent
618 running: parent.loading
619 }
620
621 Connections {
622 target: driversView
623 onCountChanged: {
624 target = null;
625 driversView.loading = false;
626 }
627 }
628 }
629
630 ListItems.Standard {
631 text: "PPD File"
632 visible: driverSelector.selectedIndex == 1
633 control: TextField {
634 id: printerPpd
635 placeholderText: "/usr/share/cups/foo.ppd"
636 }
637 enabled: parent.enabled
638 }
639
640 ListItems.Standard {
641 anchors { left: parent.left; right: parent.right }
642 text: "Printer name"
643 control: TextField {
644 id: printerName
645 placeholderText: "laserjet"
646 }
647 enabled: parent.enabled
648 }
649
650 ListItems.Standard {
651 anchors { left: parent.left; right: parent.right }
652 text: "Description (optional)"
653 control: TextField {
654 id: printerDescription
655 placeholderText: "HP Laserjet with Duplexer"
656 }
657 enabled: parent.enabled
658 }
659
660 ListItems.Standard {
661 anchors { left: parent.left; right: parent.right }
662 text: "Location (optional)"
663 control: TextField {
664 id: printerLocation
665 placeholderText: "Lab 1"
666 }
667 enabled: parent.enabled
668 }
669 }
670
671 Label {
672 id: remotePrintersLabel
673 anchors {
674 left: parent.left
675 right: parent.right
676 margins: units.gu(2)
677 top: addPrinterCol.bottom
678 }
679 text: "Other printers"
680
681 ActivityIndicator {
682 id: remotePrintersSearchIndicator
683 anchors {
684 right: parent.right
685 verticalCenter: parent.verticalCenter
686 }
687 property var target
688 Component.onCompleted: target = Printers.devices
689 running: target.searching
690 }
691 }
692
693 ListView {
694 id: remotePrintersList
695 anchors {
696 left: parent.left
697 right: parent.right
698 top: remotePrintersLabel.bottom
699 topMargin: units.gu(2)
700 }
701 height: contentItem.childrenRect.height
702 model: Printers.devices
703 delegate: ListItem {
704 height: modelLayout.height + (divider.visible ? divider.height : 0)
705 ListItemLayout {
706 id: modelLayout
707 title.text: displayName
708 subtitle.text: {
709 if (type == PrinterEnum.LPDType) return "LPD";
710 if (type == PrinterEnum.IppSType) return "IppS";
711 if (type == PrinterEnum.Ipp14Type) return "Ipp14";
712 if (type == PrinterEnum.HttpType) return "Http";
713 if (type == PrinterEnum.BehType) return "Beh";
714 if (type == PrinterEnum.SocketType) return "Socket";
715 if (type == PrinterEnum.HttpsType) return "Https";
716 if (type == PrinterEnum.IppType) return "Ipp";
717 if (type == PrinterEnum.HPType) return "HP";
718 if (type == PrinterEnum.USBType) return "USB";
719 if (type == PrinterEnum.HPFaxType) return "HPFax";
720 if (type == PrinterEnum.DNSSDType) return "DNSSD";
721 else return "Unknown protocol";
722 }
723
724 Icon {
725 id: icon
726 width: height
727 height: units.gu(2.5)
728 name: "network-printer-symbolic"
729 SlotsLayout.position: SlotsLayout.First
730 }
731
732 Button {
733 text: "Select printer"
734 onClicked: {
735 var suggestedPrinterName = (" " + displayName).slice(1);
736 suggestedPrinterName = suggestedPrinterName.replace(/\ /g, "\-");
737 printerUri.text = uri;
738 printerName.text = suggestedPrinterName;
739 printerDescription.text = info;
740 printerLocation.text = location;
741 }
742 }
743 }
744 }
745 }
746
747 Label {
748 anchors {
749 left: parent.left
750 right: parent.right
751 top: remotePrintersLabel.bottom
752 topMargin: units.gu(2)
753 }
754 text: "No other printers found"
755 visible: !remotePrintersSearchIndicator.running && remotePrintersList.count == 0
756 }
757 }
758 }
759 }
760 }