Debian Codegraph @

docs/reference/libqmi-glib/meson.build

raw
1 # SPDX-License-Identifier: GPL-2.0-or-later
2 # Copyright (C) 2019 - 2021 IƱigo Martinez <[email protected]>
3
4 md_files = []
5 foreach md_src : gen_sections
6 md_files += fs.name(md_src)
7 endforeach
8
9 toml_data = configuration_data()
10 toml_data.set('VERSION', meson.project_version())
11 toml_data.set('CONTENT_FILES', '"' + '","'.join(md_files) + '"')
12
13 qmi_toml = configure_file(
14 input: 'libqmi-glib.toml.in',
15 output: 'libqmi-glib.toml',
16 configuration: toml_data,
17 )
18
19 dependency(
20 'gi-docgen',
21 version: '>= 2021.1',
22 native: true,
23 required: get_option('gtk_doc'),
24 )
25
26 gidocgen = find_program('gi-docgen')
27
28 docs_dir = qmi_datadir / 'doc'
29
30 custom_target(
31 'libqmi-glib',
32 input: [qmi_toml, libqmi_glib_gir[0]],
33 output: 'libqmi-glib-@0@'.format(qmi_gir_version),
34 command: [
35 gidocgen,
36 'generate',
37 '--quiet',
38 '--config=@INPUT0@',
39 '--output-dir=@OUTPUT@',
40 '--no-namespace-dir',
41 '--content-dir=@0@'.format(meson.current_source_dir()),
42 '--content-dir=@0@'.format(meson.project_build_root() / 'src' / 'libqmi-glib' / 'generated'),
43 '--fatal-warnings',
44 '@INPUT1@',
45 ],
46 build_by_default: true,
47 install: true,
48 install_dir: docs_dir,
49 depends: gen_sections_deps,
50 )