Debian Codegraph @

src/powerpc/ppc_closure.S

raw
1 /* -----------------------------------------------------------------------
2 sysv.h - Copyright (c) 2003 Jakub Jelinek <[email protected]>
3 Copyright (c) 2008 Red Hat, Inc.
4
5 PowerPC Assembly glue.
6
7 Permission is hereby granted, free of charge, to any person obtaining
8 a copy of this software and associated documentation files (the
9 ``Software''), to deal in the Software without restriction, including
10 without limitation the rights to use, copy, modify, merge, publish,
11 distribute, sublicense, and/or sell copies of the Software, and to
12 permit persons to whom the Software is furnished to do so, subject to
13 the following conditions:
14
15 The above copyright notice and this permission notice shall be included
16 in all copies or substantial portions of the Software.
17
18 THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND,
19 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
20 MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
21 NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
22 HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
23 WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
24 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
25 DEALINGS IN THE SOFTWARE.
26 ----------------------------------------------------------------------- */
27 #define LIBFFI_ASM
28 #include <fficonfig.h>
29 #include <ffi.h>
30 #include "internal.h"
31 #include <powerpc/asm.h>
32
33 .file "ppc_closure.S"
34
35 #ifndef POWERPC64
36
37 FFI_HIDDEN(ffi_closure_SYSV)
38 ENTRY(ffi_closure_SYSV)
39 .cfi_startproc
40 stwu %r1,-144(%r1)
41 .cfi_def_cfa_offset 144
42 mflr %r0
43 stw %r0,148(%r1)
44 .cfi_offset 65, 4
45
46 # we want to build up an areas for the parameters passed
47 # in registers (both floating point and integer)
48
49 # so first save gpr 3 to gpr 10 (aligned to 4)
50 stw %r3, 16(%r1)
51 stw %r4, 20(%r1)
52 stw %r5, 24(%r1)
53
54 # set up registers for the routine that does the work
55
56 # closure->cif
57 lwz %r3,FFI_TRAMPOLINE_SIZE(%r11)
58 # closure->fun
59 lwz %r4,FFI_TRAMPOLINE_SIZE+4(%r11)
60 # closure->user_data
61 lwz %r5,FFI_TRAMPOLINE_SIZE+8(%r11)
62
63 .Ldoclosure:
64 stw %r6, 28(%r1)
65 stw %r7, 32(%r1)
66 stw %r8, 36(%r1)
67 stw %r9, 40(%r1)
68 stw %r10,44(%r1)
69
70 #ifndef __NO_FPRS__
71 # next save fpr 1 to fpr 8 (aligned to 8)
72 stfd %f1, 48(%r1)
73 stfd %f2, 56(%r1)
74 stfd %f3, 64(%r1)
75 stfd %f4, 72(%r1)
76 stfd %f5, 80(%r1)
77 stfd %f6, 88(%r1)
78 stfd %f7, 96(%r1)
79 stfd %f8, 104(%r1)
80 #endif
81
82 # pointer to the result storage
83 addi %r6,%r1,112
84
85 # pointer to the saved gpr registers
86 addi %r7,%r1,16
87
88 # pointer to the saved fpr registers
89 addi %r8,%r1,48
90
91 # pointer to the outgoing parameter save area in the previous frame
92 # i.e. the previous frame pointer + 8
93 addi %r9,%r1,152
94
95 # make the call
96 bl ffi_closure_helper_SYSV@local
97 .Lret:
98 # now r3 contains the return type
99 # so use it to look up in a table
100 # so we know how to deal with each type
101
102 # look up the proper starting point in table
103 # by using return type as offset
104
105 mflr %r4 # move address of .Lret to r4
106 slwi %r3,%r3,4 # now multiply return type by 16
107 addi %r4, %r4, .Lret_type0 - .Lret
108 lwz %r0,148(%r1)
109 add %r3,%r3,%r4 # add contents of table to table address
110 mtctr %r3
111 bctr # jump to it
112
113 # Each of the ret_typeX code fragments has to be exactly 16 bytes long
114 # (4 instructions). For cache effectiveness we align to a 16 byte boundary
115 # first.
116 .align 4
117 # case FFI_TYPE_VOID
118 .Lret_type0:
119 mtlr %r0
120 addi %r1,%r1,144
121 .cfi_def_cfa_offset 0
122 blr
123 .cfi_def_cfa_offset 144
124 nop
125
126 # case FFI_TYPE_INT
127 lwz %r3,112+0(%r1)
128 mtlr %r0
129 .Lfinish:
130 addi %r1,%r1,144
131 .cfi_def_cfa_offset 0
132 blr
133 .cfi_def_cfa_offset 144
134
135 # case FFI_TYPE_FLOAT
136 #ifndef __NO_FPRS__
137 lfs %f1,112+0(%r1)
138 #else
139 nop
140 #endif
141 mtlr %r0
142 addi %r1,%r1,144
143 .cfi_def_cfa_offset 0
144 blr
145 .cfi_def_cfa_offset 144
146
147 # case FFI_TYPE_DOUBLE
148 #ifndef __NO_FPRS__
149 lfd %f1,112+0(%r1)
150 #else
151 nop
152 #endif
153 mtlr %r0
154 addi %r1,%r1,144
155 .cfi_def_cfa_offset 0
156 blr
157 .cfi_def_cfa_offset 144
158
159 # case FFI_TYPE_LONGDOUBLE
160 #ifndef __NO_FPRS__
161 lfd %f1,112+0(%r1)
162 lfd %f2,112+8(%r1)
163 mtlr %r0
164 b .Lfinish
165 #else
166 mtlr %r0
167 addi %r1,%r1,144
168 .cfi_def_cfa_offset 0
169 blr
170 .cfi_def_cfa_offset 144
171 nop
172 #endif
173
174 # case FFI_TYPE_UINT8
175 #ifdef __LITTLE_ENDIAN__
176 lbz %r3,112+0(%r1)
177 #else
178 lbz %r3,112+3(%r1)
179 #endif
180 mtlr %r0
181 addi %r1,%r1,144
182 .cfi_def_cfa_offset 0
183 blr
184 .cfi_def_cfa_offset 144
185
186 # case FFI_TYPE_SINT8
187 #ifdef __LITTLE_ENDIAN__
188 lbz %r3,112+0(%r1)
189 #else
190 lbz %r3,112+3(%r1)
191 #endif
192 extsb %r3,%r3
193 mtlr %r0
194 b .Lfinish
195
196 # case FFI_TYPE_UINT16
197 #ifdef __LITTLE_ENDIAN__
198 lhz %r3,112+0(%r1)
199 #else
200 lhz %r3,112+2(%r1)
201 #endif
202 mtlr %r0
203 addi %r1,%r1,144
204 .cfi_def_cfa_offset 0
205 blr
206 .cfi_def_cfa_offset 144
207
208 # case FFI_TYPE_SINT16
209 #ifdef __LITTLE_ENDIAN__
210 lha %r3,112+0(%r1)
211 #else
212 lha %r3,112+2(%r1)
213 #endif
214 mtlr %r0
215 addi %r1,%r1,144
216 .cfi_def_cfa_offset 0
217 blr
218 .cfi_def_cfa_offset 144
219
220 # case FFI_TYPE_UINT32
221 lwz %r3,112+0(%r1)
222 mtlr %r0
223 addi %r1,%r1,144
224 .cfi_def_cfa_offset 0
225 blr
226 .cfi_def_cfa_offset 144
227
228 # case FFI_TYPE_SINT32
229 lwz %r3,112+0(%r1)
230 mtlr %r0
231 addi %r1,%r1,144
232 .cfi_def_cfa_offset 0
233 blr
234 .cfi_def_cfa_offset 144
235
236 # case FFI_TYPE_UINT64
237 lwz %r3,112+0(%r1)
238 lwz %r4,112+4(%r1)
239 mtlr %r0
240 b .Lfinish
241
242 # case FFI_TYPE_SINT64
243 lwz %r3,112+0(%r1)
244 lwz %r4,112+4(%r1)
245 mtlr %r0
246 b .Lfinish
247
248 # case FFI_TYPE_STRUCT
249 mtlr %r0
250 addi %r1,%r1,144
251 .cfi_def_cfa_offset 0
252 blr
253 .cfi_def_cfa_offset 144
254 nop
255
256 # case FFI_TYPE_POINTER
257 lwz %r3,112+0(%r1)
258 mtlr %r0
259 addi %r1,%r1,144
260 .cfi_def_cfa_offset 0
261 blr
262 .cfi_def_cfa_offset 144
263
264 # case FFI_TYPE_UINT128
265 lwz %r3,112+0(%r1)
266 lwz %r4,112+4(%r1)
267 lwz %r5,112+8(%r1)
268 b .Luint128
269
270 # The return types below are only used when the ABI type is FFI_SYSV.
271 # case FFI_SYSV_TYPE_SMALL_STRUCT + 1. One byte struct.
272 lbz %r3,112+0(%r1)
273 mtlr %r0
274 addi %r1,%r1,144
275 .cfi_def_cfa_offset 0
276 blr
277 .cfi_def_cfa_offset 144
278
279 # case FFI_SYSV_TYPE_SMALL_STRUCT + 2. Two byte struct.
280 lhz %r3,112+0(%r1)
281 mtlr %r0
282 addi %r1,%r1,144
283 .cfi_def_cfa_offset 0
284 blr
285 .cfi_def_cfa_offset 144
286
287 # case FFI_SYSV_TYPE_SMALL_STRUCT + 3. Three byte struct.
288 lwz %r3,112+0(%r1)
289 #ifdef __LITTLE_ENDIAN__
290 mtlr %r0
291 addi %r1,%r1,144
292 .cfi_def_cfa_offset 0
293 blr
294 .cfi_def_cfa_offset 144
295 #else
296 srwi %r3,%r3,8
297 mtlr %r0
298 b .Lfinish
299 #endif
300
301 # case FFI_SYSV_TYPE_SMALL_STRUCT + 4. Four byte struct.
302 lwz %r3,112+0(%r1)
303 mtlr %r0
304 addi %r1,%r1,144
305 .cfi_def_cfa_offset 0
306 blr
307 .cfi_def_cfa_offset 144
308
309 # case FFI_SYSV_TYPE_SMALL_STRUCT + 5. Five byte struct.
310 lwz %r3,112+0(%r1)
311 lwz %r4,112+4(%r1)
312 #ifdef __LITTLE_ENDIAN__
313 mtlr %r0
314 b .Lfinish
315 #else
316 li %r5,24
317 b .Lstruct567
318 #endif
319
320 # case FFI_SYSV_TYPE_SMALL_STRUCT + 6. Six byte struct.
321 lwz %r3,112+0(%r1)
322 lwz %r4,112+4(%r1)
323 #ifdef __LITTLE_ENDIAN__
324 mtlr %r0
325 b .Lfinish
326 #else
327 li %r5,16
328 b .Lstruct567
329 #endif
330
331 # case FFI_SYSV_TYPE_SMALL_STRUCT + 7. Seven byte struct.
332 lwz %r3,112+0(%r1)
333 lwz %r4,112+4(%r1)
334 #ifdef __LITTLE_ENDIAN__
335 mtlr %r0
336 b .Lfinish
337 #else
338 li %r5,8
339 b .Lstruct567
340 #endif
341
342 # case FFI_SYSV_TYPE_SMALL_STRUCT + 8. Eight byte struct.
343 lwz %r3,112+0(%r1)
344 lwz %r4,112+4(%r1)
345 mtlr %r0
346 b .Lfinish
347
348 #ifndef __LITTLE_ENDIAN__
349 .Lstruct567:
350 subfic %r6,%r5,32
351 srw %r4,%r4,%r5
352 slw %r6,%r3,%r6
353 srw %r3,%r3,%r5
354 or %r4,%r6,%r4
355 mtlr %r0
356 addi %r1,%r1,144
357 .cfi_def_cfa_offset 0
358 blr
359 .cfi_def_cfa_offset 144
360 #endif
361
362 .Luint128:
363 lwz %r6,112+12(%r1)
364 mtlr %r0
365 addi %r1,%r1,144
366 .cfi_def_cfa_offset 0
367 blr
368 .cfi_endproc
369 END(ffi_closure_SYSV)
370
371
372 FFI_HIDDEN(ffi_go_closure_sysv)
373 ENTRY(ffi_go_closure_sysv)
374 .cfi_startproc
375 stwu %r1,-144(%r1)
376 .cfi_def_cfa_offset 144
377 mflr %r0
378 stw %r0,148(%r1)
379 .cfi_offset 65, 4
380
381 stw %r3, 16(%r1)
382 stw %r4, 20(%r1)
383 stw %r5, 24(%r1)
384
385 # closure->cif
386 lwz %r3,4(%r11)
387 # closure->fun
388 lwz %r4,8(%r11)
389 # user_data
390 mr %r5,%r11
391 b .Ldoclosure
392 .cfi_endproc
393 END(ffi_go_closure_sysv)
394
395 #ifdef FFI_EXEC_STATIC_TRAMP
396 .text
397 .align PPC_TRAMP_MAP_SHIFT
398 FFI_HIDDEN (trampoline_code_table)
399 .globl trampoline_code_table
400 .type trampoline_code_table,@function
401 trampoline_code_table:
402 .rept PPC_TRAMP_MAP_SIZE / PPC_TRAMP_SIZE
403 mflr %r0
404 bcl 20,31,$+4
405 mflr %r11
406 addis %r11,%r11,PPC_TRAMP_MAP_SIZE@ha
407 mtlr %r0
408 lwz %r0,(PPC_TRAMP_MAP_SIZE-4)@l(%r11)
409 mtctr %r0
410 lwz %r11,(PPC_TRAMP_MAP_SIZE-8)@l(%r11)
411 bctr
412 nop
413 .endr
414 .size trampoline_code_table,.-trampoline_code_table
415 .align PPC_TRAMP_MAP_SHIFT
416 #endif /* FFI_EXEC_STATIC_TRAMP */
417
418 #if defined __ELF__ && defined __linux__
419 .section .note.GNU-stack,"",@progbits
420 #endif
421 #endif