Debian Codegraph @

lib/Test/HTTP/log-server

raw
1 # Thanks to merlyn for nudging me and giving me this snippet!
2 use strict;
3 use HTTP::Daemon 6.05;
4 use URI;
5 use CGI;
6 use HTTP::Request::AsCGI;
7 use Getopt::Long;
8 use Socket();
9 use Time::HiRes 'sleep';
10 our $VERSION = '0.74';
11
12 $|++;
13
14 GetOptions(
15 'e=s' => \my $expression,
16 'f=s' => \my $url_filename,
17 's=s' => \my $request_pause,
18 );
19
20 if( ! defined $request_pause ) {
21 $request_pause = 1;
22 }
23
24 # HTTP::Daemon(IO::Socket::IP) sets $@ in case of error
25 my $d = HTTP::Daemon->new or die "Couldn't create HTTP::Daemon: $@";
26
27 my $url = URI->new( $d->url );
28 if( $d->sockdomain == Socket::AF_INET ) {
29 $url->host('127.0.0.1');
30 } elsif ($d->sockdomain == Socket::AF_INET6 ) {
31 $url->host('[::1]');
32 } else {
33 die "Unexpected sockdomain: " . $d->sockdomain;
34 };
35
36 {
37 my $fh;
38 if( $url_filename ) {
39 open $fh, '>', $url_filename
40 or die "Couldn't write URL to tempfile '$url_filename': $!";
41 } else {
42 $fh = \*STDOUT;
43 };
44 print {$fh} "$url\n";
45 close $fh unless $url_filename;
46 }
47
48 my ($filename,$logfile) = @ARGV[0,1];
49 if ($filename) {
50 open DATA, "< $filename"
51 or die "Couldn't read page '$filename' : $!\n";
52 };
53 #open LOG, ">", $logfile
54 # or die "Couldn't create logfile '$logfile' : $!\n";
55 my $log;
56 my $body = join "", <DATA>;
57
58 sub debug($) {
59 my $message = $_[0];
60 $message =~ s!\n!\n#SERVER:!g;
61 warn "#SERVER: $message"
62 if $ENV{TEST_HTTP_VERBOSE};
63 };
64
65 my $multi_param = eval { CGI->can('multi_param') } ? 'multi_param' : 'param';
66
67 sub respond_200 {
68 my( $location, $r ) = @_;
69 my $context = HTTP::Request::AsCGI->new( $r )->setup;
70 my $q = CGI->new();
71
72 # Make sticky form fields
73 my ($filename, $filetype, $filecontent, $query,$botcheck_query,$query2,$session,%cat);
74 $query = defined $q->param('query') ? $q->param('query') : "(empty)";
75 $botcheck_query = defined $q->param('botcheck_query') ? $q->param('botcheck_query') : "(empty)";
76 $query2 = defined $q->param('query2') ? $q->param('query2') : "(empty)";
77 $session = defined $q->param('session') ? $q->param('session') : 1;
78 my @cats = $q->$multi_param('cat');
79 %cat = map { $_ => 1 } ( @cats ? @cats : qw( cat_foo cat_bar ));
80 my @categories = map { $cat{$_} ? "checked" : "" } qw( cat_foo cat_bar cat_baz );
81 my $headers = CGI::escapeHTML( $r->headers->as_string );
82 my $rbody = sprintf $body,$headers, $location,
83 $filename, $filetype, $filecontent,
84 $session,$query,$botcheck_query,$query2,@categories,
85 ;
86 my $res = HTTP::Response->new(200, "OK", [
87 'Set-Cookie' => $q->cookie(-name => 'log-server-httponly',-value=>'supersecret', -discard => 1, -httponly=>1),
88 'Set-Cookie' => $q->cookie(-name => 'log-server',-value=>'shazam2', -discard=>1,),
89 'Cache-Control' => 'no-cache',
90 'Pragma' => 'no-cache',
91 'Max-Age' => 0,
92 'Connection' => 'close',
93 'Content-Length' => length($rbody),
94 ], $rbody);
95 $res->content_type('text/html; charset=ISO-8859-1');
96 debug "Request " . ($r->uri->path || "/");
97 $res
98 }
99
100 SERVERLOOP: {
101 my $quitserver;
102 while (my $c = $d->accept) {
103 debug "New connection";
104 while (my $r = $c->get_request) {
105 debug "Request:\n" . $r->as_string;
106 my $location = ($r->uri->path || "/");
107 my ($link1,$link2) = ('','');
108 if ($location =~ m!^/link/([^/]+)/(.*)$!) {
109 ($link1,$link2) = ($1,$2);
110 };
111 my $res;
112 if ($location eq '/get_server_log') {
113 $res = HTTP::Response->new(200, "OK", undef, $log);
114 $log = '';
115 } elsif ( $location eq '/quit_server') {
116 debug "Quitting";
117 $res = HTTP::Response->new(200, "OK", [Connection => 'close'], "quit");
118 $quitserver = 1;
119 } else {
120 eval $expression
121 if $expression;
122 warn "eval: $@" if $@;
123 $log .= "Request:\n" . $r->as_string . "\n";
124 if ($location =~ m!^/redirect/(.*)$!) {
125 $res = HTTP::Response->new(302);
126 $res->header('location', $url . $1);
127
128 } elsif ($location =~ m!^/local/(.*)$!) {
129 my $rbody= do { open my $fh, '<', $1; binmode $fh; local $/; <$fh> };
130 $res = HTTP::Response->new(200, "OK", [
131 'Cache-Control' => 'no-cache',
132 'Pragma' => 'no-cache',
133 'Max-Age' => 0,
134 'Connection' => 'close',
135 'Content-Length' => length($rbody),
136 ], $rbody);
137
138 } elsif ($location =~ m!^/download/([\w.-]+)$!) {
139 my $rbody= do { open my $fh, '<', $0; binmode $fh; local $/; <$fh> };
140 $res = HTTP::Response->new(200, "OK", [
141 'Cache-Control' => 'no-cache',
142 'Pragma' => 'no-cache',
143 'Max-Age' => 0,
144 'Connection' => 'close',
145 'Content-Length' => length($rbody),
146 'Content-Disposition' => qq{attachment; filename=$1;},
147 ], $rbody);
148
149 } elsif ($location =~ m!^/error/notfound/(.*)$! or $location =~ m!^/favicon.ico!) {
150 $res = HTTP::Response->new(404, "Not found", [Connection => 'close']);
151 } elsif ($location =~ m!^/error/timeout/(\d+)$!) {
152 sleep $1;
153 $res = HTTP::Response->new(599, "Timeout reached", [Connection => 'close']);
154
155 } elsif ($location =~ m!^/error/close/(\d+)$!) {
156 sleep $1;
157 $res = undef;
158
159 } elsif ( $location =~ m!^/chunks!) {
160 my $count = 5;
161 $res = HTTP::Response->new(200, "OK", undef, sub {
162 sleep 1;
163 my $buf = 'x' x 16;
164 return $buf if $count-- > 0;
165 return undef; # done
166 });
167
168 } elsif ($location =~ m!^/error/after_headers$!) {
169 my $count = 2;
170 $res = HTTP::Response->new(200, "OK", undef, sub {
171 sleep 1;
172 my $buf = 'x' x 16;
173 return $buf if $count-- > 0;
174 die "Planned error after headers";
175 });
176
177 } elsif ($location =~ m!^/large/bzip/16M$!) {
178 my $headers = HTTP::Headers->new(
179 Content_Type => "application/xml",
180 Content_Encoding => 'bzip2,bzip2,bzip2', # say my name three times
181 );
182 # 16M bzip thrice-encoded, see gen-bzipbomb.pl
183 $body = join "",
184 "BZh11AY&SY\tPFN\0\0'\177\377\355\e\177v\363\267|\344?\226]pVbW\25\313|F",
185 "]h0\30\303\305i\272CF9fS\260\0\271\b\32\32h\323\32414\304ddbh4\304h4\304z\231\6h",
186 "#\32\2154\310\365=\4`\32 fQ\341O)\371Q\6L\0\230\0\t\200#L#\0\0\0\4\311\246&\203",
187 "\0#\0\0\0\0\203&\322a11\240\0&\21\200\320\232`\1\0310\4\323\0#4\20d\300L\4d`\34",
188 "\370I\21o\f\304\0\205b\344\365u\326\334O\301\0054}\306\274\215\246\240\351\247\240",
189 "M\252\333Je)\25\217\231\230\00046\236)\4(R\301\370\363\371\350\277\b0\26\275\16&",
190 "W\260\2\2151\272\177\301\366}\327b\213\374\t\264g~\245\203\225\220\2660,\226\213",
191 "\247\246l\351\303\304\300\$z0Hg\272;\31\226B\244\266\376\301\364\355I~\222\273",
192 "\226*S\"\3\263\360\200Iv\241}|\344\227q\1I\6\217I\30\302\2\261\207\224h\305\16\17",
193 "\324\1779\1\247\\R{\335\$pM8cL\"\201\311 \374\364P\274\227p\237\300\320`\36pJ\264",
194 "\21\277\305\334\221N\24\$\2T\21\223\200"
195 ;
196 $res = HTTP::Response->new(200, "OK", $headers, $body);
197
198 } elsif ($location =~ m!^/large/gzip/16M$!) {
199 my $headers = HTTP::Headers->new(
200 Content_Type => "application/xml",
201 Content_Encoding => 'gzip,gzip,gzip', # say my name three times
202 );
203 # 16M bzip thrice-encoded, see gen-gzipbomb.pl
204 $body = join "",
205 "\37\213\b\0\0\0\0\0\0\377\223\357\346`\0\203\377o/l\344mr`h}h\235\321\341",
206 "- T^\300^\225-\276p\307\221Km\242>/b\31\237%\260>\346\220S7\2760\243&\376\363",
207 "\277_[\373\325\336|\252\356\334\230#\265\177\275\1771\27\304\f\206\3\363\275_",
208 "\357]Ww\361\351\355\247o\370\241b\26\aj\336\316?\34\242\224\27a\347\24\270",
209 "\336\236\201\1\0!\203w\217s\0\0\0",
210 ;
211 $res = HTTP::Response->new(200, "OK", $headers, $body);
212
213 } elsif ($location =~ m!^/content/(.*)$!) {
214 my $headers = HTTP::Headers->new(
215 Content_Type => "text/html",
216 );
217 (my $html = $1) =~ s!%([a-fA-F0-9]{2})!chr(hex($1))!ge;
218 $body = join "",
219 "<html>",
220 "$html",
221 "</html>",
222 ;
223 $res = HTTP::Response->new(200, "OK", $headers, $body);
224
225 } elsif ($location =~ m!^/basic_auth/([^/]+)/([^/]+)$!) {
226 my ($user, $pass) = $r->authorization_basic;
227 my( $ex_user, $ex_pass ) = ($1,$2);
228 if( $user eq $ex_user
229 and $pass eq $ex_pass) {
230 $res = respond_200( $location, $r );
231
232 } else {
233 debug "# User : '$user' Password : '$pass'\n";
234 $res = HTTP::Response->new(401, "Auth Required", undef,
235 "auth required ($user/$pass)");
236 $res->www_authenticate("Basic realm=\"testing realm\"");
237 };
238
239 } else {
240 $res = respond_200( $location, $r );
241 };
242 };
243 debug "Response:\n" . $res->as_string
244 if $res;
245 eval {
246 $c->send_response($res)
247 if $res;
248 };
249 if (my $err = $@) {
250 debug "Server raised error: $err";
251 if ($err !~ /^Planned error\b/) {
252 warn $err;
253 };
254 $c->close;
255 };
256 if (! $res) {
257 $c->close;
258 };
259 last if $quitserver;
260 }
261 sleep $request_pause;
262 undef($c);
263 last SERVERLOOP
264 if $quitserver;
265 };
266 undef $d;
267 };
268 END { debug "Server $$ stopped" };
269
270 # The below <link> tag should stop the browser from requesting a favicon.ico, but we still see it...
271 __DATA__
272 <html lang="en">
273 <head>
274 <title>WWW::Mechanize::Firefox test page</title>
275 <link rel="shortcut icon" href="#">
276 <style>
277 .hidden { display: none; }
278 </style>
279 <script>
280 window.onload = function() {
281 document.forms[0].navigator.value = window.navigator.userAgent;
282 }
283 </script>
284 </head>
285 <body>
286 <h1>Request headers</h1>
287 <pre id="request_headers">
288 %s
289 </pre>
290 <h1>Location: %s</h1>
291 <p>
292 <a href="/test">Link /test</a>
293 <a href="/foo">Link /foo</a>
294 <a href="/slash_end">Link /</a>
295 <a href="/slash_front">/Link </a>
296 <a href="/slash_both">/Link in slashes/</a>
297 <a href="/foo1.save_log_server_test.tmp">Link foo1.save_log_server_test.tmp</a>
298 <a href="/foo2.save_log_server_test.tmp">Link foo2.save_log_server_test.tmp</a>
299 <a href="/foo3.save_log_server_test.tmp">Link foo3.save_log_server_test.tmp</a>
300 <table>
301 <tr><th>Col1</th><th>Col2</th><th>Col3</th></tr>
302 <tr><td>A1</td><td>A2</td><td>A3</td></tr>
303 <tr><td>B1</td><td>B2</td><td>B3</td></tr>
304 <tr><td>C1</td><td>C2</td><td>C3</td></tr>
305 </table>
306 <a id="maplink" href="/imageclick" target="_self">
307 <img id="ismap"
308 ismap="ismap"
309 src="data:image/png;base64,iVBORw0KGgoAAAANSUhEUgAAAHgAAAB4CAIAAAC2BqGFAAAAA3NCSVQICAjb4U/gAAAIcElEQVR4nO2c3XMT1xmHf+85uytpJRuBwcKxbA8lwBA6adqUzjBtSJpMOu0kM8lFbvO/9aK9aC/TTmnTSckE0pQkFAi1ScAUjLEty5Yl62u12t1zerF8OM1AsLU6ZzHnufBoxp6jo8ev3j2fL/32nIRh+DDdHXhWMKIVYUQrwohWhBGtCCNaEUa0IoxoRRjRijCiFWFEK8KIVoQRrQgjWhFGtCKMaEUY0YowohVhRCvCiFaEEa0II1oRlu4OfD+MgQhEIADxT0ACkJCAlJASQmjt4hOQXtGMgTEIgZWqt7rWW6/3G62g2Q37oSTAtmjUtYoj9v69TulAdmI8F/9xao1TCg/QMAbOcXfFm5tv3ljsMgJnRARGRPTwz6SEkFJKREIKiSNT7guHR8vP5aIojbrTFdFEsC38907300u1Zie0Lco5j3yKEIETAbA4AVhY8eYXu6N56+c/3veD6XwQQqYphFIU0RZHqxN+eH61Wu9nbLY1eJ8cKeEHYnyv86tflEbyVhgl3cudkhbRjo25G62PPl/P2sTYjhxvQQjZC+TrJ8dOHB3tB4l0cFBSkTpsG2c/W5u91XYzyQw3GSM3Q2e/rFVr/munDgQpcK1ftG3hzMeVhRXvMel4Z+Qc9vXttudHv3n1YBAm2/a20TxhcWx8eH51odJz7KH0xLHZQqX39/Orjj2M5reBTtG2hYtX6/OLXccaNCk/BseiG4vdL6/Wba3fXm2iGUNlzf/0Sj2bdMb4LlmH/fNKvbLmM31xpe2dCThzruJmuJq3czP8zLnKEL8434ce0RbHpdl6P5A7GyzvACL0A3lprm4p+s/+PxpEEyEIcWG2YQ8zNX8X26ILVxtBCGX/3a1oEM0YZq83uI6PyxnNXm9oydR6RF/+ZjNeoFCMxenyN5vPhGhGqFR9zxdavr9E8HxRqfoDT/K3jWrRxHBnuaMlnGMsTovLHVIe1Boi+m7FG3zZaOcdYLS42tv9ES2BykZfn2cwwkrNV79UrVQ0Edod/SvEBLS7keKHhOqI7nqhlsfgVojQ9VSv5qmO6CBIxXZeEKge9mjI0Wlgl+doAFzjc3ALXPn4UqloKZFxuPbNaSnhKO+G6ojOu5ZIgei8q3oXQHVE57KUc5hG1RLIOMzN0i6PaCFRHs8KfVEthJwqZdW/v/JRh8DURE7jkS0hMHUwJ5V3QENEz0wWglCb6SAUM5OFZyCiJfJ5NlXSkz3ivJHPs90/jgYQRXjpeLEfahDdD+VLx4uRjuUWDaKFwEzZLRYsxWElJYoFa6bsanlC6NkFjyKcPnnA6yv9xF5fvHrygJZwhi7RQmBqInuk7IaRoqgOI/l82S1PZHUNeLQdoAlC/PJUiTEVEwcpwRi9fqqk8aijNtFSgnO8+8aEggTi9cW7b0xwrvMOgM5DjkJgrOi8fbrU6Q0xcXZ60dunS2NFR+/FFs3HdsMIM2X3rVdKnV7y2VoCnV701iulmbKr/Y6F/gudYYhD0/n33pwMApngLEYIGQTyvTcnD03nQ92n0JEG0QDCEKX9mfffmS6O2H4Se11+IIoj9vvvTJf2Z9JgGem5LASACJaFuevNT/69QYBlbXtXTwJhKCVw+if7Xjg6GqbpBlyKRMdwjijCV9fqF69tRkJanJ5k9ysSMowkZ/Ty8T0vHt8bN5IqUic6hnMAWLjbvXmnPX+3K4RkjOLr4HGcy/sXweNfPV92D08XZsoukDrFMSkVHRNfBwdQbwQbm/1WO+h6URgJABZnbo6PFOx9e5y9RRtI9UVwpOH622N44G50xN4zasex/LC6wf3SBil53D2eVIt+QCz0qSYVw7tnASNaEUa0IoxoRaTxYfitCkoPRhr3Zy1bRx0PXm0tsfTwRZpIhWgisFguQxSh2Qqa7aDdCVudsOOFHS/y+6LrR0Eog1DEUxUiWIxsi2VsymV4LsvzWZ53rULeGsnbowU7n2eQEPLeiEW7d22i78llkBK1er+63lut9Srr/kYrZPe804PQjmspMULm20UQhJCeL7u+kJv9OJCFhJRSSHBGB8ec0r7M+Fh2fH92tMCFgNBXT0y1aCIwBs7QbEeLy52Fpe7tiiclOCPGwIi2VRtlS2LZuh5y7/V6o1/d6IsbrSiShRw/NOlOP+eWJ1zONUwj1U3BY79eT8wvtK7dbFUbgc2JM6i5oRWvikRCRhKHJ91jhwoz5TwBkVCUVVRENGOwOJYqvStfN24ueTYnzrcXuYNDBM4pPn++uOrdWu4yohePjPzwWHEkz8No6LqHG9GMYFm4tdj915WNjWZgW0+05qmMMJJ+II5N53/2o7HiHmuo69dDFG3bqK75Zy+s1ZrBjsurKSASstcXJw4VTr18IOPQkFZZhyI6rl557vPq3K12NpOqIH4kUSSDSL7207ETR0eHUZwwedGWhbVa/09nV+L9kWQbHza9viiPZ399eiIemSRIwk8kx8a1G80//PUu7leyfLrIOmx1w//dBwudbphstYkkG3NsfHGl/o8vavmslrInycAZSYnf/3mx2QoSdJ1YS7aFr65tXvhPQ/G4bRgQwbHYH/+21EuurkhSJSqxXO19fLGWe/otxxCBEz74aJknVOwqGS9S4i+frCqrraYGxmizHVyebSTiOgHRnOPyXD2K1NVWU4Zjs8+u1hM5t5dMRF+c21RcW00ZjGj+VpMP7GnQBhjDUsUT2pd7h4bFcHupO3gNpkEbIEJ1vfd0TP52BDFaqfmDZ8WBRQMdL9y1mgECPF8M/gETyNFCPNzQMzyKXTLsTT9GtCKMaEUY0YowohVhRCvCiFaEEa0II1oRRrQijGhFGNGKMKIVYUQrwohWhBGtCCNaEUa0IoxoRRjRijCiFWFEK8KIVoQRrYj/AQxTcgT19UdzAAAAAElFTkSuQmCC"
310 onclick="storeCoordinates(event)" />
311 </a>
312 <pre id="fileupload">
313 Filename: %s
314 Filetype: %s
315 Content: %s
316 </pre>
317 <form name='f' action="/formsubmit" method="POST" enctype="multipart/form-data">
318 <input type="hidden" name="session" value="%s"/>
319 <input type="text" name="query" value="%s"/>
320 <input type="text" name="botcheck_query" class="hidden" value="%s"/>
321 <input type="image" name="submit_image" value="Go_img" id="submit_button_image" />
322 <input type="text" name="query2" value="%s"/>
323 <input type="submit" name="submit" value="Go" id="submit_button" />
324 <input type="checkbox" name="cat" value="cat_foo" %s />
325 <input type="checkbox" name="cat" value="cat_bar" %s />
326 <input type="checkbox" name="cat" value="cat_baz" %s />
327 <input type="hidden" name="navigator" value="[JS disabled]" />
328 </form>
329 </p>
330 </body>
331 </html>