Debian Codegraph @

compiler-rt/lib/rtsan/tests/CMakeLists.txt

raw
1 include(CompilerRTCompile)
2
3 include_directories(..)
4
5 set(RTSAN_UNITTEST_CFLAGS
6 ${COMPILER_RT_UNITTEST_CFLAGS}
7 ${COMPILER_RT_GTEST_CFLAGS}
8 ${COMPILER_RT_GMOCK_CFLAGS}
9 ${SANITIZER_TEST_CXX_CFLAGS}
10 -I${COMPILER_RT_SOURCE_DIR}/lib/
11 -I${COMPILER_RT_SOURCE_DIR}/include/
12 -I${COMPILER_RT_SOURCE_DIR}/lib/rtsan
13 -I${COMPILER_RT_SOURCE_DIR}/lib/sanitizer_common/tests
14 -DSANITIZER_COMMON_NO_REDEFINE_BUILTINS
15 -O2)
16
17 set(RTSAN_INST_TEST_SOURCES
18 rtsan_test_functional.cpp
19 rtsan_test_interceptors_posix.cpp
20 rtsan_test_main.cpp)
21
22 set(RTSAN_NOINST_TEST_SOURCES
23 ../rtsan_preinit.cpp
24 rtsan_test_assertions.cpp
25 rtsan_test_context.cpp
26 rtsan_test_main.cpp)
27
28 set(RTSAN_UNITTEST_HEADERS
29 rtsan_test_utilities.h)
30
31 add_custom_target(RtsanUnitTests)
32 set_target_properties(RtsanUnitTests PROPERTIES FOLDER "Compiler-RT Tests")
33
34 set(RTSAN_UNITTEST_LINK_FLAGS
35 ${COMPILER_RT_UNITTEST_LINK_FLAGS}
36 ${COMPILER_RT_UNWINDER_LINK_LIBS}
37 ${SANITIZER_TEST_CXX_LIBRARIES}
38 -no-pie)
39
40 if (COMPILER_RT_USE_ATOMIC_LIBRARY)
41 list(APPEND RTSAN_UNITTEST_LINK_FLAGS ${COMPILER_RT_ATOMIC_LIBRARY})
42 if (NOT WIN32)
43 get_filename_component(atomic_dir ${COMPILER_RT_ATOMIC_LIBRARY} DIRECTORY)
44 list(APPEND RTSAN_UNITTEST_LINK_FLAGS "-Wl,-rpath,${atomic_dir}")
45 endif()
46 else()
47 append_list_if(COMPILER_RT_HAS_LIBATOMIC -latomic RTSAN_UNITTEST_LINK_FLAGS)
48 endif()
49 append_list_if(COMPILER_RT_HAS_LIBDL -ldl RTSAN_UNITTEST_LINK_FLAGS)
50 append_list_if(COMPILER_RT_HAS_LIBRT -lrt RTSAN_UNITTEST_LINK_FLAGS)
51 append_list_if(COMPILER_RT_HAS_LIBM -lm RTSAN_UNITTEST_LINK_FLAGS)
52 append_list_if(COMPILER_RT_HAS_LIBPTHREAD -pthread RTSAN_UNITTEST_LINK_FLAGS)
53 append_list_if(COMPILER_RT_HAS_LIBLOG -llog RTSAN_UNITTEST_LINK_FLAGS)
54
55 if (APPLE)
56 add_weak_symbols("sanitizer_common" WEAK_SYMBOL_LINK_FLAGS)
57 list(APPEND RTSAN_UNITTEST_LINK_FLAGS ${WEAK_SYMBOL_LINK_FLAGS})
58 list(APPEND RTSAN_UNITTEST_LINK_FLAGS ${DARWIN_osx_LINK_FLAGS})
59 list(APPEND RTSAN_UNITTEST_CFLAGS ${DARWIN_osx_CFLAGS})
60 endif()
61
62 set(COMPILER_RT_GOOGLETEST_SOURCES ${COMPILER_RT_GTEST_SOURCE} ${COMPILER_RT_GMOCK_SOURCE})
63
64 set(RTSAN_TEST_ARCH ${RTSAN_SUPPORTED_ARCH})
65 if(APPLE)
66 darwin_filter_host_archs(RTSAN_SUPPORTED_ARCH RTSAN_TEST_ARCH)
67 endif()
68
69 foreach(arch ${RTSAN_TEST_ARCH})
70 set(RtsanTestObjects)
71
72 generate_compiler_rt_tests(RtsanTestObjects
73 RtsanUnitTests "Rtsan-${arch}-Test" ${arch}
74 COMPILE_DEPS ${RTSAN_UNITTEST_HEADERS}
75 SOURCES ${RTSAN_INST_TEST_SOURCES} ${COMPILER_RT_GOOGLETEST_SOURCES}
76 DEPS rtsan
77 CFLAGS ${RTSAN_UNITTEST_CFLAGS} -fsanitize=realtime
78 LINK_FLAGS ${RTSAN_UNITTEST_LINK_FLAGS} -fsanitize=realtime)
79
80 check_symbol_exists(__GLIBC__ stdio.h RTSAN_USING_GLIBC)
81 if (RTSAN_USING_GLIBC)
82 set(RtsanTestObjects_FileOffset64)
83 generate_compiler_rt_tests(RtsanTestObjects_FileOffset64
84 RtsanUnitTests "Rtsan-${arch}-FileOffset64-Test" ${arch}
85 COMPILE_DEPS ${RTSAN_UNITTEST_HEADERS}
86 SOURCES ${RTSAN_INST_TEST_SOURCES} ${COMPILER_RT_GOOGLETEST_SOURCES}
87 DEPS rtsan
88 CFLAGS ${RTSAN_UNITTEST_CFLAGS} -D_FILE_OFFSET_BITS=64 -fsanitize=realtime
89 LINK_FLAGS ${RTSAN_UNITTEST_LINK_FLAGS} -fsanitize=realtime)
90 endif()
91
92 set(RTSAN_TEST_RUNTIME RTRtsanTest.${arch})
93 if(APPLE)
94 set(RTSAN_TEST_RUNTIME_OBJECTS
95 $<TARGET_OBJECTS:RTRtsan.osx>
96 $<TARGET_OBJECTS:RTInterception.osx>
97 $<TARGET_OBJECTS:RTSanitizerCommon.osx>
98 $<TARGET_OBJECTS:RTSanitizerCommonLibc.osx>
99 $<TARGET_OBJECTS:RTSanitizerCommonCoverage.osx>
100 $<TARGET_OBJECTS:RTSanitizerCommonSymbolizer.osx>)
101 else()
102 set(RTSAN_TEST_RUNTIME_OBJECTS
103 $<TARGET_OBJECTS:RTRtsan.${arch}>
104 $<TARGET_OBJECTS:RTInterception.${arch}>
105 $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
106 $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
107 $<TARGET_OBJECTS:RTSanitizerCommonCoverage.${arch}>
108 $<TARGET_OBJECTS:RTSanitizerCommonSymbolizer.${arch}>
109 $<TARGET_OBJECTS:RTSanitizerCommonSymbolizerInternal.${arch}>)
110 endif()
111 add_library(${RTSAN_TEST_RUNTIME} STATIC ${RTSAN_TEST_RUNTIME_OBJECTS})
112 set_target_properties(${RTSAN_TEST_RUNTIME} PROPERTIES
113 ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
114 FOLDER "Compiler-RT Runtime tests")
115
116 set(RtsanNoInstTestObjects)
117 generate_compiler_rt_tests(RtsanNoInstTestObjects
118 RtsanUnitTests "Rtsan-${arch}-NoInstTest" ${arch}
119 COMPILE_DEPS ${RTSAN_UNITTEST_HEADERS}
120 SOURCES ${RTSAN_NOINST_TEST_SOURCES}
121 ${COMPILER_RT_GOOGLETEST_SOURCES}
122 CFLAGS ${RTSAN_UNITTEST_CFLAGS}
123 LINK_FLAGS ${RTSAN_UNITTEST_LINK_FLAGS}
124 RUNTIME ${RTSAN_TEST_RUNTIME})
125 set_target_properties(RtsanUnitTests PROPERTIES
126 RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
127 endforeach()