Debian Codegraph @

src/pa/hpux32.S

raw
1 /* -----------------------------------------------------------------------
2 hpux32.S - Copyright (c) 2006 Free Software Foundation, Inc.
3 (c) 2008 Red Hat, Inc.
4 based on src/pa/linux.S
5
6 HP-UX PA Foreign Function Interface
7
8 Permission is hereby granted, free of charge, to any person obtaining
9 a copy of this software and associated documentation files (the
10 ``Software''), to deal in the Software without restriction, including
11 without limitation the rights to use, copy, modify, merge, publish,
12 distribute, sublicense, and/or sell copies of the Software, and to
13 permit persons to whom the Software is furnished to do so, subject to
14 the following conditions:
15
16 The above copyright notice and this permission notice shall be included
17 in all copies or substantial portions of the Software.
18
19 THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, EXPRESS
20 OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
21 MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
22 IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY CLAIM, DAMAGES OR
23 OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
24 ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
25 OTHER DEALINGS IN THE SOFTWARE.
26 ----------------------------------------------------------------------- */
27
28 #define LIBFFI_ASM
29 #include <fficonfig.h>
30 #include <ffi.h>
31
32 .LEVEL 1.1
33 .SPACE $PRIVATE$
34 .IMPORT $global$,DATA
35 .IMPORT $$dyncall,MILLICODE
36 .SUBSPA $DATA$
37 .align 4
38
39 /* void ffi_call_pa32(void (*)(char *, extended_cif *),
40 extended_cif *ecif,
41 unsigned bytes,
42 unsigned flags,
43 unsigned *rvalue,
44 void (*fn)(void));
45 */
46
47 .export ffi_call_pa32,ENTRY,PRIV_LEV=3
48 .import ffi_prep_args_pa32,CODE
49
50 .SPACE $TEXT$
51 .SUBSPA $CODE$
52 .align 4
53
54 L$FB1
55 ffi_call_pa32
56 .proc
57 .callinfo FRAME=64,CALLS,SAVE_RP,SAVE_SP,ENTRY_GR=4
58 .entry
59 stw %rp, -20(%sp)
60 copy %r3, %r1
61 L$CFI11
62 copy %sp, %r3
63 L$CFI12
64
65 /* Setup the stack for calling prep_args...
66 We want the stack to look like this:
67
68 [ Previous stack ] <- %r3
69
70 [ 64-bytes register save area ] <- %r4
71
72 [ Stack space for actual call, passed as ] <- %arg0
73 [ arg0 to ffi_prep_args_pa32 ]
74
75 [ Stack for calling prep_args ] <- %sp
76 */
77
78 stwm %r1, 64(%sp)
79 stw %r4, 12(%r3)
80 L$CFI13
81 copy %sp, %r4
82
83 addl %arg2, %r4, %arg0 ; arg stack
84 stw %arg3, -48(%r3) ; save flags we need it later
85
86 /* Call prep_args:
87 %arg0(stack) -- set up above
88 %arg1(ecif) -- same as incoming param
89 %arg2(bytes) -- same as incoming param */
90 bl ffi_prep_args_pa32,%r2
91 ldo 64(%arg0), %sp
92 ldo -64(%sp), %sp
93
94 /* now %sp should point where %arg0 was pointing. */
95
96 /* Load the arguments that should be passed in registers
97 The fp args are loaded by the prep_args function. */
98 ldw -36(%sp), %arg0
99 ldw -40(%sp), %arg1
100 ldw -44(%sp), %arg2
101 ldw -48(%sp), %arg3
102
103 /* in case the function is going to return a structure
104 we need to give it a place to put the result. */
105 ldw -52(%r3), %ret0 ; %ret0 <- rvalue
106 ldw -56(%r3), %r22 ; %r22 <- function to call
107 bl $$dyncall, %r31 ; Call the user function
108 copy %r31, %rp
109
110 /* Prepare to store the result; we need to recover flags and rvalue. */
111 ldw -48(%r3), %r21 ; r21 <- flags
112
113 /* Adjust flags range from [-8, 15] to [0, 23]. */
114 addi 8, %r21, %r21
115
116 blr %r21, %r0
117 ldw -52(%r3), %r20 ; r20 <- rvalue
118
119 /* Giant jump table */
120 /* 8-byte small struct */
121 b,n L$smst8
122 nop
123 /* 7-byte small struct */
124 b,n L$smst7
125 nop
126 /* 6-byte small struct */
127 b,n L$smst6
128 nop
129 /* 5-byte small struct */
130 b,n L$smst5
131 nop
132 /* 4-byte small struct */
133 b,n L$smst4
134 nop
135 /* 3-byte small struct */
136 b,n L$smst3
137 nop
138 /* 2-byte small struct */
139 b,n L$smst2
140 nop
141 /* 1-byte small struct */
142 b L$done
143 stb %ret0, 0(%r20)
144 /* void */
145 b,n L$done
146 nop
147 /* int */
148 b L$done
149 stw %ret0, 0(%r20)
150 /* float */
151 b L$done
152 fstw %fr4L,0(%r20)
153 /* double */
154 b L$done
155 fstd %fr4,0(%r20)
156 /* long double */
157 b,n L$done
158 nop
159 /* unsigned int8 */
160 b L$done
161 stw %ret0, 0(%r20)
162 /* signed int8 */
163 b L$done
164 stw %ret0, 0(%r20)
165 /* unsigned int16 */
166 b L$done
167 stw %ret0, 0(%r20)
168 /* signed int16 */
169 b L$done
170 stw %ret0, 0(%r20)
171 /* unsigned int32 */
172 b L$done
173 stw %ret0, 0(%r20)
174 /* signed int32 */
175 b L$done
176 stw %ret0, 0(%r20)
177 /* unsigned int64 */
178 b,n L$uint64
179 nop
180 /* signed int64 */
181 b,n L$sint64
182 nop
183 /* large struct */
184 b,n L$done
185 nop
186 /* pointer */
187 b L$done
188 stw %ret0, 0(%r20)
189 /* complex */
190 b,n L$done
191 nop
192
193 /* Store the result according to the return type. The most
194 likely types should come first. */
195
196 L$uint64
197 L$sint64
198 stw %ret0, 0(%r20)
199 b L$done
200 stw %ret1, 4(%r20)
201
202 L$smst2
203 /* 2-byte structs are returned in ret0 as ????xxyy. */
204 extru %ret0, 23, 8, %r22
205 stbs,ma %r22, 1(%r20)
206 b L$done
207 stb %ret0, 0(%r20)
208
209 L$smst3
210 /* 3-byte structs are returned in ret0 as ??xxyyzz. */
211 extru %ret0, 15, 8, %r22
212 stbs,ma %r22, 1(%r20)
213 extru %ret0, 23, 8, %r22
214 stbs,ma %r22, 1(%r20)
215 b L$done
216 stb %ret0, 0(%r20)
217
218 L$smst4
219 /* 4-byte structs are returned in ret0 as wwxxyyzz. */
220 extru %ret0, 7, 8, %r22
221 stbs,ma %r22, 1(%r20)
222 extru %ret0, 15, 8, %r22
223 stbs,ma %r22, 1(%r20)
224 extru %ret0, 23, 8, %r22
225 stbs,ma %r22, 1(%r20)
226 b L$done
227 stb %ret0, 0(%r20)
228
229 L$smst5
230 /* 5 byte values are returned right justified:
231 ret0 ret1
232 5: ??????aa bbccddee */
233 stbs,ma %ret0, 1(%r20)
234 extru %ret1, 7, 8, %r22
235 stbs,ma %r22, 1(%r20)
236 extru %ret1, 15, 8, %r22
237 stbs,ma %r22, 1(%r20)
238 extru %ret1, 23, 8, %r22
239 stbs,ma %r22, 1(%r20)
240 b L$done
241 stb %ret1, 0(%r20)
242
243 L$smst6
244 /* 6 byte values are returned right justified:
245 ret0 ret1
246 6: ????aabb ccddeeff */
247 extru %ret0, 23, 8, %r22
248 stbs,ma %r22, 1(%r20)
249 stbs,ma %ret0, 1(%r20)
250 extru %ret1, 7, 8, %r22
251 stbs,ma %r22, 1(%r20)
252 extru %ret1, 15, 8, %r22
253 stbs,ma %r22, 1(%r20)
254 extru %ret1, 23, 8, %r22
255 stbs,ma %r22, 1(%r20)
256 b L$done
257 stb %ret1, 0(%r20)
258
259 L$smst7
260 /* 7 byte values are returned right justified:
261 ret0 ret1
262 7: ??aabbcc ddeeffgg */
263 extru %ret0, 15, 8, %r22
264 stbs,ma %r22, 1(%r20)
265 extru %ret0, 23, 8, %r22
266 stbs,ma %r22, 1(%r20)
267 stbs,ma %ret0, 1(%r20)
268 extru %ret1, 7, 8, %r22
269 stbs,ma %r22, 1(%r20)
270 extru %ret1, 15, 8, %r22
271 stbs,ma %r22, 1(%r20)
272 extru %ret1, 23, 8, %r22
273 stbs,ma %r22, 1(%r20)
274 b L$done
275 stb %ret1, 0(%r20)
276
277 L$smst8
278 /* 8 byte values are returned right justified:
279 ret0 ret1
280 8: aabbccdd eeffgghh */
281 extru %ret0, 7, 8, %r22
282 stbs,ma %r22, 1(%r20)
283 extru %ret0, 15, 8, %r22
284 stbs,ma %r22, 1(%r20)
285 extru %ret0, 23, 8, %r22
286 stbs,ma %r22, 1(%r20)
287 stbs,ma %ret0, 1(%r20)
288 extru %ret1, 7, 8, %r22
289 stbs,ma %r22, 1(%r20)
290 extru %ret1, 15, 8, %r22
291 stbs,ma %r22, 1(%r20)
292 extru %ret1, 23, 8, %r22
293 stbs,ma %r22, 1(%r20)
294 stb %ret1, 0(%r20)
295
296 L$done
297 /* all done, return */
298 copy %r4, %sp ; pop arg stack
299 ldw 12(%r3), %r4
300 ldwm -64(%sp), %r3 ; .. and pop stack
301 ldw -20(%sp), %rp
302 bv %r0(%rp)
303 nop
304 .exit
305 .procend
306 L$FE1
307
308 /* void ffi_closure_pa32(void);
309 Called with closure argument in %r19 */
310
311 .SPACE $TEXT$
312 .SUBSPA $CODE$
313 .export ffi_closure_pa32,ENTRY,PRIV_LEV=3,RTNVAL=GR
314 .import ffi_closure_inner_pa32,CODE
315 .align 4
316 L$FB2
317 ffi_closure_pa32
318 .proc
319 .callinfo FRAME=64,CALLS,SAVE_RP,SAVE_SP,ENTRY_GR=3
320 .entry
321
322 stw %rp, -20(%sp)
323 copy %r3, %r1
324 L$CFI21
325 copy %sp, %r3
326 L$CFI22
327 stwm %r1, 64(%sp)
328
329 /* Put arguments onto the stack and call ffi_closure_inner. */
330 stw %arg0, -36(%r3)
331 stw %arg1, -40(%r3)
332 stw %arg2, -44(%r3)
333 stw %arg3, -48(%r3)
334
335 /* Retrieve closure pointer and real gp. */
336 copy %r19, %arg0
337 ldw 8(%r19), %r19
338 bl ffi_closure_inner_pa32, %r2
339 copy %r3, %arg1
340 ldwm -64(%sp), %r3
341 ldw -20(%sp), %rp
342 ldw -36(%sp), %ret0
343 bv %r0(%rp)
344 ldw -40(%sp), %ret1
345 .exit
346 .procend
347 L$FE2:
348
349 .SPACE $PRIVATE$
350 .SUBSPA $DATA$
351
352 .align 4
353 .EXPORT _GLOBAL__F_ffi_call_pa32,DATA
354 _GLOBAL__F_ffi_call_pa32
355 L$frame1:
356 .word L$ECIE1-L$SCIE1 ;# Length of Common Information Entry
357 L$SCIE1:
358 .word 0x0 ;# CIE Identifier Tag
359 .byte 0x1 ;# CIE Version
360 .ascii "\0" ;# CIE Augmentation
361 .uleb128 0x1 ;# CIE Code Alignment Factor
362 .sleb128 4 ;# CIE Data Alignment Factor
363 .byte 0x2 ;# CIE RA Column
364 .byte 0xc ;# DW_CFA_def_cfa
365 .uleb128 0x1e
366 .uleb128 0x0
367 .align 4
368 L$ECIE1:
369 L$SFDE1:
370 .word L$EFDE1-L$ASFDE1 ;# FDE Length
371 L$ASFDE1:
372 .word L$ASFDE1-L$frame1 ;# FDE CIE offset
373 .word L$FB1 ;# FDE initial location
374 .word L$FE1-L$FB1 ;# FDE address range
375
376 .byte 0x4 ;# DW_CFA_advance_loc4
377 .word L$CFI11-L$FB1
378 .byte 0x83 ;# DW_CFA_offset, column 0x3
379 .uleb128 0x0
380 .byte 0x11 ;# DW_CFA_offset_extended_sf; save r2 at [r30-20]
381 .uleb128 0x2
382 .sleb128 -5
383
384 .byte 0x4 ;# DW_CFA_advance_loc4
385 .word L$CFI12-L$CFI11
386 .byte 0xd ;# DW_CFA_def_cfa_register = r3
387 .uleb128 0x3
388
389 .byte 0x4 ;# DW_CFA_advance_loc4
390 .word L$CFI13-L$CFI12
391 .byte 0x84 ;# DW_CFA_offset, column 0x4
392 .uleb128 0x3
393
394 .align 4
395 L$EFDE1:
396
397 L$SFDE2:
398 .word L$EFDE2-L$ASFDE2 ;# FDE Length
399 L$ASFDE2:
400 .word L$ASFDE2-L$frame1 ;# FDE CIE offset
401 .word L$FB2 ;# FDE initial location
402 .word L$FE2-L$FB2 ;# FDE address range
403 .byte 0x4 ;# DW_CFA_advance_loc4
404 .word L$CFI21-L$FB2
405 .byte 0x83 ;# DW_CFA_offset, column 0x3
406 .uleb128 0x0
407 .byte 0x11 ;# DW_CFA_offset_extended_sf
408 .uleb128 0x2
409 .sleb128 -5
410
411 .byte 0x4 ;# DW_CFA_advance_loc4
412 .word L$CFI22-L$CFI21
413 .byte 0xd ;# DW_CFA_def_cfa_register = r3
414 .uleb128 0x3
415
416 .align 4
417 L$EFDE2: