Debian Codegraph @

flang/test/Transforms/DoConcurrent/reduce_add.mlir

raw
1 // Tests mapping reductions from fir to OpenMP.
2
3 // RUN: fir-opt --omp-do-concurrent-conversion="map-to=host" %s | FileCheck %s
4
5 fir.declare_reduction @add_reduction_i32 : i32 init {
6 ^bb0(%arg0: i32):
7 %c0_i32 = arith.constant 0 : i32
8 fir.yield(%c0_i32 : i32)
9 } combiner {
10 ^bb0(%arg0: i32, %arg1: i32):
11 %0 = arith.addi %arg0, %arg1 : i32
12 fir.yield(%0 : i32)
13 }
14
15 func.func @_QPdo_concurrent_reduce() {
16 %3 = fir.alloca i32 {bindc_name = "s", uniq_name = "_QFdo_concurrent_reduceEs"}
17 %4:2 = hlfir.declare %3 {uniq_name = "_QFdo_concurrent_reduceEs"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
18 %c1 = arith.constant 1 : index
19 fir.do_concurrent {
20 %7 = fir.alloca i32 {bindc_name = "i"}
21 %8:2 = hlfir.declare %7 {uniq_name = "_QFdo_concurrent_reduceEi"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
22 fir.do_concurrent.loop (%arg0) = (%c1) to (%c1) step (%c1) reduce(@add_reduction_i32 #fir.reduce_attr<add> %4#0 -> %arg1 : !fir.ref<i32>) {
23 %9 = fir.convert %arg0 : (index) -> i32
24 fir.store %9 to %8#0 : !fir.ref<i32>
25 %10:2 = hlfir.declare %arg1 {uniq_name = "_QFdo_concurrent_reduceEs"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
26 %11 = fir.load %10#0 : !fir.ref<i32>
27 %c1_i32_0 = arith.constant 1 : i32
28 %12 = arith.addi %11, %c1_i32_0 : i32
29 hlfir.assign %12 to %10#0 : i32, !fir.ref<i32>
30 }
31 }
32 return
33 }
34
35 // CHECK-LABEL: omp.declare_reduction @add_reduction_i32.omp : i32 init {
36 // CHECK: ^bb0(%[[VAL_0:.*]]: i32):
37 // CHECK: %[[VAL_1:.*]] = arith.constant 0 : i32
38 // CHECK: omp.yield(%[[VAL_1]] : i32)
39
40 // CHECK-LABEL: } combiner {
41 // CHECK: ^bb0(%[[VAL_0:.*]]: i32, %[[VAL_1:.*]]: i32):
42 // CHECK: %[[VAL_2:.*]] = arith.addi %[[VAL_0]], %[[VAL_1]] : i32
43 // CHECK: omp.yield(%[[VAL_2]] : i32)
44 // CHECK: }
45
46 // CHECK-LABEL: func.func @_QPdo_concurrent_reduce() {
47 // CHECK: %[[VAL_0:.*]] = fir.alloca i32 {bindc_name = "i"}
48 // CHECK: %[[VAL_1:.*]]:2 = hlfir.declare %[[VAL_0]] {uniq_name = "_QFdo_concurrent_reduceEi"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
49 // CHECK: %[[VAL_2:.*]] = fir.alloca i32 {bindc_name = "s", uniq_name = "_QFdo_concurrent_reduceEs"}
50 // CHECK: %[[VAL_3:.*]]:2 = hlfir.declare %[[VAL_2]] {uniq_name = "_QFdo_concurrent_reduceEs"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
51 // CHECK: %[[VAL_4:.*]] = arith.constant 1 : index
52 // CHECK: omp.parallel {
53 // CHECK: %[[VAL_5:.*]] = fir.alloca i32 {bindc_name = "i"}
54 // CHECK: %[[VAL_6:.*]]:2 = hlfir.declare %[[VAL_5]] {uniq_name = "_QFdo_concurrent_reduceEi"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
55
56 // CHECK: omp.wsloop reduction(@add_reduction_i32.omp %[[VAL_3]]#0 -> %[[VAL_7:.*]] : !fir.ref<i32>) {
57 // CHECK: omp.loop_nest (%[[VAL_8:.*]]) : index = (%[[VAL_4]]) to (%[[VAL_4]]) inclusive step (%[[VAL_4]]) {
58 // CHECK: %[[VAL_9:.*]] = fir.convert %[[VAL_8]] : (index) -> i32
59 // CHECK: fir.store %[[VAL_9]] to %[[VAL_6]]#0 : !fir.ref<i32>
60 // CHECK: %[[VAL_10:.*]]:2 = hlfir.declare %[[VAL_7]] {uniq_name = "_QFdo_concurrent_reduceEs"} : (!fir.ref<i32>) -> (!fir.ref<i32>, !fir.ref<i32>)
61 // CHECK: %[[VAL_11:.*]] = fir.load %[[VAL_10]]#0 : !fir.ref<i32>
62 // CHECK: %[[VAL_12:.*]] = arith.constant 1 : i32
63 // CHECK: %[[VAL_13:.*]] = arith.addi %[[VAL_11]], %[[VAL_12]] : i32
64 // CHECK: hlfir.assign %[[VAL_13]] to %[[VAL_10]]#0 : i32, !fir.ref<i32>
65 // CHECK: omp.yield
66 // CHECK: }
67 // CHECK: }
68 // CHECK: omp.terminator
69 // CHECK: }
70
71 // CHECK: return
72 // CHECK: }
73