Debian Codegraph @

eg/rl-timeout

raw
1 #!/usr/bin/env perl
2 #
3 # rl-timeout: Test various readline builtin timeouts
4 #
5 # Copyright (C) 2024 Hiroo Hayashi
6 #
7 # Derived from: examples/rl-timeout.c in the GNU Readline Library
8 # Copyright (C) 2021 Free Software Foundation, Inc.
9
10 use strict;
11 use warnings;
12 use Term::ReadLine;
13
14 BEGIN {
15 import Term::ReadLine::Gnu qw(RL_STATE_TIMEOUT READERR);
16 }
17
18 sub usage {
19 print <<EOM;
20 usage: rl-timeout [readline1 | readline2 | callback1 | callback2] [timeout]
21 EOM
22 }
23
24 my $t = new Term::ReadLine 'rl-timeout';
25 my $a = $t->Attribs;
26
27 if ($a->{readline_version} < 0x0802) {
28 warn "rl-timeout: This example requires readline 8.2 or later.\n";
29 exit(1);
30 }
31 my $timeout_secs = 1;
32 my $timeout_usecs = 0;
33 my $running = 0;
34 my $prompt = 'rl-timeout$ ';
35 my $UINT_MAX = ~0;
36
37 # ****************************************************************
38 #
39 # Example 1: readline () with rl_readline_state
40 #
41 # ****************************************************************
42
43 sub rltest_timeout_readline1 {
44 $t->set_timeout($timeout_secs, $timeout_usecs);
45 my $temp = $t->readline($prompt);
46 if ($t->ISSTATE(RL_STATE_TIMEOUT)) {
47 print "timeout\n";
48 } elsif (!$temp) {
49 print "no input line\n";
50 } else {
51 print "input line: $temp\n";
52 }
53 }
54
55 # ****************************************************************
56 #
57 # Example 2: readline () with rl_timeout_event_hook
58 #
59 # ****************************************************************
60
61 sub timeout_handler {
62 print "timeout\n";
63 return READERR;
64 }
65
66 sub rltest_timeout_readline2 {
67 my $temp;
68
69 $t->set_timeout($timeout_secs, $timeout_usecs);
70 $a->{timeout_event_hook} = \&timeout_handler;
71 $temp = $t->readline($prompt);
72 if (!$temp) {
73 print "no input line\n";
74 } else {
75 print "input line: $temp\n";
76 }
77 }
78
79 # ****************************************************************
80 #
81 # Example 3: rl_callback_* () with rl_timeout_remaining
82 #
83 # ****************************************************************
84
85 # Callback function called for each line when accept-line executed, EOF
86 # seen, or EOF character read. This sets a flag and returns; it could
87 # also call exit(3).
88 sub cb_linehandler {
89 my ($line) = @_;
90
91 if (!$line || $line eq "exit") {
92 if (!$line) {
93 print "\n";
94 }
95 print "exit\n";
96
97 # This function needs to be called to reset the terminal settings,
98 # and calling it from the line handler keeps one extra prompt from
99 # being displayed.
100 $t->callback_handler_remove();
101 $running = 0;
102 } else {
103 if ($line ne "") {
104 $t->add_history($line);
105 }
106 print "input line: $line\n";
107 }
108 }
109
110 sub rltest_timeout_callback1 {
111 $t->set_timeout($timeout_secs, $timeout_usecs);
112 $t->callback_handler_install($prompt, \&cb_linehandler);
113 $running = 1;
114 while ($running) {
115 my $fds = '';
116 vec($fds, fileno($a->{instream}), 1) = 1;
117 # -1: error, 0: timeout, 1: input available (the timeout has not expired)
118 my ($r, $sec, $usec) = $t->timeout_remaining();
119 if ($r == 1) {
120 my $timeout = $sec + $usec / 1000000;
121 $r = select($fds, undef, undef, $timeout);
122 } elsif ($r < 0) {
123 die "Error in rl_timout_remaining().\n";
124 }
125 if ($r < 0 && $! && !$!{EINTR}) {
126 warn "rl-timeout: select: $!";
127 $t->callback_handler_remove();
128 last;
129 } elsif ($r == 0) { # timeout in rl_timeout_remaining() or select()
130 print "rl-timeout: timeout\n";
131 $t->callback_handler_remove();
132 last;
133 }
134
135 # FD_ISSET(fileno($a->{instream}), $fds)
136 if (vec($fds, fileno($a->{instream}), 1)) {
137 $t->callback_read_char();
138 }
139 }
140
141 print "rl-timeout: Event loop has exited\n";
142 }
143
144 # ****************************************************************
145 #
146 # Example 4: rl_callback_* () with rl_timeout_event_hook
147 #
148 # ****************************************************************
149
150 sub cb_timeouthandler {
151 print "timeout\n";
152 $t->callback_handler_remove();
153 $running = 0;
154 return READERR;
155 }
156
157 sub rltest_timeout_callback2 {
158 $t->set_timeout($timeout_secs, $timeout_usecs);
159 $a->{timeout_event_hook} = \&cb_timeouthandler;
160 $t->callback_handler_install($prompt, \&cb_linehandler);
161 $running = 1;
162 while ($running) {
163 $t->callback_read_char();
164 }
165
166 print "rl-timeout: Event loop has exited\n";
167 }
168
169 if ($#ARGV >= 0) {
170 if ($#ARGV >= 1) {
171 my $timeout = $ARGV[1];
172 if ($timeout <= 0.0) {
173 warn "rl-timeout: specify a positive number for timeout.\n";
174 exit(2);
175 } elsif ($timeout > $UINT_MAX) {
176 warn "rl-timeout: timeout too large.\n";
177 exit(2);
178 }
179 $timeout_secs = int $timeout;
180 $timeout_usecs = int(($timeout - $timeout_secs) * 1000000 + 0.5);
181 }
182 if ($ARGV[0] eq "readline1") {
183 rltest_timeout_readline1();
184 } elsif ($ARGV[0] eq "readline2") {
185 rltest_timeout_readline2();
186 } elsif ($ARGV[0] eq "callback1") {
187 rltest_timeout_callback1();
188 } elsif ($ARGV[0] eq "callback2") {
189 rltest_timeout_callback2();
190 } else {
191 usage();
192 exit(2);
193 }
194 } else {
195 usage();
196 exit(2);
197 }
198 exit(0);