Debian Codegraph @

llvm/test/Transforms/LoopInterchange/pr43326-ideal-access-pattern.ll

raw
1 ; RUN: opt < %s -passes=loop-interchange -cache-line-size=64 -pass-remarks-missed='loop-interchange' -pass-remarks-output=%t -S \
2 ; RUN: -verify-dom-info -verify-loop-info -verify-loop-lcssa -stats 2>&1
3 ; RUN: FileCheck --input-file=%t --check-prefix=REMARKS %s
4
5 ; Triply nested loop, should be able to do interchange three times
6 ; to get the ideal access pattern.
7 ; void f(int e[restrict 10][10][10], int f[restrict 10][10][10]) {
8 ; for (int a = 0; a < 10; a++) {
9 ; for (int b = 0; b < 10; b++) {
10 ; for (int c = 0; c < 10; c++) {
11 ; f[c][b][a] = e[c][b][a];
12 ; }
13 ; }
14 ; }
15 ; }
16
17 ; REMARKS: --- !Analysis
18 ; REMARKS-NEXT: Pass: loop-interchange
19 ; REMARKS-NEXT: Name: Dependence
20 ; REMARKS-NEXT: Function: pr43326-triply-nested
21 ; REMARKS-NEXT: Args:
22 ; REMARKS-NEXT: - String: Computed dependence info, invoking the transform.
23 ; REMARKS-NEXT: ...
24
25 ; REMARKS: --- !Passed
26 ; REMARKS-NEXT: Pass: loop-interchange
27 ; REMARKS-NEXT: Name: Interchanged
28 ; REMARKS-NEXT: Function: pr43326-triply-nested
29 ; REMARKS: --- !Passed
30 ; REMARKS-NEXT: Pass: loop-interchange
31 ; REMARKS-NEXT: Name: Interchanged
32 ; REMARKS-NEXT: Function: pr43326-triply-nested
33 ; REMARKS: --- !Passed
34 ; REMARKS-NEXT: Pass: loop-interchange
35 ; REMARKS-NEXT: Name: Interchanged
36 ; REMARKS-NEXT: Function: pr43326-triply-nested
37
38 define void @pr43326-triply-nested(ptr noalias %e, ptr noalias %f) {
39 entry:
40 br label %for.outermost.header
41
42 for.outermost.header: ; preds = %entry, %for.outermost.latch
43 %indvars.outermost = phi i64 [ 0, %entry ], [ %indvars.outermost.next, %for.outermost.latch ]
44 br label %for.middle.header
45
46 for.cond.cleanup: ; preds = %for.outermost.latch
47 ret void
48
49 for.middle.header: ; preds = %for.outermost.header, %for.middle.latch
50 %indvars.middle = phi i64 [ 0, %for.outermost.header ], [ %indvars.middle.next, %for.middle.latch ]
51 br label %for.innermost
52
53 for.outermost.latch: ; preds = %for.middle.latch
54 %indvars.outermost.next = add nuw nsw i64 %indvars.outermost, 1
55 %exitcond.outermost = icmp ne i64 %indvars.outermost.next, 10
56 br i1 %exitcond.outermost, label %for.outermost.header, label %for.cond.cleanup
57
58 for.middle.latch: ; preds = %for.innermost
59 %indvars.middle.next = add nuw nsw i64 %indvars.middle, 1
60 %exitcond.middle = icmp ne i64 %indvars.middle.next, 10
61 br i1 %exitcond.middle, label %for.middle.header, label %for.outermost.latch
62
63 for.innermost: ; preds = %for.middle.header, %for.innermost
64 %indvars.innermost = phi i64 [ 0, %for.middle.header ], [ %indvars.innermost.next, %for.innermost ]
65 %arrayidx12 = getelementptr inbounds [10 x [10 x i32]], ptr %e, i64 %indvars.innermost, i64 %indvars.middle, i64 %indvars.outermost
66 %0 = load i32, ptr %arrayidx12
67 %arrayidx18 = getelementptr inbounds [10 x [10 x i32]], ptr %f, i64 %indvars.innermost, i64 %indvars.middle, i64 %indvars.outermost
68 store i32 %0, ptr %arrayidx18
69 %indvars.innermost.next = add nuw nsw i64 %indvars.innermost, 1
70 %exitcond.innermost = icmp ne i64 %indvars.innermost.next, 10
71 br i1 %exitcond.innermost, label %for.innermost, label %for.middle.latch
72 }