Debian Codegraph @

examples/connect.pl

raw
1 #!/usr/bin/perl
2
3 use v5.14;
4 use warnings;
5
6 use IO::Poll;
7 use IO::Socket::IP;
8 use Socket qw( SOCK_STREAM );
9 use Getopt::Long;
10
11 GetOptions(
12 'timeout=f' => \my $TIMEOUT,
13 ) or exit 1;
14
15 my $host = shift @ARGV or die "Need HOST\n";
16 my $service = shift @ARGV or die "Need SERVICE\n";
17
18 my $socket = IO::Socket::IP->new(
19 PeerHost => $host,
20 PeerService => $service,
21 Type => SOCK_STREAM,
22 Timeout => $TIMEOUT,
23 ) or die "Cannot connect to $host:$service - $IO::Socket::errstr";
24
25 printf STDERR "Connected to %s:%s\n", $socket->peerhost_service;
26
27 my $poll = IO::Poll->new;
28
29 $poll->mask( \*STDIN => POLLIN );
30 $poll->mask( $socket => POLLIN );
31
32 while(1) {
33 $poll->poll( undef );
34
35 if( $poll->events( \*STDIN ) ) {
36 my $ret = STDIN->sysread( my $buffer, 8192 );
37 defined $ret or die "Cannot read STDIN - $!\n";
38 $ret or last;
39 $socket->syswrite( $buffer );
40 }
41 if( $poll->events( $socket ) ) {
42 my $ret = $socket->sysread( my $buffer, 8192 );
43 defined $ret or die "Cannot read socket - $!\n";
44 $ret or last;
45 STDOUT->syswrite( $buffer );
46 }
47 }