| 1 |
/* ----------------------------------------------------------------------- |
| 2 |
sysv.S - Copyright (c) 2022 Xu Chenghua <[email protected]> |
| 3 |
2022 Cheng Lulu <[email protected]> |
| 4 |
|
| 5 |
LoongArch Foreign Function Interface |
| 6 |
|
| 7 |
Permission is hereby granted, free of charge, to any person obtaining |
| 8 |
a copy of this software and associated documentation files (the |
| 9 |
``Software''), to deal in the Software without restriction, including |
| 10 |
without limitation the rights to use, copy, modify, merge, publish, |
| 11 |
distribute, sublicense, and/or sell copies of the Software, and to |
| 12 |
permit persons to whom the Software is furnished to do so, subject to |
| 13 |
the following conditions: |
| 14 |
|
| 15 |
The above copyright notice and this permission notice shall be included |
| 16 |
in all copies or substantial portions of the Software. |
| 17 |
|
| 18 |
THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, |
| 19 |
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF |
| 20 |
MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND |
| 21 |
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT |
| 22 |
HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, |
| 23 |
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, |
| 24 |
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER |
| 25 |
DEALINGS IN THE SOFTWARE. |
| 26 |
----------------------------------------------------------------------- */ |
| 27 |
|
| 28 |
#define LIBFFI_ASM |
| 29 |
#include <fficonfig.h> |
| 30 |
#include <ffi.h> |
| 31 |
|
| 32 |
/* Define aliases so that we can handle all ABIs uniformly. */ |
| 33 |
|
| 34 |
#if __SIZEOF_POINTER__ == 8 |
| 35 |
# define PTRS 8 |
| 36 |
# define LARG ld.d |
| 37 |
# define SARG st.d |
| 38 |
#else |
| 39 |
# define PTRS 4 |
| 40 |
# define LARG ld.w |
| 41 |
# define SARG st.w |
| 42 |
#endif |
| 43 |
|
| 44 |
#if defined(__loongarch_single_float) |
| 45 |
# define FLTS 4 |
| 46 |
# define FLD fld.w |
| 47 |
# define FST fst.w |
| 48 |
#elif defined(__loongarch_double_float) |
| 49 |
# define FLTS 8 |
| 50 |
# define FLARG fld.d |
| 51 |
# define FSARG fst.d |
| 52 |
#elif defined(__loongarch_soft_float) |
| 53 |
# define FLTS 0 |
| 54 |
#else |
| 55 |
#error unsupported LoongArch floating-point ABI |
| 56 |
#endif |
| 57 |
|
| 58 |
.text |
| 59 |
.globl ffi_call_asm |
| 60 |
.type ffi_call_asm, @function |
| 61 |
.hidden ffi_call_asm |
| 62 |
/* struct call_context |
| 63 |
{ |
| 64 |
ABI_FLOAT fa[8]; |
| 65 |
size_t a[10]; |
| 66 |
} |
| 67 |
|
| 68 |
- 8 floating point parameter/result registers (fa[0] - fa[7]) |
| 69 |
- 8 integer parameter/result registers (a[0] - a[7]) |
| 70 |
- 2 registers used by the assembly code to in-place construct its own stack |
| 71 |
frame. |
| 72 |
- frame pointer (a[8]) |
| 73 |
- return address (a[9]) |
| 74 |
|
| 75 |
void ffi_call_asm (size_t *stackargs, struct call_context *regargs, |
| 76 |
void (*fn)(void), void *closure); */ |
| 77 |
|
| 78 |
#define FRAME_LEN (8 * FLTS + 10 * PTRS) |
| 79 |
|
| 80 |
ffi_call_asm: |
| 81 |
.cfi_startproc |
| 82 |
|
| 83 |
/* We are NOT going to set up an ordinary stack frame. In order to pass |
| 84 |
the stacked args to the called function, we adjust our stack pointer |
| 85 |
to a0, which is in the _caller's_ alloca area. We establish our own |
| 86 |
stack frame at the end of the call_context. |
| 87 |
|
| 88 |
Anything below the arguments will be freed at this point, although |
| 89 |
we preserve the call_context so that it can be read back in the |
| 90 |
caller. */ |
| 91 |
|
| 92 |
.cfi_def_cfa 5, FRAME_LEN # Interim CFA based on a1. |
| 93 |
SARG $fp, $a1, FRAME_LEN - 2*PTRS |
| 94 |
.cfi_offset 22, -2*PTRS |
| 95 |
SARG $ra, $a1, FRAME_LEN - 1*PTRS |
| 96 |
.cfi_offset 1, -1*PTRS |
| 97 |
|
| 98 |
addi.d $fp, $a1, FRAME_LEN |
| 99 |
move $sp, $a0 |
| 100 |
.cfi_def_cfa 22, 0 # Our frame is fully set up. |
| 101 |
|
| 102 |
# Load arguments. |
| 103 |
move $t1, $a2 |
| 104 |
move $t2, $a3 |
| 105 |
|
| 106 |
#if FLTS |
| 107 |
FLARG $fa0, $fp, -FRAME_LEN+0*FLTS |
| 108 |
FLARG $fa1, $fp, -FRAME_LEN+1*FLTS |
| 109 |
FLARG $fa2, $fp, -FRAME_LEN+2*FLTS |
| 110 |
FLARG $fa3, $fp, -FRAME_LEN+3*FLTS |
| 111 |
FLARG $fa4, $fp, -FRAME_LEN+4*FLTS |
| 112 |
FLARG $fa5, $fp, -FRAME_LEN+5*FLTS |
| 113 |
FLARG $fa6, $fp, -FRAME_LEN+6*FLTS |
| 114 |
FLARG $fa7, $fp, -FRAME_LEN+7*FLTS |
| 115 |
#endif |
| 116 |
|
| 117 |
LARG $a0, $fp, -FRAME_LEN+8*FLTS+0*PTRS |
| 118 |
LARG $a1, $fp, -FRAME_LEN+8*FLTS+1*PTRS |
| 119 |
LARG $a2, $fp, -FRAME_LEN+8*FLTS+2*PTRS |
| 120 |
LARG $a3, $fp, -FRAME_LEN+8*FLTS+3*PTRS |
| 121 |
LARG $a4, $fp, -FRAME_LEN+8*FLTS+4*PTRS |
| 122 |
LARG $a5, $fp, -FRAME_LEN+8*FLTS+5*PTRS |
| 123 |
LARG $a6, $fp, -FRAME_LEN+8*FLTS+6*PTRS |
| 124 |
LARG $a7, $fp, -FRAME_LEN+8*FLTS+7*PTRS |
| 125 |
|
| 126 |
/* Call */ |
| 127 |
jirl $ra, $t1, 0 |
| 128 |
|
| 129 |
#if FLTS |
| 130 |
/* Save return values - only a0/a1 (fa0/fa1) are used. */ |
| 131 |
FSARG $fa0, $fp, -FRAME_LEN+0*FLTS |
| 132 |
FSARG $fa1, $fp, -FRAME_LEN+1*FLTS |
| 133 |
#endif |
| 134 |
|
| 135 |
SARG $a0, $fp, -FRAME_LEN+8*FLTS+0*PTRS |
| 136 |
SARG $a1, $fp, -FRAME_LEN+8*FLTS+1*PTRS |
| 137 |
|
| 138 |
/* Restore and return. */ |
| 139 |
addi.d $sp, $fp, -FRAME_LEN |
| 140 |
.cfi_def_cfa 3, FRAME_LEN |
| 141 |
LARG $ra, $fp, -1*PTRS |
| 142 |
.cfi_restore 1 |
| 143 |
LARG $fp, $fp, -2*PTRS |
| 144 |
.cfi_restore 22 |
| 145 |
jr $ra |
| 146 |
.cfi_endproc |
| 147 |
.size ffi_call_asm, .-ffi_call_asm |
| 148 |
|
| 149 |
|
| 150 |
/* ffi_closure_asm. Expects address of the passed-in ffi_closure in t0. |
| 151 |
void ffi_closure_inner (ffi_cif *cif, |
| 152 |
void (*fun)(ffi_cif *, void *, void **, void *), |
| 153 |
void *user_data, |
| 154 |
size_t *stackargs, struct call_context *regargs) */ |
| 155 |
|
| 156 |
.globl ffi_closure_asm |
| 157 |
.hidden ffi_closure_asm |
| 158 |
.type ffi_closure_asm, @function |
| 159 |
|
| 160 |
ffi_closure_asm: |
| 161 |
.cfi_startproc |
| 162 |
addi.d $sp, $sp, -FRAME_LEN |
| 163 |
.cfi_def_cfa_offset FRAME_LEN |
| 164 |
|
| 165 |
/* Make a frame. */ |
| 166 |
SARG $fp, $sp, FRAME_LEN - 2*PTRS |
| 167 |
.cfi_offset 22, -2*PTRS |
| 168 |
SARG $ra, $sp, FRAME_LEN - 1*PTRS |
| 169 |
.cfi_offset 1, -1*PTRS |
| 170 |
addi.d $fp, $sp, FRAME_LEN |
| 171 |
|
| 172 |
/* Save arguments. */ |
| 173 |
#if FLTS |
| 174 |
FSARG $fa0, $sp, 0*FLTS |
| 175 |
FSARG $fa1, $sp, 1*FLTS |
| 176 |
FSARG $fa2, $sp, 2*FLTS |
| 177 |
FSARG $fa3, $sp, 3*FLTS |
| 178 |
FSARG $fa4, $sp, 4*FLTS |
| 179 |
FSARG $fa5, $sp, 5*FLTS |
| 180 |
FSARG $fa6, $sp, 6*FLTS |
| 181 |
FSARG $fa7, $sp, 7*FLTS |
| 182 |
#endif |
| 183 |
|
| 184 |
SARG $a0, $sp, 8*FLTS+0*PTRS |
| 185 |
SARG $a1, $sp, 8*FLTS+1*PTRS |
| 186 |
SARG $a2, $sp, 8*FLTS+2*PTRS |
| 187 |
SARG $a3, $sp, 8*FLTS+3*PTRS |
| 188 |
SARG $a4, $sp, 8*FLTS+4*PTRS |
| 189 |
SARG $a5, $sp, 8*FLTS+5*PTRS |
| 190 |
SARG $a6, $sp, 8*FLTS+6*PTRS |
| 191 |
SARG $a7, $sp, 8*FLTS+7*PTRS |
| 192 |
|
| 193 |
/* Enter C */ |
| 194 |
LARG $a0, $t0, FFI_TRAMPOLINE_SIZE+0*PTRS |
| 195 |
LARG $a1, $t0, FFI_TRAMPOLINE_SIZE+1*PTRS |
| 196 |
LARG $a2, $t0, FFI_TRAMPOLINE_SIZE+2*PTRS |
| 197 |
addi.d $a3, $sp, FRAME_LEN |
| 198 |
move $a4, $sp |
| 199 |
|
| 200 |
bl ffi_closure_inner |
| 201 |
|
| 202 |
/* Return values. */ |
| 203 |
#if FLTS |
| 204 |
FLARG $fa0, $sp, 0*FLTS |
| 205 |
FLARG $fa1, $sp, 1*FLTS |
| 206 |
#endif |
| 207 |
|
| 208 |
LARG $a0, $sp, 8*FLTS+0*PTRS |
| 209 |
LARG $a1, $sp, 8*FLTS+1*PTRS |
| 210 |
|
| 211 |
/* Restore and return. */ |
| 212 |
LARG $ra, $sp, FRAME_LEN-1*PTRS |
| 213 |
.cfi_restore 1 |
| 214 |
LARG $fp, $sp, FRAME_LEN-2*PTRS |
| 215 |
.cfi_restore 22 |
| 216 |
addi.d $sp, $sp, FRAME_LEN |
| 217 |
.cfi_def_cfa_offset 0 |
| 218 |
jr $ra |
| 219 |
.cfi_endproc |
| 220 |
.size ffi_closure_asm, .-ffi_closure_asm |
| 221 |
|
| 222 |
/* Static trampoline code table, in which each element is a trampoline. |
| 223 |
|
| 224 |
The trampoline clobbers t0 and t1, but we don't save them on the stack |
| 225 |
because our psABI explicitly says they are scratch registers, at least for |
| 226 |
ELF. Our dynamic trampoline is already clobbering them anyway. |
| 227 |
|
| 228 |
The trampoline has two parameters - target code to jump to and data for |
| 229 |
the target code. The trampoline extracts the parameters from its parameter |
| 230 |
block (see tramp_table_map()). The trampoline saves the data address in |
| 231 |
t0 and jumps to the target code. As ffi_closure_asm() already expects the |
| 232 |
data address to be in t0, we don't need a "ffi_closure_asm_alt". */ |
| 233 |
|
| 234 |
#if defined(FFI_EXEC_STATIC_TRAMP) |
| 235 |
.align 16 |
| 236 |
.globl trampoline_code_table |
| 237 |
.hidden trampoline_code_table |
| 238 |
.type trampoline_code_table, @function |
| 239 |
|
| 240 |
trampoline_code_table: |
| 241 |
|
| 242 |
.rept 65536 / 16 |
| 243 |
pcaddu12i $t1, 16 # 65536 >> 12 |
| 244 |
ld.d $t0, $t1, 0 |
| 245 |
ld.d $t1, $t1, 8 |
| 246 |
jirl $zero, $t1, 0 |
| 247 |
.endr |
| 248 |
.size trampoline_code_table, .-trampoline_code_table |
| 249 |
|
| 250 |
.align 2 |
| 251 |
#endif |
| 252 |
|
| 253 |
/* ffi_go_closure_asm. Expects address of the passed-in ffi_go_closure in t2. |
| 254 |
void ffi_closure_inner (ffi_cif *cif, |
| 255 |
void (*fun)(ffi_cif *, void *, void **, void *), |
| 256 |
void *user_data, |
| 257 |
size_t *stackargs, struct call_context *regargs) */ |
| 258 |
|
| 259 |
.globl ffi_go_closure_asm |
| 260 |
.hidden ffi_go_closure_asm |
| 261 |
.type ffi_go_closure_asm, @function |
| 262 |
|
| 263 |
ffi_go_closure_asm: |
| 264 |
.cfi_startproc |
| 265 |
addi.d $sp, $sp, -FRAME_LEN |
| 266 |
.cfi_def_cfa_offset FRAME_LEN |
| 267 |
|
| 268 |
/* Make a frame. */ |
| 269 |
SARG $fp, $sp, FRAME_LEN - 2*PTRS |
| 270 |
.cfi_offset 22, -2*PTRS |
| 271 |
SARG $ra, $sp, FRAME_LEN - 1*PTRS |
| 272 |
.cfi_offset 1, -1*PTRS |
| 273 |
addi.d $fp, $sp, FRAME_LEN |
| 274 |
|
| 275 |
/* Save arguments. */ |
| 276 |
#if FLTS |
| 277 |
FSARG $fa0, $sp, 0*FLTS |
| 278 |
FSARG $fa1, $sp, 1*FLTS |
| 279 |
FSARG $fa2, $sp, 2*FLTS |
| 280 |
FSARG $fa3, $sp, 3*FLTS |
| 281 |
FSARG $fa4, $sp, 4*FLTS |
| 282 |
FSARG $fa5, $sp, 5*FLTS |
| 283 |
FSARG $fa6, $sp, 6*FLTS |
| 284 |
FSARG $fa7, $sp, 7*FLTS |
| 285 |
#endif |
| 286 |
|
| 287 |
SARG $a0, $sp, 8*FLTS+0*PTRS |
| 288 |
SARG $a1, $sp, 8*FLTS+1*PTRS |
| 289 |
SARG $a2, $sp, 8*FLTS+2*PTRS |
| 290 |
SARG $a3, $sp, 8*FLTS+3*PTRS |
| 291 |
SARG $a4, $sp, 8*FLTS+4*PTRS |
| 292 |
SARG $a5, $sp, 8*FLTS+5*PTRS |
| 293 |
SARG $a6, $sp, 8*FLTS+6*PTRS |
| 294 |
SARG $a7, $sp, 8*FLTS+7*PTRS |
| 295 |
|
| 296 |
/* Enter C */ |
| 297 |
LARG $a0, $t2, 1*PTRS |
| 298 |
LARG $a1, $t2, 2*PTRS |
| 299 |
move $a2, $t2 |
| 300 |
addi.d $a3, $sp, FRAME_LEN |
| 301 |
move $a4, $sp |
| 302 |
|
| 303 |
bl ffi_closure_inner |
| 304 |
|
| 305 |
/* Return values. */ |
| 306 |
#if FLTS |
| 307 |
FLARG $fa0, $sp, 0*FLTS |
| 308 |
FLARG $fa1, $sp, 1*FLTS |
| 309 |
#endif |
| 310 |
|
| 311 |
LARG $a0, $sp, 8*FLTS+0*PTRS |
| 312 |
LARG $a1, $sp, 8*FLTS+1*PTRS |
| 313 |
|
| 314 |
/* Restore and return. */ |
| 315 |
LARG $ra, $sp, FRAME_LEN-1*PTRS |
| 316 |
.cfi_restore 1 |
| 317 |
LARG $fp, $sp, FRAME_LEN-2*PTRS |
| 318 |
.cfi_restore 22 |
| 319 |
addi.d $sp, $sp, FRAME_LEN |
| 320 |
.cfi_def_cfa_offset 0 |
| 321 |
jr $ra |
| 322 |
.cfi_endproc |
| 323 |
.size ffi_go_closure_asm, .-ffi_go_closure_asm |
| 324 |
|
| 325 |
#if defined __ELF__ && defined __linux__ |
| 326 |
.section .note.GNU-stack,"",%progbits |
| 327 |
#endif |