Debian Codegraph @

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/DWARF/BUILD.gn

raw
1 import("//lldb/utils/TableGen/lldb_tablegen.gni")
2
3 lldb_tablegen("SymbolFileDWARFProperties") {
4 args = [ "-gen-lldb-property-defs" ]
5 }
6
7 lldb_tablegen("SymbolFileDWARFPropertiesEnum") {
8 args = [ "-gen-lldb-property-enum-defs" ]
9 td_file = "SymbolFileDWARFProperties.td"
10 }
11
12 static_library("DWARF") {
13 output_name = "lldbPluginSymbolFileDWARF"
14 configs += [
15 "//llvm/utils/gn/build:clang_code",
16 "//llvm/utils/gn/build:lldb_code",
17 ]
18 deps = [
19 ":SymbolFileDWARFProperties",
20 ":SymbolFileDWARFPropertiesEnum",
21 "//clang/lib/AST",
22 "//clang/lib/Basic",
23 "//lldb/source/Core",
24 "//lldb/source/Expression",
25 "//lldb/source/Host",
26 "//lldb/source/Interpreter",
27 "//lldb/source/Plugins/ExpressionParser/Clang",
28
29 #"//lldb/source/Plugins/Language/CPlusPlus", # 3-hop dependency cycle.
30 "//lldb/source/Plugins/Language/ObjC",
31 "//lldb/source/Symbol",
32 "//lldb/source/Target",
33 "//lldb/source/Utility",
34
35 #"//lldb/source/Plugins/TypeSystem/Clang", # Dependency cycle.
36 "//llvm/lib/DebugInfo/DWARF",
37 "//llvm/lib/Support",
38 ]
39
40 # Uses source-relative includes for own headers.
41 include_dirs = [ "//lldb/source" ]
42 sources = [
43 "AppleDWARFIndex.cpp",
44 "DIERef.cpp",
45 "DWARFASTParser.cpp",
46 "DWARFASTParserClang.cpp",
47 "DWARFAttribute.cpp",
48 "DWARFBaseDIE.cpp",
49 "DWARFCompileUnit.cpp",
50 "DWARFContext.cpp",
51 "DWARFDIE.cpp",
52 "DWARFDataExtractor.cpp",
53 "DWARFDebugArangeSet.cpp",
54 "DWARFDebugAranges.cpp",
55 "DWARFDebugInfo.cpp",
56 "DWARFDebugInfoEntry.cpp",
57 "DWARFDebugMacro.cpp",
58 "DWARFDebugRanges.cpp",
59 "DWARFDeclContext.cpp",
60 "DWARFDefines.cpp",
61 "DWARFFormValue.cpp",
62 "DWARFIndex.cpp",
63 "DWARFTypeUnit.cpp",
64 "DWARFUnit.cpp",
65 "DebugNamesDWARFIndex.cpp",
66 "LogChannelDWARF.cpp",
67 "ManualDWARFIndex.cpp",
68 "NameToDIE.cpp",
69 "SymbolFileDWARF.cpp",
70 "SymbolFileDWARFDebugMap.cpp",
71 "SymbolFileDWARFDwo.cpp",
72 "UniqueDWARFASTType.cpp",
73 ]
74 }