Debian Codegraph @

t/04_plugins/09_nickreclaim/04_immediate_quit.t

raw
1 use strict;
2 use warnings FATAL => 'all';
3 use lib 't/inc';
4 use POE;
5 use POE::Component::IRC;
6 use POE::Component::IRC::Plugin::NickReclaim;
7 use POE::Component::Server::IRC;
8 use Test::More tests => 8;
9
10 my $bot1 = POE::Component::IRC->spawn(
11 Flood => 1,
12 plugin_debug => 1,
13 alias => 'bot1',
14 );
15 my $bot2 = POE::Component::IRC->spawn(
16 Flood => 1,
17 plugin_debug => 1,
18 alias => 'bot2',
19 );
20 my $ircd = POE::Component::Server::IRC->spawn(
21 Auth => 0,
22 AntiFlood => 0,
23 );
24
25 $bot2->plugin_add(NickReclaim => POE::Component::IRC::Plugin::NickReclaim->new(
26 poll => 65, # longer than the test timeout
27 ));
28
29 POE::Session->create(
30 package_states => [
31 main => [qw(
32 _start
33 ircd_listener_add
34 ircd_listener_failure
35 _shutdown
36 irc_001
37 irc_433
38 irc_join
39 irc_nick
40 irc_disconnected
41 )],
42 ],
43 );
44
45 $poe_kernel->run();
46
47 sub _start {
48 my ($kernel) = $_[KERNEL];
49
50 $ircd->yield('register', 'all');
51 $ircd->yield('add_listener');
52 $kernel->delay(_shutdown => 60, 'Timed out');
53 }
54
55 sub ircd_listener_failure {
56 my ($kernel, $op, $reason) = @_[KERNEL, ARG1, ARG3];
57 $kernel->yield('_shutdown', "$op: $reason");
58 }
59
60 sub ircd_listener_add {
61 my ($kernel, $heap, $port) = @_[KERNEL, HEAP, ARG0];
62 $heap->{port} = $port;
63
64 $bot1->yield(register => 'all');
65 $bot1->yield(connect => {
66 nick => 'TestBot1',
67 server => '127.0.0.1',
68 port => $port,
69 });
70 }
71
72 sub irc_001 {
73 my $irc = $_[SENDER]->get_heap();
74 pass($irc->session_alias() . ' (nick=' . $irc->nick_name() .') logged in');
75 $irc->yield(join => '#testchannel');
76 }
77
78 sub irc_join {
79 my ($sender, $who, $where) = @_[SENDER, ARG0, ARG1];
80 my $nick = ( split /!/, $who )[0];
81 my $irc = $sender->get_heap();
82
83 return if $nick ne $irc->nick_name();
84 pass($irc->session_alias().' (nick='.$irc->nick_name().") joined $where");
85
86 if ($irc == $bot1) {
87 $bot2->yield(register => 'all');
88 $bot2->yield(connect => {
89 nick => 'TestBot1',
90 server => '127.0.0.1',
91 port => $_[HEAP]->{port},
92 });
93 }
94 else {
95 $bot1->yield('quit');
96 }
97 }
98
99 sub irc_433 {
100 my $irc = $_[SENDER]->get_heap();
101 pass($irc->session_alias . ' (nick=' . $irc->nick_name() .') nick collision');
102 }
103
104 sub irc_nick {
105 my ($sender, $new_nick) = @_[SENDER, ARG1];
106 my $irc = $sender->get_heap();
107 return if $irc != $bot2 || $new_nick ne 'TestBot1';
108
109 pass($irc->session_alias().' (nick='.$irc->nick_name().') reclaimed nick');
110 $irc->yield('quit');
111 }
112
113 sub irc_disconnected {
114 my ($kernel, $sender, $heap) = @_[KERNEL, SENDER, HEAP];
115 my $irc = $sender->get_heap();
116
117 pass($irc->session_alias . ' (nick=' . $irc->nick_name() .') disconnected');
118 $heap->{count}++;
119 $kernel->yield('_shutdown') if $heap->{count} == 2;
120 }
121
122 sub _shutdown {
123 my ($kernel, $error) = @_[KERNEL, ARG0];
124 fail($error) if defined $error;
125
126 $kernel->alarm_remove_all();
127 $ircd->yield('shutdown');
128 $bot1->yield('shutdown');
129 $bot2->yield('shutdown');
130 }
131