Debian Codegraph @

src/imports/Lomiri/AddressBook/ContactEditor/ComboButtonAddField.qml

raw
1 /*
2 * Copyright (C) 2012-2014 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
16
17 import QtQuick 2.4
18 import QtContacts 5.0
19
20 import Lomiri.Components 1.3
21 import Lomiri.Components.ListItems 1.3
22
23 ComboButton {
24 id: root
25
26 property QtObject contact: null
27 property int selectedDetail: -1
28 readonly property var validDetails: [ ContactDetail.PhoneNumber,
29 ContactDetail.Email,
30 ContactDetail.Address,
31 ContactDetail.Birthday,
32 ContactDetail.OnlineAccount,
33 ContactDetail.Organization,
34 ContactDetail.Note,
35 ContactDetail.Url,
36 ContactDetail.Ringtone
37 ]
38 property var singleValueDetails: []
39 readonly property var specialFields: {
40 "CONTACT_DETAIL_MIDDLE_NAME": 1000
41 }
42
43 signal fieldSelected(var detailType, string fieldName, string qmlTypeName)
44 signal specialFieldSelected(string fieldName, int type)
45
46 function nameFromEnum(value)
47 {
48 switch (value)
49 {
50 case ContactDetail.PhoneNumber:
51 return i18n.dtr("lomiri-addressbook-app", "Phone")
52 case ContactDetail.Email:
53 return i18n.dtr("lomiri-addressbook-app", "Email")
54 case ContactDetail.Address:
55 return i18n.dtr("lomiri-addressbook-app", "Address")
56 case ContactDetail.OnlineAccount:
57 return i18n.dtr("lomiri-addressbook-app", "Social")
58 case ContactDetail.Organization:
59 return i18n.dtr("lomiri-addressbook-app", "Professional Details")
60 case ContactDetail.Birthday:
61 return i18n.dtr("lomiri-addressbook-app", "Birthday")
62 case ContactDetail.Note:
63 return i18n.dtr("lomiri-addressbook-app", "Note")
64 case ContactDetail.Ringtone:
65 return i18n.dtr("lomiri-addressbook-app", "Ringtone")
66 case ContactDetail.Url:
67 return i18n.dtr("lomiri-addressbook-app", "Web address")
68 // special cases
69 case root.specialFields.CONTACT_DETAIL_MIDDLE_NAME:
70 return i18n.dtr("lomiri-addressbook-app", "Middle Name")
71 default:
72 console.error("Invalid contact detail enum value:" + value)
73 return ""
74 }
75 }
76
77 function qmlTypeFromEnum(value)
78 {
79 switch (value)
80 {
81 case ContactDetail.PhoneNumber:
82 return "PhoneNumber"
83 case ContactDetail.Email:
84 return "EmailAddress"
85 case ContactDetail.Address:
86 return "Address"
87 case ContactDetail.OnlineAccount:
88 return "OnlineAccount"
89 case ContactDetail.Organization:
90 return "Organization"
91 case ContactDetail.Birthday:
92 return "Birthday"
93 case ContactDetail.Ringtone:
94 return "Ringtone"
95 default:
96 console.error("Invalid contact detail enum value:" + value)
97 return ""
98 }
99 }
100
101 // check which details will be allowed to create
102 // some details we only support one value
103 function filterSingleDetails(details, contact)
104 {
105 var result = []
106 if (contact) {
107 // Handle special cases
108 // MiddleName: Only allow to add middle name if the field is empty
109 var nameDet = contact.detail(ContactDetail.Name)
110 if (nameDet && (nameDet.value(Name.MiddleName) === undefined)) {
111 result.push(root.specialFields.CONTACT_DETAIL_MIDDLE_NAME)
112 }
113
114 for(var i=0; i < details.length; i++) {
115 var det = details[i]
116 const editComponent = singleValueDetails.find(detailEditor => detailEditor.detailType === det);
117 if (editComponent) {
118 if (editComponent.isEmpty && editComponent.isEmpty()) {
119 result.push(det)
120 }
121 } else {
122 result.push(det)
123 }
124 }
125 }
126 return result
127 }
128
129 collapsedHeight: units.gu(4)
130 implicitHeight: expanded ? expandedHeight : collapsedHeight
131 onClicked: expanded = !expanded
132
133 // make sure that the signal will be fired after the item collapse
134 onHeightChanged: {
135 if (!expanded && (selectedDetail !== -1) && (height === collapsedHeight)) {
136 if (root.selectedDetail >= root.specialFields.CONTACT_DETAIL_MIDDLE_NAME)
137 root.specialFieldSelected(root.nameFromEnum(root.selectedDetail), root.selectedDetail)
138 else
139 root.fieldSelected(root.selectedDetail, root.nameFromEnum(root.selectedDetail), root.qmlTypeFromEnum(root.selectedDetail))
140 root.selectedDetail = -1
141 view.model = root.filterSingleDetails(validDetails, root.contact)
142 }
143 }
144
145 ListView {
146 id: view
147 objectName: "listViewOptions"
148
149 model: root.filterSingleDetails(validDetails, root.contact)
150 delegate: Standard {
151 objectName: text
152 text: root.nameFromEnum(modelData)
153 onClicked: {
154 root.selectedDetail = modelData
155 root.expanded = false
156 }
157 }
158
159 Scrollbar{
160 flickableItem: view
161 }
162 }
163 }