Debian Codegraph @

src/xtensa/sysv.S

raw
1 /* -----------------------------------------------------------------------
2 sysv.S - Copyright (c) 2013 Tensilica, Inc.
3
4 XTENSA Foreign Function Interface
5
6 Permission is hereby granted, free of charge, to any person obtaining
7 a copy of this software and associated documentation files (the
8 ``Software''), to deal in the Software without restriction, including
9 without limitation the rights to use, copy, modify, merge, publish,
10 distribute, sublicense, and/or sell copies of the Software, and to
11 permit persons to whom the Software is furnished to do so, subject to
12 the following conditions:
13
14 The above copyright notice and this permission notice shall be included
15 in all copies or substantial portions of the Software.
16
17 THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND,
18 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
19 MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
20 NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
21 HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
22 WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
23 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
24 DEALINGS IN THE SOFTWARE.
25 ----------------------------------------------------------------------- */
26
27 #define LIBFFI_ASM
28 #include <fficonfig.h>
29 #include <ffi.h>
30
31 #define ENTRY(name) .text; .globl name; .type name,@function; .align 4; name:
32 #define END(name) .size name , . - name
33
34 /* Assert that the table below is in sync with ffi.h. */
35
36 #if FFI_TYPE_UINT8 != 5 \
37 || FFI_TYPE_SINT8 != 6 \
38 || FFI_TYPE_UINT16 != 7 \
39 || FFI_TYPE_SINT16 != 8 \
40 || FFI_TYPE_UINT32 != 9 \
41 || FFI_TYPE_SINT32 != 10 \
42 || FFI_TYPE_UINT64 != 11
43 #error "xtensa/sysv.S out of sync with ffi.h"
44 #endif
45
46 #define FFI_REGISTER_ARGS_OFFSET ((XTENSA_STACK_ALIGNMENT - \
47 FFI_REGISTER_NARGS * 4) & \
48 (XTENSA_STACK_ALIGNMENT - 1))
49
50 /* ffi_call_SYSV (rvalue, rbytes, flags, (*fnaddr)(), bytes, ecif)
51 void *rvalue; a2
52 unsigned long rbytes; a3
53 unsigned flags; a4
54 void (*fnaddr)(); a5
55 unsigned long bytes; a6
56 extended_cif* ecif) a7
57 */
58
59 ENTRY(ffi_call_SYSV)
60
61 entry a1, 32 # 32 byte frame for using call8 below
62
63 mov a10, a7 # a10(->arg0): ecif
64 sub a11, a1, a6 # a11(->arg1): stack pointer
65 mov a7, a1 # fp
66 movsp a1, a11 # set new sp = old_sp - bytes
67
68 # align ffi_prep_args stack argument so that arguments
69 # passed on stack if any start on 16-byte aligned boundary
70
71 addi a11, a11, FFI_REGISTER_ARGS_OFFSET
72
73 movi a8, ffi_prep_args
74 callx8 a8 # ffi_prep_args(ecif, stack)
75
76 # prepare to move stack pointer back
77 # to point to arguments passed on stack
78
79 addi a6, a1, FFI_REGISTER_ARGS_SPACE
80
81 # we can pass up to 6 arguments in registers
82 # for simplicity, just load 6 arguments
83
84 l32i a10, a1, FFI_REGISTER_ARGS_OFFSET + 0
85 l32i a11, a1, FFI_REGISTER_ARGS_OFFSET + 4
86 l32i a12, a1, FFI_REGISTER_ARGS_OFFSET + 8
87 l32i a13, a1, FFI_REGISTER_ARGS_OFFSET + 12
88 l32i a14, a1, FFI_REGISTER_ARGS_OFFSET + 16
89 l32i a15, a1, FFI_REGISTER_ARGS_OFFSET + 20
90
91 # move stack pointer
92
93 movsp a1, a6
94
95 callx8 a5 # (*fn)(args...)
96
97 # Handle return value(s)
98
99 beqz a2, .Lexit
100
101 movi a5, FFI_TYPE_STRUCT
102 bne a4, a5, .Lstore
103 movi a5, 16
104 blt a5, a3, .Lexit
105
106 s32i a10, a2, 0
107 blti a3, 5, .Lexit
108 addi a3, a3, -1
109 s32i a11, a2, 4
110 blti a3, 8, .Lexit
111 s32i a12, a2, 8
112 blti a3, 12, .Lexit
113 s32i a13, a2, 12
114
115 .Lexit: retw
116
117 .Lstore:
118 addi a4, a4, -FFI_TYPE_UINT8
119 bgei a4, 7, .Lexit # should never happen
120 movi a6, store_calls
121 add a4, a4, a4
122 addx4 a6, a4, a6 # store_table + idx * 8
123 jx a6
124
125 .align 8
126 store_calls:
127 # UINT8
128 s8i a10, a2, 0
129 retw
130
131 # SINT8
132 .align 8
133 s8i a10, a2, 0
134 retw
135
136 # UINT16
137 .align 8
138 s16i a10, a2, 0
139 retw
140
141 # SINT16
142 .align 8
143 s16i a10, a2, 0
144 retw
145
146 # UINT32
147 .align 8
148 s32i a10, a2, 0
149 retw
150
151 # SINT32
152 .align 8
153 s32i a10, a2, 0
154 retw
155
156 # UINT64
157 .align 8
158 s32i a10, a2, 0
159 s32i a11, a2, 4
160 retw
161
162 END(ffi_call_SYSV)
163
164
165 /*
166 * void ffi_cacheflush (unsigned long start, unsigned long end)
167 */
168
169 #define EXTRA_ARGS_SIZE 24
170
171 ENTRY(ffi_cacheflush)
172
173 entry a1, 32
174
175 1:
176 #if XCHAL_DCACHE_SIZE
177 dhwbi a2, 0
178 #endif
179 #if XCHAL_ICACHE_SIZE
180 ihi a2, 0
181 #endif
182 addi a2, a2, 4
183 blt a2, a3, 1b
184
185 retw
186
187 END(ffi_cacheflush)
188
189 /* ffi_trampoline is copied to the stack */
190
191 ENTRY(ffi_trampoline)
192
193 /* 32 bytes for spill + spill overflow area of a frame that uses
194 call8,
195 FFI_REGISTER_NARGS * 4 bytes for arguments passed in registers,
196 aligned up to 4 to maintain 16 byte stack alignment,
197 4 * 4 bytes for the result.
198 This size must be in sync with ffi_closure_SYSV_inner logic.
199 */
200 entry a1, 32 + FFI_REGISTER_ARGS_SPACE + (4 * 4) # [ 0]
201 j 2f # [ 3]
202 .align 4 # [ 6]
203 1: .long 0 # [ 8]
204 2: l32r a15, 1b # [12]
205 _mov a14, a0 # [15]
206 callx0 a15 # [18]
207 # [21]
208 END(ffi_trampoline)
209
210 /*
211 * ffi_closure()
212 *
213 * a0: closure + 21
214 * a14: return address (a0)
215 */
216
217 ENTRY(ffi_closure_SYSV)
218
219 /* intentionally omitting entry here */
220
221 # restore return address (a0) and move pointer to closure to a10
222 addi a10, a0, -21
223 mov a0, a14
224
225 # allow up to 4 arguments as return values
226 addi a11, a1, 4 * 4
227
228 # save up to 6 arguments to stack (allocated by entry below)
229 s32i a2, a11, 0
230 s32i a3, a11, 4
231 s32i a4, a11, 8
232 s32i a5, a11, 12
233 s32i a6, a11, 16
234 s32i a7, a11, 20
235
236 movi a8, ffi_closure_SYSV_inner
237 mov a12, a1
238 callx8 a8 # .._inner(*closure, **avalue, *rvalue)
239
240 # load up to four return arguments
241 l32i a2, a1, 0
242 l32i a3, a1, 4
243 l32i a4, a1, 8
244 l32i a5, a1, 12
245
246 # (sign-)extend return value
247 movi a11, FFI_TYPE_UINT8
248 bne a10, a11, 1f
249 extui a2, a2, 0, 8
250 retw
251
252 1: movi a11, FFI_TYPE_SINT8
253 bne a10, a11, 1f
254 sext a2, a2, 7
255 retw
256
257 1: movi a11, FFI_TYPE_UINT16
258 bne a10, a11, 1f
259 extui a2, a2, 0, 16
260 retw
261
262 1: movi a11, FFI_TYPE_SINT16
263 bne a10, a11, 1f
264 sext a2, a2, 15
265
266 1: retw
267
268 END(ffi_closure_SYSV)